collage spécial indisponible apres un range("").clearcontents

**tkitoi** · 05/10/2024, 18h34

Bonjour,

Je débute VBA comme beaucoup de gens qui viennent poser leurs questions ici, et je rencontre un problème dans mon code ...
Le but du jeux est pour chaque feuille de mon classeur de nettoyer le contenu de cellule/zone de cellules et jusque la tout va bien.
Toutefois, un peu avant ma boucle, je procède à la copie d'une zone d'une certaine feuille (avec un nombre de colonne fixe, mais pas les lignes) et souhaite faire un collage spécial de cette zone sur toutes mes feuilles.

Voilà le bout de code qui pose problème :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
    If ActiveSheet.Name <> "FeuilZ" Then Sheets("FeuilZ").Activate
    zderniereligne = Range("A" & Rows.Count).End(xlUp).Row
    Range(Range("A3"), Range("E" & zderniereligne)).Copy
    For Each Sheet In Sheets
        If Sheet.Name <> "FeuilZ" Then
            Sheet.Activate
            [A3:F82].ClearContents
            [I10:M39].ClearContents
            [J5].ClearContents
            [J3].ClearContents
            [I10].PasteSpecial Paste:=xlPasteValues
            If [L1].Value <> zyear Then [L1].Value = zyear
            [A3].Select
        Else
            If ActiveSheet.Name <> "Feuil1" Then Sheets("Feuil1").Activate
            [A3].Select
        End If
    Next Sheet

Le problème arrive au moment de la ligne [I10].PasteSpecial Paste:=xlPasteValues.

Si je fait du pas à pas pour vérifier ce qu'il se passe, la copie est bien faite et est dans le presse papier, si je fait un clic droit dans une cellule, l'option collage spécial est bien dispo, mais des que le premier range ([A3:F82].ClearContents) arrive dans la boucle, l'option de collage spécial disparait et j'ai donc une erreur "La méthode PasteSpecial de la classe Range a échoué" au moment du collage.
Le débogage me surligne la ligne [I10].PasteSpecial Paste:=xlPasteValues.

J'utilise des clearcontents et un special paste car la mise en forme du tableau ne doit pas changer, uniquement les valeurs.
Je précise que le presse papier contient malgré tout ma copie, je ne peux juste pas la coller ...

J'avais auparavant divisé cette procédure en plusieurs petites, chacune sa tache, et tout roulait, mais j'avais du coup plusieurs procédures (3) qui lançait la même boucle each sheet in sheets et voulait optimiser en évitant d'avoir plusieurs boucles for each sheet in sheets et tout faire dans la même, mais le nettoyage de la zone concernée doit arriver avant le collage (normal vous me direz).

Auriez vous des idées ?

En espérant avoir été clair et en vous remerciant pour votre temps.

**Philippe Tulliez** · 05/10/2024, 19h05

Bonjour,
utilisez la méthode ClearContents avant la copie.
Vérifiez manuellement. Si vous effectuez une copie et qu'ensuite vous faites un effacement du contenu le presse papier se vide donc impossible de coller

**tkitoi** · 05/10/2024, 19h16

Envoyé par Philippe Tulliez

Bonjour,
utilisez la méthode ClearContents avant la copie.
Vérifiez manuellement. Si vous effectuez une copie et qu'ensuite vous faites un effacement du contenu le presse papier se vide donc impossible de coller

Bonjour Philippe et merci.

Dans ce cas je ne voit que 2 options :
- soit faire 2 boucles, une qui nettoie toutes mes feuilles, et une qui copie une fois ma zone et la colle sur toutes mes feuilles.
- soit dans la boucle faire le nettoyage, puis aller copier ma zone voulue puis retourner sur la précédente feuille active (en ayant pris sont nom dans une variable par exemple) pour coller les valeurs.

Qu'est-ce qui serait le plus optimiser entre faire tourner 2 boucles, ou faire 12 copier coller (12 étant mon nombre de feuilles autres que "FeuillZ").

Merci beaucoup.

**Philippe Tulliez** · 05/10/2024, 19h30

Bonjour,
Petit exemple rapide, qui pourrait être amélioré, avec la copie d'un tableau structuré (voir lien plus bas)

Petites remarques

En VBA, il est inutile dans 99% des cas, d'utiliser les méthodes Activate, Select, etc.
Evitez les adressages des cellules entourés de crochets
Utilisez la parentalité des objets (voir les liens plus bas)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub t()
  Const SourceSheetName As String = "FeuilZ" ' Nom de la feuille source
  Const TableName As String = "t_Test"       ' Nom de la table structurée à copier
  Dim sh As Worksheet
  ' Efface le contenu de certaines plages des feuille du classeur à l'exception de la feuille FeuilZ
  For Each sh In Worksheets
    With sh
      Select Case .Name
         Case Is <> SourceSheetName
            .Range("A3:F82").ClearContents
            .Range("I10:M39").ClearContents
            .Range("J5").ClearContents
            .Range("I3").ClearContents
      End Select
    End With
  Next
  ' Copie de la plage des données de la table
  Range(TableName).Copy
  ' Collage special
    For Each sh In Worksheets
    With sh
      Select Case .Name
         Case Is <> SourceSheetName
         .Range("I10").PasteSpecial xlPasteValues
      End Select
    End With
  Next
  Set sh = Nothing
End Sub

Liens

**tkitoi** · 05/10/2024, 20h16

Envoyé par Philippe Tulliez

Bonjour,
Petit exemple rapide, qui pourrait être amélioré, avec la copie d'un tableau structuré (voir lien plus bas)

Petites remarques

En VBA, il est inutile dans 99% des cas, d'utiliser les méthodes Activate, Select, etc.
Evitez les adressages des cellules entourés de crochets
Utilisez la parentalité des objets (voir les liens plus bas)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub t()
  Const SourceSheetName As String = "FeuilZ" ' Nom de la feuille source
  Const TableName As String = "t_Test"       ' Nom de la table structurée à copier
  Dim sh As Worksheet
  ' Efface le contenu de certaines plages des feuille du classeur à l'exception de la feuille FeuilZ
  For Each sh In Worksheets
    With sh
      Select Case .Name
         Case Is <> SourceSheetName
            .Range("A3:F82").ClearContents
            .Range("I10:M39").ClearContents
            .Range("J5").ClearContents
            .Range("I3").ClearContents
      End Select
    End With
  Next
  ' Copie de la plage des données de la table
  Range(TableName).Copy
  ' Collage special
    For Each sh In Worksheets
    With sh
      Select Case .Name
         Case Is <> SourceSheetName
         .Range("I10").PasteSpecial xlPasteValues
      End Select
    End With
  Next
  Set sh = Nothing
End Sub

Liens

Merci Philippe pour cet exemple, je vais essayer ainsi.

Toutefois une question :
- Pourquoi est-il préférable d'utiliser range("Ax") au lieu de [Ax] ?

Merci.