liste du texte déjà entré dans un textbox

**horneth** · 22/10/2006, 12h45

Bonjour, j'aimerais savoir comment on peut faire en sorte que lorsqu'on clique sur un textbox, le (ou les) texte(s) qu'on avait déjà tapé précédemment s'affiche en dessous. Comme lorsqu'on fait une recherche avec google par exemple si on tape "a" il nous met toutes les recherches commencant par "a" que l'on avait effectuées avant. Sans peut-être aller jusque là je voudrais savoir au moins comment afficher les recherches précédentes, sans se soucier de la première lettre de la recherche.

Merci d'avance de votre aide.

**ProgElecT** · 22/10/2006, 13h15

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Option Explicit
 
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long
'Const LB_FINDSTRING = &H18F
'Const LB_FINDSTRINGEXACT = &H1A2
Dim Masq
Private Sub Form_Load()
'KPD-Team 1998'URL: http://www.allapi.net/
'E-Mail: KPDTeam@Allapi.net'Add some items to the listbox
With List1
 .AddItem "Computer": .AddItem "Screen"
 .AddItem "Modem": .AddItem "Printer"
 .AddItem "Scanner": .AddItem "Sound Blaster"
 .AddItem "Keyboard": .AddItem "CD-Rom"
 .AddItem "Mouse": .AddItem "Sourdingue"
End With
End Sub
Private Sub Check1_Click()
If Check1.Value = 0 Then Masq = &H18F Else Masq = &H1A2
Text1_Change
End Sub
Private Sub Text1_Change()
'c'est ici que cela devrait t'interresser
List1.ListIndex = SendMessage(List1.hwnd, Masq, -1, ByVal CStr(Text1.Text))
End Sub

**horneth** · 22/10/2006, 14h36

ok merci je vais regarder ca
edit : bon alors j'ai rentré le code dans mon programme mais en fait ca fait rien du tout. Quand je tape du texte ca change rien à la listbox. En même temps ca me parait normal puisque la fonction Send Message est vide dans ton code donc elle sert à rien en fait la.

**avigeilpro** · 22/10/2006, 15h26

SI ca fait quelque chose :
Lorsque tu tape du text ca selectionne celui qui correspond le plus à ce que tu tape.

PS :
Rajoute la ligne en gras dans le form_load

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Form_Load()
'KPD-Team 1998'URL: http://www.allapi.net/
'E-Mail: KPDTeam@Allapi.net'Add some items to the listbox
With List1
 .AddItem "Computer": .AddItem "Screen"
 .AddItem "Modem": .AddItem "Printer"
 .AddItem "Scanner": .AddItem "Sound Blaster"
 .AddItem "Keyboard": .AddItem "CD-Rom"
 .AddItem "Mouse": .AddItem "Sourdingue"
End With
Masq = &H18F
End Sub

EDIT : Sendmessage est une API windows, il ne faut pas la programmer mais juste déclarer son appel

**horneth** · 22/10/2006, 15h33

ok merci beaucoup.
Mais maintenant moi j'aurais voulu savoir comment fair pour qu'il enregistre le texte et que la prochaine fois que je lance le programme qu'il se remette tout seul dans la listbox, si c'est possible. Parce que là il tuilise seulement les mots définis dans le form_oad mais moi je voudrais que à chaque fois que je rentre un nouveau mot il s'en rappelle pour la prochaine fois.

**avigeilpro** · 22/10/2006, 15h45

Vire le check1, remplace tout le code de la feuille par ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
Option Explicit
 
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long
Const LB_FINDSTRING = &H18F
Const LB_FINDSTRINGEXACT = &H1A2
 
Dim Masq
Dim AdresseLog As String
 
Private Sub Form_Load()
Masq = LB_FINDSTRING
 
'Adresse du fichier de sauvegarde des frappes
AdresseLog = "C:\Frappes.log"
 
'Met à jour le contenu de la liste
MAJList
 
End Sub
Private Sub Text1_Change()
 
'Met à jour le contenu de la liste
MAJList
 
'c'est ici que cela devrait t'interresser
List1.ListIndex = SendMessage(List1.hwnd, Masq, -1, ByVal CStr(Text1.Text))
 
End Sub
 
Private Sub Text1_KeyUp(KeyCode As Integer, Shift As Integer)
On Error Resume Next
 
Dim Contenu As String
 
 
 
If KeyCode = 13 Then
    If Dir(AdresseLog) <> "" Then
        Contenu = Space(FileLen(AdresseLog))
 
        Open AdresseLog For Binary As #1
        Get #1, , Contenu
        Close #1
 
        Kill AdresseLog
 
        'si le text n'existe pas déjà
        If InStr(Contenu, Text1.Text) = 0 Then
            Contenu = Contenu & ";" & Text1.Text
        End If
    Else
        Contenu = Contenu & Text1.Text
    End If
 
    Open AdresseLog For Binary As #1
    Put #1, , Contenu
    Close #1
    'Met à jour le contenu de la liste
    MAJList
 
End If
 
End Sub
 
Public Sub MAJList()
Dim Contenu As String
Dim ListLg() As String
Dim Index As Integer
 
If Dir(AdresseLog) <> "" Then
    Contenu = Space(FileLen(AdresseLog))
 
    Open AdresseLog For Binary As #1
    Get #1, , Contenu
    Close #1
 
    ListLg = Split(Contenu, ";")
    List1.Clear
 
    For Index = 0 To UBound(ListLg)
    List1.AddItem ListLg(Index)
    Next
End If
End Sub

**horneth** · 22/10/2006, 15h47

ok merci je teste de suite
edit : Ca marche niquel c'est parfait merci !

**horneth** · 22/10/2006, 16h50

Juste une dernière chose, comment tu connais la liste des keycode correspondant à chaque touche parce que ca me serait bien utile?

Désolé pour le double poste mais ca évite de créer un nouveau topic.

**Delbeke** · 22/10/2006, 17h03

Vaux mieux ouvrir un autre topic pour une autre question, sinon le titre du post ne correspond plus a rien.
Sinon, tu fais la touche F2 dans l'interface de VB(Eplorateur d'objet intégré de Vb) et tu rechecherches vbkey. Tu auras toutes les correspondances

**horneth** · 22/10/2006, 17h37

ok merci et désolé pour le HS alors :S

liste du texte déjà entré dans un textbox

VB 6 et antérieur

Discussions similaires

Partager

Partager