Discussion :

[bobymob]

Bonjour,

Je reçois des fichiers Excel en pièces jointes, dans ma messagerie Outlook Express de façon aléatoire. Ces fichiers doivent être chargés dans une base Access dans un délai très court.
Est-il possible de saugarder ces fichiers Excel dans un répertoire dédié de mon disque dur, sans mon intervention, donc automatiquement?
En ce qui concerne le chargement de ces fichiers Excel, du répertoire dédié, dans la base ne me pose pas de problème.
Je remercie par avance ceux qui auront la gentillesse de se pencher sur mon problème.

Bobymob.

[cafeine]

Hello,

oui, c'est possible !

Il faut ajouter la référence Microsoft Outlook X.0 Object Library

et adapter ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub GetXLFilesFromOutlook()
    Dim oOutlk As Outlook.Application
    Dim oInbox As Object, oMapi As Object
    Dim mail As Object
    Dim PieceJointe As Object
    Dim PJindex As Integer
 
    Set oOutlk = New Outlook.Application
    Set oMapi = oOutlk.GetNamespace("MAPI")
 
    ' répertoire Inbox
    Set oInbox = oMapi.GetDefaultFolder(olFolderInbox)
    ' boucle sur chaque mail
    For Each mail In oInbox.Items
        ' teste la présence de pièce jointe
        If mail.Attachments.count > 0 Then
            Debug.Print mail.SenderName, mail.Subject, mail.Attachments.count
            For PJindex = 1 To mail.Attachments.count
                Set PieceJointe = mail.Attachments.Item(PJindex)
                ' récupère les fichiers Excel
                If PieceJointe.FileName Like "*.xls" Then
                    PieceJointe.SaveAsFile "C:\Temp\PJOutLk" & PieceJointe.FileName
 
                    ' met ton code d'importation ici
                    ' Exemple
                     'DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel9, "UneTable", _
                                               "C:\Temp\PJOutLk" & PieceJointe.FileName
                    Debug.Print "Importation de " & PieceJointe.FileName
                End If
            Next PJindex
        End If
        DoEvents
    Next mail
    Set PieceJointe = Nothing
    Set mail = Nothing
    Set oInbox = Nothing
    Set oOutlk = Nothing
    Set oMapi = Nothing
End Sub

[toto222]

bonjour la procedure sub je la met ou pour pouvoir justemnt faire cela car la procedure m'interesse beaucoup pour d'autre application egalement
merci d'avance

[cafeine]

Hello,

il suffit de la mettre dans un module de code, et de l'adapter à son application.