Discussion :

[Stephane_123]

Hello,

J'ai un code VBA pour disons copier une colonne de ma base de donnée bd1.mdb dans un ficher Excel ouvert.

Le souc, c'est que ça ne fonctionne pas et je ne comprends pas mon erreur. De manière générale, comment aller puiser dans Access depuis Excel?

Merci

voilà le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 Private Sub Workbook_Open()
 
Const ML_PATH = "path to bd1"
Const ML_QUERY = "sql query"
 
Call LancementRequêteAccess
End Sub
 
Function LancementRequêteAccess()
'variable objet affectée à l'application Access
Dim oAccesS As Access.Application
'variable pour la base de donnée
Dim db As DAO.Database
'variable objet requête
Dim qdf As QueryDef
'variable objet recordset
Dim rst As DAO.Recordset
 
'creation d'une instance Access par automation
Set oAccesS = CreateObject("Access.Application")
'chargement de la BDD
oAccesS.OpenCurrentDatabase ML_PATH
'affectation d'une référence à la BDD
Set db = oAccesS.CurrentDb
'affectation d'une référence à la requête
Set qdf = db.QueryDefs(ML_QUERY)
'lancement de la requête et création du jeu d'enregistrements
Set rst = qdf.OpenRecordset(dbOpenSnapshot)
'écriture du jeu d'enregistrement à partir de la cellule A1
'de la feuille "Feuil1"
Worksheets("Feuil3").Range("A1").CopyFromRecordset rst
'libération de la mémoire
Set rst = Nothing
Set db = Nothing
End Function

[Invité]

Une constante ne se met jamais dans une procédure !
J'ai testé ça chez moi et ça fonctionne parfaitement

Dans un Module1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Option Explicit
Const ML_PATH = "C:\ESSAI\MaBase_don.mdb"
Const ML_QUERY = "Rqt ListeDesCommandes"
 
Sub Test()
Call LancementRequêteAccess
End Sub
 
Function LancementRequêteAccess()
On Error GoTo Err_Function
'variable objet affectée à l'application Access
Dim oAccesS As Access.Application
'variable pour la base de donnée
Dim db As DAO.Database
'variable objet requête
Dim qdf As QueryDef
'variable objet recordset
Dim rst As DAO.Recordset
 
'creation d'une instance Access par automation
Set oAccesS = CreateObject("Access.Application")
'chargement de la BDD
oAccesS.OpenCurrentDatabase ML_PATH
'affectation d'une référence à la BDD
Set db = oAccesS.CurrentDb
'affectation d'une référence à la requête
Set qdf = db.QueryDefs(ML_QUERY)
'lancement de la requête et création du jeu d'enregistrements
Set rst = qdf.OpenRecordset(dbOpenSnapshot)
'écriture du jeu d'enregistrement à partir de la cellule A1
'de la feuille "Feuil1"
Worksheets("Feuil1").Range("A1").CopyFromRecordset rst
'libération de la mémoire
Exit_Err:
rst.Close: qdf.Close: db.Close
oAccesS.CloseCurrentDatabase
Set rst = Nothing
Set qdf = Nothing
Set db = Nothing
Set oAccesS = Nothing
Exit Function
 
Err_Function:
  MsgBox "Une erreur est survenue, fermeture de la base"
  Resume Exit_Err
End Function

Il faut penser à bien fermer tous les objets ouverts, et les mettres ensuite à NOTHING

Voilà

[Stephane_123]

Hello,

merci pour la réponse. En effet, j'avais viré les constantes, erreur bête.

Par contre j'ai une question pas moins bête au sujet de

Const ML_QUERY = "Rqt ListeDesCommandes"

Qu'entends-tu par "Rqt ListeDesCommandes", des commandes SQL? Le programme bug à ce niveau là, tu peux me donner un exemple merci

Steph

[Invité]

Par contre j'ai une question pas moins bête au sujet de
Const ML_QUERY = "Rqt ListeDesCommandes"
Qu'entends-tu par "Rqt ListeDesCommandes", des commandes SQL? Le programme bug à ce niveau là, tu peux me donner un exemple merci

Excuse, il faut que tu mettes à cet endroit le nom de ta requête dans ta base à toi !

Dans ma base, c'est "Rqt ListeDesCommandes", certainement pas dans la tienne

Désolé

[Stephane_123]

youhouhou ça merche merci

[Antichoc]

Ce code fait-il appel à une bibliothèque précise ??? Il me rejette toutes les déclarations DIM de la BDD !!!

[cafeine]

Oui, il faut ajouter la référence DAO.

En revanche, je vois pas pourquoi il serait nécessaire d'ouvrir Access.
L'ouverture DAO suffit pour traiter un recordset a priori.

[Antichoc]

Merci, mais comment tu fait pour l'ajouter ???

(C'est du tout nouveau pour moi le DAO)

Merci

[cafeine]

Tu vas dans le module de code.

Puis menu : Outils > Références

Puis tu vas cocher dans la liste : Microsoft DAO 3.6

Dans le code suivant, on voit qu'il n'est pas nécessaire d'ouvrir un objet Access :
http://www.developpez.net/forums/sho...d.php?t=269383