Discussion :

[Anto03]

Bonjour,
Voilà je sais qu'il est possible de modifier le paramètre d'une requête sql lorsqu'il s'agit d'une requête de modification ou de suppression or dans mon cas il s'agit d'une requête de sélection.
Voyez plutôt :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
set RequeteSql = currentdb.OpenRecordset(NomTableArchive)
RequeteSql.Parameters("MaDate") = MaDate
 
set ARCHIVE = currentdb.openRecorset(NomTableArchive)
set REQUETE = Opendatabase(BaseSource).OpenRecordset(RequeteSql.SQL)

Le problème ici c'est que la valeur de requeteSql.SQL ne change pas et est toujours sous la forme "... WHERE Date_Creation = [MaDate]". Or si j'execute le code RequeteSql.Parameters(0) là il m'affiche bien la date passé en paramètre.

Il semblerait donc que lorsque l'on modifie un paramètre access ne modifie pas le sql. Que-dois je faire dans ce cas là ? J'aimerai mieux éviter de passer par une table temporaire si possible.
merci d'avance

[LedZeppII]

Bonjour,

Est-ce que tu as essayé comme dans la faq ?

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim qdf As DAO.QueryDef 
Dim rcs As DAO.Recordset 
 
  'référence à la requête 
Set qdf = CurrentDb.QueryDefs("NomQuery") 
 
  'code qui utilise qdf 
  'par exemple 
qdf.Parameters("NomParamètre") = valeur    '<== si requête paramétrée 
Set rcs = qdf.OpenRecordset                '<== pour travailler sur les données 
 
 
  'libération de la référence 
Set qdf = Nothing

A+

[Anto03]

Salut LedZeppII,
Oui bien sûr j'ai essayé cette technique surtout que il me semble que j'en suis l'auteur ^^
Seulement avec cette technique qui transforme ma requête en recordset je me connecte à ma base de données courrante.
Or moi je veux me connecter à une autre base de données

[Tofalu]

Oui bien sûr j'ai essayé cette technique surtout que il me semble que j'en suis l'auteur ^^

Seulement avec cette technique qui transforme ma requête en recordset je me connecte à ma base de données courrante.

Tu n'as qu'à instancier un objet database pointant sur la bonne base de données.

Un tutoriel qui pourra t'aider :

http://warin.developpez.com/accesss/dao

A moins que tu n'en soit aussi l'auteur

[Anto03]

Oups désolé en effet ce n'est pas moi l'auteur mais j'avais envoyé un email à la FAQ cet été qui reprenait cet exemple à quelque chose prêt...
Sans rancune
J'ai déjà un objet dababase qui pointe sur la bonne base de données comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
set REQUETE = Opendatabase(BaseSource)

seulement comment lui attribuer mon recordset créé précedemment par la méthode dont je suis "presque l'auteur" ^^ :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
Set qdf = CurrentDb.QueryDefs("NomQuery") 
 
  'code qui utilise qdf 
  'par exemple 
qdf.Parameters("NomParamètre") = valeur   
Set rcs = qdf.OpenRecordset  '<== Ce recordset ici

[Tofalu]

Je n'ai rien compris désolé.

L'objet recordset est ouvert depuis un objet querydef de la base nommée REQUETE en théorie non ?

[Anto03]

uhm je vais tenter d'expliquer en détails je pense que ça t'aidera.
En faite j'ai 3 bases de données différentes et j'aimerai archives certaines données à l'intèrieur de ces 3 bases.
Pour cela j'ai créé une base de données ARCHIVE.MDB qui contient toutes les tables des 3 bases de données et qui récupère les données à l'aide de requête.
Seulement ces requêtes sont dans ARCHIVE.MDB. Je récupère donc le sql de ses requêtes et je les appliques aux 3 bases de données.
Ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
'Récupération de la requête dans ARCHIVE.mdb
Dim RequeteSql As DAO.QueryDef  
Set RequeteSql = CurrentDb.QueryDefs("MaRequete")  
'Execution de cette requete sur une autre base de données
set PREMIEREBASE = Opendatabase(BaseSource).OpenRecordset(RequeteSql.SQL)

voilà, ceci marche parfaitement tant que ma requête ne contient pas de paramètre... parce que si je fais ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
'Récupération de la requête dans ARCHIVE.mdb
Dim RequeteSql As DAO.QueryDef  
Set RequeteSql = CurrentDb.QueryDefs("MaRequete")  
'Modification du paramètre
RequeteSql.Parameters("Date") = #01/01/2006#
'Execution de cette requete sur une autre base de données
set PREMIEREBASE = Opendatabase(BaseSource).OpenRecordset(RequeteSql.SQL)

et bien ça ne fonctionne pas évidemment. La solution serait de mettre mes requêtes dans les bases de données concernées mais j'aimerai éviter ça justement...
Merci d'avance

[LedZeppII]

Bonsoir,

tu peux créer une requête temporaire dans l'autre base

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
'Récupération de la requête dans ARCHIVE.mdb
Dim RequeteSql As DAO.QueryDef
Dim DB1 As DAO.Database, Qd1 As DAO.QueryDef, PREMIEREBASE As DAO.RecordSet
 
Set RequeteSql = CurrentDb.QueryDefs("MaRequete")
' Ouverture base 1
Set DB1 = Opendatabase(BaseSource)
' Creation requête temporaire paramétrée dans Base 1 avec le même
' SQL que celui de "MaRequete"
Set Qd1 = DB1.CreateQueryDef("", RequeteSql.SQL)
'Modification du paramètre
Qd1.Parameters("Date") = #01/01/2006#
'Execution de cette requete sur une autre base de données
set PREMIEREBASE = Qd1.OpenRecordset

ou bien remplacer le paramètre par sa valeur dans le SQL de la requête

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
'Récupération de la requête dans ARCHIVE.mdb
Dim RequeteSql As DAO.QueryDef, strSQL As String
Set RequeteSql = CurrentDb.QueryDefs("MaRequete")  
strSQL = RequeteSql.SQL
' Au cas où la requête est de la forme PARAMETERS ...; SELECT ...
l = InStr(strSQL, "SELECT")
If l > 1 Then
   strSQL = Mid(strSQL, l, Len(strSQL) + 1 - l)
End If
'Modification du paramètre
strSQL = Replace(strSQL, "[Date]", "#01/01/2006#")
'Execution de cette requete sur une autre base de données
set PREMIEREBASE = Opendatabase(BaseSource).OpenRecordset(strSQL)

A+

[Anto03]

La solution des requêtes temporaires me va très bien !
Merci beaucoup !!!