Discussion :

[john7]

J'ai vu un peu regardé l'exemple dans l'aide de VB6, mais ça coince.
Je voudrais créer une table pour mettre des images persos s'appelant "Catégorie" et un index "RefCatégorie". Voici ce que j'ai écris.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Public Sub CreerBase()
   CheminBase = App.Path & "\DB\Images.mdb"
 
    Set db = DAO.Workspaces(0).CreateDatabase(CheminBase, dbLangGeneral)
 
Set Table = db.CreateTableDef("Categorie")
 
With Table
Set idxNew = .CreateIndex("RefCategorie")
With idxNew
    .fields.Append .CreateField("NomCategorie")
    .fields.Append .CreateField("Cliparts", dbText)
    .fields.Append .CreateField("Photos", dbText)
    .fields.Append .CreateField("Gifs", dbText)
    .fields.Append .CreateField("Textures", dbText)
    .fields.Append .CreateField("Web", dbText)
    .fields.Append .CreateField("autres", dbText)
    .Unique = True
 
End With
        .Indexes.Append idxNew
        .Indexes.Refresh
 
End With
db.TableDefs.Append Table
db.Close
Set db = Nothing

Le problème c'est que ma base est bien crée ainsi que la table, mais pas l'index. Si vous avez une réponse, ou une autre façon de faire.
Je vous remercie.

[WOLO Laurent]

Etant données que la table et l'index sont crées une seule fois, pourquoi ne pas le faire dans ton SGBDR lors de la création des objects de ta base ?

[john7]

Il est vrai que je pourrais créer une base avec access contenant les index et les références de catégories, mais je voudrais donner la possibilité de créer d'autres références par le code. Je voulais juste que par le programme, l'utilisateur puisse créer sa propre base avec ses références et là j'en étais aux tests.
Je vous remercie pour votre réponse, et j'espére que je me suis mieux exprimé cette fois.

[AdHoc]

bonjour,
au vu de l'aide de vb, tu mélanges deux choses la creation d'une Table et la creation de ses index.
Fais l'un, puis l'autre.
Le code suivant me crée la table avec un index

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
   Dim dbBase As Database
   Dim NewTable As TableDef
   Dim idxNew As Index
 
    Set dbBase = DAO.Workspaces(0).CreateDatabase("App.Path & "Images.mdb", dbLangGeneral)
 
Set NewTable = dbBase.CreateTableDef("Categorie")
 
With NewTable
   'Creation de la table
   .Fields.Append .CreateField("NoCategorie", dbInteger)
   .Fields.Append .CreateField("NomCategorie", dbText)
   .Fields.Append .CreateField("Cliparts", dbText)
   .Fields.Append .CreateField("Photos", dbText)
   .Fields.Append .CreateField("Gifs", dbText)
   .Fields.Append .CreateField("Textures", dbText)
   .Fields.Append .CreateField("Web", dbText)
   .Fields.Append .CreateField("autres", dbText)
   'Creation de l'index
   Set idxNew = .CreateIndex("idxCategorie")
   With idxNew
      .Fields.Append .CreateField("NoCategorie")
      .Unique = True
   End With
   'Ajout de l'index à la collection d'index
   .Indexes.Append idxNew
   .Indexes.Refresh
End With
'Ajout de la table à la base de données
dbBase.TableDefs.Append NewTable
dbBase.Close
Set dbBase = Nothing

[john7]

Effectivement vu comme ça!!!! Créer un index pour créer un champ avec, bien compris.Merci beaucoup.
Tout à fait autre chose, n'y a t'il pas trop de bruit dans le tunnel ?