Discussion :

[Mus30]

Bonjour à tous, aujourd'hui, j'ai un problème déjà mainte fois abordé sur le forum d'actualisation de sous formulaire, mais le soucis c'est que je n'ai pas réussi à le résourdre malgré tous les topics.

Voilà le topo :

J'ai un formulaire F_Remplissage_Date dans lequel se trouve un sous formulaire F_Remplissage_Date_Sous_Formulaire (en mode feuille de donnée) lui même basé sur une requête R_Remplissage_Date.

J'ai dans mon formulaire une combobox (Cmb_Rapport) qui doit (en théorie) me permettre de filtrer mon sous-formulaire.

J'ai donc fait un évènement sur mise à jour où ma combobox filtre ma requête.
Tout se passe bien au niveau du code, sauf que le sous-formulaire ne s'actualise pas. Les changement son bien pris en compte car si je ferme et réouvre le formulaire, ça prend en compte les modif.

Je vous mets le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub Cmb_Rapport_AfterUpdate()
 
Dim Intitule_Rapport As String
Dim strRapport As String
 
Intitule_Rapport = Me!Cmb_Rapport.Text
 
strRapport = "SELECT Table_rapport_de_verification.[Intitulé du rapport de vérification]," & _
" Table_importation_de_donnees.Service, Table_importation_de_donnees.Etage," & _
" Table_importation_de_donnees.Pièce, Table_importation_de_donnees.Matériel," & _
" Table_importation_de_donnees.[Numéro de réserve]," & _
" Table_importation_de_donnees.[Description de la réserve]," & _
" Table_importation_de_donnees.[Degré de gravité], Table_importation_de_donnees.[Date de levée]," & _
" Table_importation_de_donnees.[Nom Intervenant], Table_importation_de_donnees.Observations"
strRapport = strRapport & vbCrLf & "FROM Table_rapport_de_verification INNER JOIN" & _
" Table_importation_de_donnees ON Table_rapport_de_verification.[Numéro rapport] =" & _
" Table_importation_de_donnees.[Numéro rapport]"
strRapport = strRapport & vbCrLf & "WHERE (((Table_rapport_de_verification.[Intitulé du rapport de vérification])=" & Chr(34) & Intitule_Rapport & Chr(34) & "))"
strRapport = strRapport & vbCrLf & "ORDER BY Table_rapport_de_verification.[Intitulé du rapport de vérification], Table_importation_de_donnees.[Numéro de réserve];"
 
CurrentDb.QueryDefs("R_Remplissage_Date").SQL = strRapport
 
Forms![F_Remplissage_Date].Form![F_Remplissage_Date_sous_formulaire].Requery
 
End Sub

J'ai essayé du refresh, du requery, du recalc et pour l'instant rien ne fonctionne.

Merci d'avance pour votre aide.

[cafeine]

Hello,

as-tu essayé directement un truc du genre ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
With Forms("F_Remplissage_Date").Controls("F_Remplissage_Date_sous_formulaire").Form
    .RecordSource = strRapport
    .Requery
End With

PS : Pense aux alias en SQL

Code SQL :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
SELECT MaTableQuelleAunNOMaCoucherDehors.Chp1, 
    MaTableQuelleAunNOMaCoucherDehors.chp2
FROM MaTableQuelleAunNOMaCoucherDehors

est équivalent à

Code SQL :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
SELECT t1.Chp1, t1.chp2
FROM MaTableQuelleAunNOMaCoucherDehors AS t1

ah oui et sinon pense au débogage des requêtes SQL via VBA :
http://cafeine.developpez.com/access...el/debugprint/

[Mus30]

Merci beaucoup cafeine, ton code à très bien marché.

Dire que j'y ai passé l'après midi dessus, j'aurai du poster plus tot ^^

Sinon, pour les alias, c'est vrai que je ne les utilise pas car je ne n'en connaissais pas l'utilisation tout simplement.

C'est mon premier projet sur access et ce que j'ai fait et principalement inspiré des tuto et faq de ce site.


Merci à toute l'équipe d'ailleur.

Je promet d'essayer de coder plus proprement à l'avenir