Discussion :

[ProgElecT]

Apres avoir recherché et lut les divers tutoriel sur le site, il semblerait q'aucune infos ne sois disponnible

Je voudrait recuperer la vidéo d'une webcam brancher sur un port USB.
Est-il possible d'utiliser MCI32.OCX

Comment declarer le type de périphérique MCI par ''DeviceType'', MMMOVIE, OVERLAY ???

Dans le programme de dessin que j'utilise habituellement je demande Importer > Twain > Acquerir
la source selectionné étant PC Camera (6005CCIF) 1.0(32-32)

[avigeilpro]

essaye d'utiliser le composant

Contrôle de numérisation d'images Kodak

j'ai vite regardé et quand je tape:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ImgScan1.OpenScanner

il me donne le choix entre mon scanner et ma webcam.
maintenant je ne sais pas plus l'utiliser. tu n'a qu'a essayer.
Bon courage

[ridan]

salut

tu pourrais aussi chercher des infos sur la dll avicap32.dll.

Bonne prog

[ProgElecT]

Merci pour les sujestions

je programme sous VB6 plate forme WINDOW XP

Apres avoir recuperé sur un PC plate forme Windows 98 les 4 OCXs
lors de la demande d'ajout de ces composants, ma demande est rejeté
"Le fichier 'c:\windows\system\IMGSCAN.OCX'ne peut être enregistré en tant que composant Activex"
Il semblerait donc que XP n'accepte pas ses OCX.

pour ce qui est de avicap.DLL, n'ayant aucune documentation et etant null en anglais !!!!

Mais je vai persister, si je trouve la solution j'en ferai part

[ridan]

salut

voici un petit exemple qui pourrait t'aider : ( en utilisant un PictureBox et un Timer )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Private Declare Function capCreateCaptureWindow Lib "avicap32.dll" Alias "capCreateCaptureWindowA" ( _
     ByVal lpszWindowName As String, _
     ByVal dwStyle As Long, _
     ByVal X As Long, _
     ByVal Y As Long, _
     ByVal nWidth As Long, _
     ByVal nHeight As Long, _
     ByVal hwndParent As Long, _
     ByVal nID As Long) As Long
 
Private Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" ( _
     ByVal hwnd As Long, _
     ByVal wMsg As Long, _
     ByVal wParam As Long, _
     ByRef lParam As Any) As Long
 
Private Const WM_USER As Long = &H400
Private Const WM_CAP_DRIVER_CONNECT As Long = WM_USER + 10
Private Const WM_CAP_DRIVER_DISCONNECT As Long = WM_USER + 11
Private Const WM_CAP_GRAB_FRAME As Long = WM_USER + 60
Private Const WM_CAP_EDIT_COPY As Long = WM_USER + 30
 
Private iResult As Long
 
Private Sub Form_Load()
 
    Timer1.Interval = 50
    iResult = capCreateCaptureWindow("Capture", _
                                    0, 0, 0, _
                                    Picture1.ScaleWidth, _
                                    Picture1.ScaleHeight, _
                                    Me.hwnd, 0)
    SendMessage iResult, WM_CAP_DRIVER_CONNECT, 0, 0
 
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
 
    SendMessage iResult, WM_CAP_DRIVER_DISCONNECT, 0, 0
 
End Sub
 
Private Sub Timer1_Timer()
 
    Clipboard.Clear
    SendMessage iResult, WM_CAP_GRAB_FRAME, 0, 0
    SendMessage iResult, WM_CAP_EDIT_COPY, 0, 0
    Picture1.Picture = Clipboard.GetData
 
End Sub

[ProgElecT]

[ résolu ]

Sa marche !!!
un grand merci ridan

je vois que tu fait parti des moderateurs
Etant depuis peu sur ce site qui me convient parfaitement, je posede des sources deja ziper qui pourrait rendre service mais je n'ai toujours pas compris comment les mettres a dispos lors d'une reponse ou par un autre moyen.
Ne voulant pas saturer la FAQ mais voulant remercier par ma participation, bien qu'ayant recherché en lisant les regles du forum, je ne voudrai pas pertuber son fonctionnement

Un merci renouvelé

Voila 2 minutes que je cherche le tag resolut et ou le mettre ?

[ridan]

salut

il est possible mettre tes sources sur la Page Codes Sources, pour plus d'informations :

Comment Participer à la page codes sources