Discussion :

[virgul]

Bonjour,

Petit truc tout simple enfin je crois.

Il faut que je test si la valeur d'un noeud est vide.

Je sais que pour voir si il y a qqch il faut faire un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:if test="Rue">

Mais si on veut testez si le noeud est vide comment faire un xsl:choose et otherwise ne convient pas à mon problème.


Merci pour votre aide


++
Thierry

[virgul]

ok merci j'ai trouvé la solution de mon problème

mais je ne sais toujours pas et ca m'intéresserais de savoir si on peux tester un noeud pour voir si il est vide?

Merci de votre aide


++

Thierry

[enigma]

Salut Thierry,

Je suis aussi curieux de savoir comment on fait pour voir si un noeud est vide.
J'ai essayé avec un contains (.,'') et aussi avec un string-length().

[GrandFather]

Bonjour,

le test à effectuer dépend de ce que l'on appelle élément vide. Selon qu'on veut tester que l'élément comprenne des éléments fils, des noeuds textuels ou des attributs, ou tout cela à la fois, on utiliser les expressions XPath *, @*, node() ou text(), en conjonction avec l'opérateur not().

Exemples :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
<?xml version="1.0" encoding="UTF-8"?>
<test>
 
	<test1>
	</test1>
 
	<test2></test2>
 
	<test3/>
 
	<test4 aaa="bbb"/>
 
	<test5>
		Texte avec un <b>mot</b> en gras
	</test5>
 
	<test6>
		<truc/>
	</test6>
 
</test>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="text" version="1.0" encoding="UTF-8"/>
 
	<xsl:variable name="linebreak">
<xsl:text>
</xsl:text>
</xsl:variable>
 
	<xsl:template match="/test">
			<xsl:apply-templates select="*"/>
	</xsl:template>
 
	<xsl:template match="*">
		<xsl:value-of select="name()"/><xsl:value-of select="$linebreak"/>
		<xsl:text>not(*) : </xsl:text><xsl:value-of select="not(*)"/><xsl:value-of select="$linebreak"/>
		<xsl:text>not(node()) : </xsl:text><xsl:value-of select="not(node())"/><xsl:value-of select="$linebreak"/>
		<xsl:text>not(text()) : </xsl:text><xsl:value-of select="not(text())"/><xsl:value-of select="$linebreak"/>
		<xsl:text>not(@*) : </xsl:text><xsl:value-of select="not(@*)"/><xsl:value-of select="$linebreak"/>		
		<xsl:value-of select="$linebreak"/>
	</xsl:template>
 
</xsl:stylesheet>

Le résultat est :

test1
not(*) : true
not(node()) : false
not(text()) : false
not(@*) : true

test2
not(*) : true
not(node()) : true
not(text()) : true
not(@*) : true

test3
not(*) : true
not(node()) : true
not(text()) : true
not(@*) : true

test4
not(*) : true
not(node()) : true
not(text()) : true
not(@*) : false

test5
not(*) : false
not(node()) : false
not(text()) : false
not(@*) : true

test6
not(*) : false
not(node()) : false
not(text()) : true
not(@*) : true

[enigma]

Merci, ça peut toujours servir !

[virgul]

Salut,

Merci pour ton petit exemple maintenant je comprend comment je vais faire!!!

Au faite ca ca ne serai pas un truc utile à mettre dans la FAQ XML? A bon entendeur


++

Thierry