Discussion :

[Jay.L]

Bonjour,

j'ai un problème avec un "vieux" programme access que je dois modifier.
Je ne suis pas vraiment calé en access mais je dois quand même m'y atteler.
Je dois, par programmation, vérifier si un champ est présent dans une table liée puis l'ajouter s'il n'y est pas. Je ne sais pas comment retrouver le retour en cas d'erreur.

Voici le code que j'ai utilisé :
__________________

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    Dim rs_emprunt As Recordset
    Set rs_emprunt = gl_db_data.OpenRecordset("SELECT titre2 FROM livre", dbOpenDynaset)

__________________

Qu'est-ce qu'il faudrait faire pour récupérer si oui ou non titre2 a bien pu être "sélecté" ? Car je n'ai rien trouvé là dessus ni dans le forum ni dans la Faq.

Si vous avez une piste ou une autre solution, je suis preneur.
N'hésitez pas à me demander plus d'infos au cas où ...
D'avance, merci.

[loufab]

Bonjour,

Fait une recherche dans le forum, la question a été évoqué en début d'année et le code complet a été fourni.

Cordialement,

[Tofalu]

Bonjour


Accédez à l'objet Database puis TableDefs correspondant
Testez l'existence du champ avec un contrôle d'erreur
Créez le champ en cas d'erreur

A ce titre je ferais quelque chose de générique permettant d'ajouter le champ soit dans une table locale, soit dans la table liée (si elle l'est)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Sub CreerChampSiInexistant(strNomTable As String, strNomChamp As String)
Dim otbl As DAO.TableDef
Dim odb As DAO.Database
Dim strTemp As String
'Accède à la table dans la base de données courante
Set odb = CurrentDb
Set otbl = odb.TableDefs(strNomTable)
 
'Vérifie si la table est une table attachée
If (otbl.Attributes And dbAttachedTable) Then
    'Récupère le nom de la table dans la base distante
    strTemp = otbl.SourceTableName
    'Ouvre la base distante et accède à la table
    Set odb = DBEngine.OpenDatabase(CheminConnect(otbl.Connect), False, False)
    Set otbl = odb.TableDefs(strTemp)
End If
'Crée le champ
CreationChamp otbl, strNomChamp
End Sub
 
 
Sub CreationChamp(otbl As DAO.TableDef, strNomChamp As String)
On Error GoTo err
With otbl
    .Fields.Append .CreateField(strNomChamp, dbText, 50)
End With
 
fin:
Exit Sub
err:
    'Le champ existe déjà, on ne lève pas l'erreur
    'Par contre on lève toutes les autres
    With err
        If .Number <> 3191 Then _
            .Raise .Number, .Source, .Description
    End With
Resume fin
End Sub
Function CheminConnect(strChemin As String) As String
Dim i As Integer
Dim temp() As String
temp = Split(strChemin, ";")
For i = 0 To UBound(temp)
    If temp(i) Like "DATABASE=*" Then
        CheminConnect = Trim(Mid(temp(i), 10))
        Exit For
    End If
Next i
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub essai()
 
CreerChampSiInexistant "TBL_GROUPE", "essai"
End Sub

On pourrait faire encore plus générique notamment en spécifiant les propriétés du champ. Ici, elles sont définies dans la sub CreationChamp