Discussion :

[thorgal85]

bonjour,

Avec ce code j'arrive à lister les url des images d'un page HTML

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Set MaPageHtml = IE.document
 
For i = 0 To MaPageHtml.images.length - 1 'boucle sur les images
    Set imgHtml = MaPageHtml.images.Item(i)
 
    If InStr(laListe, imgHtml.src) = 0 Then 'controle des doublons dans la page
    laListe = laListe & imgHtml.src & vbLf
    Form1.ListUrl.AddItem imgHtml.src 'adresse image
 
    End If

Comment puis-je télécharger dans un répertoire ces images ?

[Mandalar]

je ne comprends pas exactement comment fonctionne ton code mais je connais un moyen pour copier un fichier d'une addresse web vers l'ordi :

dans un formulaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, ByVal szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long

et pour appeler la fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

URLDownloadToFile 0, URL, destination, 0, 0

[thorgal85]

merci pour l'aide !

J'utilise la fonction ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

URLDownloadToFile 0, "http://www.dvdfr.com/images/dvd/cover_200x280/0/439.jpg", "C:\", 0, 0

L'URL est contenue dans une varianble string normalement. Si je vais dans C:\ je ne vois pas de fichier image ? Il n'y a pas de message d'erreur ! Qu'est-ce que j'oublie ?

[Mandalar]

il faut que tu mettes "C:\image.jpg" a la place de "C:\"
ainsi le fichier "image.jpg" sera créé et contiendra ton image

[thorgal85]

j'ai modifié le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

URLDownloadToFile 0, Tmp, "X:\" & Titre & ".jpg", 0, 0

Sur mon lecteur X:\ je ne vois rien d'enregistré !! ou ai-je commis une boulette ?

[thorgal85]

milles escuses !!! j'implore le pardon.......c'est moi qui ai fait la boulette !! il y avait un " de trop dans ma variable string !! Désolé donc .....et ça marche....donc !! pardon, pardon.......

[Mandalar]

euh pas la peine de t'excuser
ajoute simplement le tag [résolu] par contre ce serait sympas

[Rémiz]

Salut,

En fait j'utilise cette fonction et elle marche bien. Le problème, c'est que l'image sur le web est rafraichie toutes les 5 secondes, et pourtant je charge tout le temps la même image. Comme si la fonction allait chercher le fichier en mémoire cache...

Que faire ? Y a t il une option à modifier ? Merci

[DarkVader]

Veuillez créer un nouveau thread plutôt que faire remonter celui-là si vous désirez poursuivre, quitte à y faire référence par un lien
car le problème soulevé ne consiste pas en une précision sur le sujet.

Urldownloadtofile charge un fichier distant en une seule opération ponctuelle - ce n'est donc pas le problème
et sans voir le code dans lequel la fonction est utilisée, difficile de se faire une idée.

[Rémiz]

le problème soulevé ne consiste pas en une précision sur le sujet.

Ah bon ? Pourtant je parle bien de "Télécharger une image d'une page web" comme le titre du message l'annonce...Je parle bien d'une précision sur le sujet, si si !

Quand à mon code, ben rien de compliqué, j'appelle juste la fonction dans une boucle pour enregistrer les images d'une page (provenant d'une webcam). Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub Bo_Demarrer_Click()
 
    Dim URL As String, Destination As String, No As Long
 
    URL = "http://212.86.4.14/camera_image/image.jpg"
 
    Do
        No = No + 1
        Destination = "Fichiers\Image " & No & ".jpg"
        URLDownloadToFile 0, URL, Destination, 0, 0 'chargement de l'image
        Sleep 10000 'Fonction d'attente pour 10 secondes
    Loop
 
End Sub

Voilà, a+

[DarkVader]

Il est plus probable que l'image n'est pas modifiée-
afin de lever le doute, supprime le fichier du cache avec DeleteUrlCacheEntry.

[SfJ5Rpw8]

tiens j'ai trouvé ça

http://www.autohotkey.com/docs/comma...loadToFile.htm

ce qui donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

URLDownloadToFile 0, URL & "?FauxParam=" & No, Destination, 0, 0 'chargement de l'image

? elle est ou ta webcam ?...

[Rémiz]

Merci de vos réponses, ça marche !

Bbil : Ta méthode marche, mais ça va créer un nouveau fichier à chaque fois dans la cache, ce qui prend de la place sur le disque dur au bout d'un moment. La camera est en Finlande du sud ouest, dans le centre ville de Pori pour être précis C'est pour m'amuser à voir l'évolution du climat au fil du temps...

DarkVader : oui, ça marche bien avec DeleteUrlCacheEntry !!! Sans, vb va lire la cache.

Voici donc le code dans le module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Public Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, ByVal szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
Public Declare Function DeleteUrlCacheEntry Lib "WININET.DLL" Alias "DeleteUrlCacheEntryA" (ByVal lpszUrlName As String) As Long
Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Et dans le Form :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub Bo_Demarrer_Click()
 
    Dim URL As String, Freq As Long
    Dim No As Long, Destination As String
 
    Freq = InputBox("Donnez la période de rafraichissement (en secondes)")
    URL = "http://212.86.4.14/camera_image/image.jpg"
 
    Do
        No = No + 1
        Destination = "Fichiers\Image " & No & ".jpg"
        DeleteUrlCacheEntry URL
        URLDownloadToFile 0, URL, Destination, 0, 0 'chargement de l'image
        Sleep Freq * 1000 'Fonction d'attente pour Freq secondes
    Loop
 
End Sub

A+