Discussion :

[Toftof]

Bonjour,

Je sais envoyer et lie des mails depuis OutLook (je le précise pout le cas où cela intéresserait qq'un). Mais chez mon client, il me demande d'en faire autant avec Lotus Notes. J'ai trouvé comment envoyer un mail avec gestion des propriétés. Par contre, pour ce qui est de la réception, rien de satisfaisant n'est venu éclairer de manière durable mon horizon.

Si vous avez quelque chose pour moi, je vous en remercie d'avance.

[Frank]

Merci de regarder la FAQ.

Il y a me semble t'il des liens qui pourront t'aider.

[Kloun]

Qu'est ce que tu entends par réception ?

[random]

ben on pourrait commencer par ajouter la référence lotus note
puis lancer l'explorateur d'objet pour voir un peu ...

[Toftof]

Pour ce qui est de consulter le site, c'est déjà fait:
1/ Dans la FAQ, il n'y a que comment envoyer un mail (d'ailleurs, il me semble que c'est ma source)

2/ Dans les forums, il y a un début de solution basé sur une connexion ODBC mais je n'ai pas réussi à l'implémenter.

Depuis Access, j'ai cherché les propriétés d'un objet Notes mais rien ne s'affiche (contrairement à OutLook). C'est pourquoi je ne sais toujours pas identifier un nouveau mail ni en extraire le contenu.

Ce que je cherche à faire c'est :
1/ Identifier un nouveau mail
2/ En extraire le corps et le destinataire
3/ En extraire la pièce jointe
4/ Marquer le message comme lu

Et là ...

[Kloun]

Un lien qui va bien : http://www-12.lotus.com/ldd/doc/domi...n?OpenFrameset

et un bout de code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
Option Compare Database
Option Explicit
 
Dim iNot_Session As New Domino.NotesSession
Dim iNot_Document As New Domino.NotesDocument
Dim iNot_DocCollection As New Domino.NotesDocumentCollection
Dim iNot_MailDB As Domino.NotesDatabase
Dim iNot_DBDir As New Domino.NotesDbDirectory
Dim iNot_ArchiveDB As Domino.NotesDatabase
 
Function RecupFichierJoint() As Integer
Dim item As NotesRichTextItem
Dim obj As Variant
Dim iStr_Subject As String
Dim iStr_NomFichier As String
Dim iLng_NbDocument As Long
Dim iBol As Boolean
 
Dim Compteur As Integer
Dim iStr_Dir As String
Dim i As Long
 
    'On Error GoTo Erreur
    ecritStatus "Récupération des fichiers joints en cours ..."
    ecritLog "Début de la récupération des fichiers joints."
    Compteur = 0
    Set iNot_Session = Nothing
    iNot_Session.Initialize "toto" ' password eventuel
    Set iNot_DBDir = iNot_Session.GetDbDirectory("")
    Set iNot_MailDB = iNot_DBDir.OpenMailDatabase
    Set iNot_ArchiveDB = iNot_Session.GetDatabase("", "LeNomCompletDeLArchive.nsf")
    iStr_Dir = fngGetParamString("Type", "Dir")
 
'    Set iNot_ArchiveDB = iNot_DBDir.GetFirstDatabase(NOTES_DATABASE)
'    While Not IsNull(iNot_ArchiveDB)
'       Debug.Print iNot_ArchiveDB.FilePath
'       Set iNot_ArchiveDB = iNot_DBDir.GetNextDatabase
'    Wend
 
    If Not iNot_ArchiveDB.IsOpen Then
        iNot_ArchiveDB.Open
    End If
 
    If Not iNot_MailDB.IsOpen Then
        iNot_MailDB.Open
    End If
 
    Set iNot_DocCollection = iNot_MailDB.AllDocuments
    Set iNot_Document = iNot_DocCollection.GetFirstDocument
    iLng_NbDocument = iNot_DocCollection.Count
    For i = 0 To iLng_NbDocument - 1
        If i <= iNot_DocCollection.Count Then
            If TestDocumentNotes <> 0 Then
                GoTo Fin
            End If
            iStr_Subject = iNot_Document.GetFirstItem("Subject").Values(0)
            'Debug.Print iStr_subject
            If iStr_Subject = "Sujet1" Or iStr_Subject = "Sujet2" Then
                'Set iNot_DocumentCopie = New NotesiNot_Documentument '(iNot_ArchiveDB)
                If ArchiveDocNotes <> 0 Then
                    GoTo BoucleNext
                End If
                'Debug.Print iNot_Document.Created & " - " & iStr_subject
                Set item = iNot_Document.GetFirstItem("Body")
                If (item.Type = RICHTEXT) Then
                    If Not IsEmpty(item.EmbeddedObjects) Then
                        For Each obj In item.EmbeddedObjects
                            If (obj.Type = EMBED_ATTACHMENT) Then
                                iStr_NomFichier = obj.Name
                                If iStr_NomFichier <> "" Then
                                    'iStr_NomFichier = right(iStr_NomFichier, Len(iStr_NomFichier) - 3)
                                    'iStr_NomFichier = left(iStr_NomFichier, InStr(1, iStr_NomFichier, ".") + 3)
                                    ecritLog "Fichier récupéré : " & iStr_NomFichier
                                    obj.ExtractFile (iStr_Dir & iStr_NomFichier)
                                    Compteur = Compteur + 1
                                End If
                            End If
                        Next
                    End If
                End If
                iBol = True
            End If
            If iBol Then
                iNot_Document.Remove False
                iBol = False
                Set iNot_DocCollection = Nothing
                Set iNot_MailDB = Nothing
                Set iNot_ArchiveDB = Nothing
                Set iNot_DBDir = Nothing
                Set iNot_Session = Nothing
                iNot_Session.Initialize "toto"
                Set iNot_DBDir = iNot_Session.GetDbDirectory("")
                Set iNot_MailDB = iNot_DBDir.OpenMailDatabase
                Set iNot_DocCollection = iNot_MailDB.AllDocuments
                Set iNot_Document = iNot_DocCollection.GetFirstDocument
                Set iNot_ArchiveDB = iNot_Session.GetDatabase("", "LeNomCompletDeLArchive.nsf")
                iLng_NbDocument = iNot_DocCollection.Count
                i = 0
            Else
BoucleNext:
                Set iNot_Document = iNot_DocCollection.GetNextDocument(iNot_Document)
            End If
        End If
    Next
Fin:
    ecritLog Compteur & " fichiers récupérés."
    ecritLog "Récupération des fichiers terminée."
    RecupFichierJoint = 0
    GoTo FinFonction
Erreur:
    ecritLog "Erreur : " & Err.Number & " - " & Err.Description
    RecupFichierJoint = 1
FinFonction:
    Set iNot_DocCollection = Nothing
    Set iNot_MailDB = Nothing
    Set iNot_ArchiveDB = Nothing
    Set iNot_DBDir = Nothing
    Set iNot_Session = Nothing
    ecritStatus "Récupération des fichiers terminée."
    LogFermeturePossible
End Function
 
Function TestDocumentNotes() As Integer
Dim iStr As String
Dim i As Integer
    On Error GoTo Erreur
    iStr = iNot_Document.GetFirstItem("Subject").Values(0)
    TestDocumentNotes = 0
    Exit Function
Erreur:
    If Err.Number = 429 Then
        TestDocumentNotes = -1
    Else
        Set iNot_Document = iNot_DocCollection.GetNextDocument(iNot_Document)
        i = TestDocumentNotes
        If i = -1 Then
            TestDocumentNotes = -1
        End If
    End If
End Function
 
Function ArchiveDocNotes() As Integer
    On Error GoTo Erreur
    iNot_Document.CopyToDatabase iNot_ArchiveDB
    ArchiveDocNotes = 0
    Exit Function
Erreur:
    ArchiveDocNotes = -1
End Function

Je m'en sers pour récupérer les pièces jointes des mails dont le sujet est Sujet1 ou Sujet2.
Les mails sont ensuite archivés et effacés.
Il faut ajouter la réf Lotus Domino Objects.
Ca fonctionnait sous Lotus 5 et ça fonctionne avec la 6.5

[Toftof]

Super !
Mon test ne s'est pas bien passé maius j'y retourne cette après-midi.

En tout cas, merci beaucoup !
Je vous tiens au courant

[Toftof]

Alors là, grand merci Mon Sieur !
... et chapeau bas.

Par contre, attention pour ceux qui voudraient utiliser : il y a un système de fonctions écrites par notre inspirateur qui lui servent à créer des LOG. Donc, vous rencontrerez des erreurs de compilations si vous ne les enlevez ou ne les réécrivez pas .