Discussion :

[Gabout]

Bonjour,

[Access 20000] Envoyer un email depuis Access avec SendObject... pas de problème.

Je cherche comment spécifier dans cet envoi une ou des pièces jointes (exemple fichier PDF).

Quelqu'un aurait-il une idée ?

[Gabout]

Autant pour moi : j'ai trouvé dans la FAQ ce qui me fallait ! "Comment envoyer un mail avec une pièce attachée ?" de Papy turbo

Je vais étudier cela de près, désolé !

[Gabout]

Re-désolé, le code proposé par Papy turbo fait référence à des types non décrits genre CDOMessage, etc. ou peut être le code est-il prévu pour une version > Access 2000 !!

Je suis donc de nouveau attentif à vos suggestions ...

[vodiem]

Etienne Bar alors ?
ici

[Gabout]

Merci du tuyau Vodiem,

Mais je suis sur Thunderbird... et même en remplaçant les données de Outloock par Thunderbird, Access ne reconnait pas le type :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim oEmail As Thunderbird.Application

[delcroixf]

As tu déclaré ton application dans les références ?

[Gabout]

Oui, tout était déclaré... mais j'ai sèché.

Par contre j'ai récupéré un code en Belgique qui, une fois adapté, semble bien fonctionner :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Option Compare Database
Option Explicit
 
'Envoyer un message avec une pièce jointe
'SendMailCDO "origine@domaine.fr", _
'        "destinataire@domaine.fr", _
'        "Test d'envoi de Gabout avec pièce jointe", _
'        "Ceci n'est qu'un test", , , _
'        "C:\joe_20060720_0166_0014.pdf"
 
Function SendMailCDO(Sender As String, Receiver As String, _
                     Subject As String, BodyText As String, _
                     Optional Cc As String, Optional Bcc As String, _
                     Optional PJ As String)
    Dim Cdo_Message As New CDO.Message
    Set Cdo_Message.Configuration = GetSMTPServerConfig()
    With Cdo_Message
        .To = Receiver
        .From = Sender
        .Subject = Subject
        .Cc = Cc
        .Bcc = Bcc
        .TextBody = BodyText
        .AddAttachment (PJ)
        .send
    End With
    Set Cdo_Message = Nothing
End Function
 
Function GetSMTPServerConfig() As Object
    Dim Cdo_Config As New CDO.Configuration
    Dim Cdo_Fields As Object
    Set Cdo_Fields = Cdo_Config.Fields
    With Cdo_Fields
        .Item(cdoSendUsingMethod) = cdoSendUsingPort
        .Item(cdoSMTPServer) = "smtp.free.fr"
        .Item(cdoSMTPServerPort) = 25
        .Update
    End With
    Set GetSMTPServerConfig = Cdo_Config
    Set Cdo_Config = Nothing
    Set Cdo_Fields = Nothing
End Function

Ne pas oublier de référencer Microsoft CDO for Windows 2000 Library

Donc, si cela peut aider quelqu'un...

Grand merci de votre aide à tous,

[vodiem]

merci Gabout, j'ai pas d'affinité particulière avec Outlook alors avoir une solus pour s'en passer c'est pas pour me déplaire.
merci de nous avoir fait partager tes recherches!