VBA ACCESS : Axes des graphiques

**Janny** · 09/05/2007, 17h32

Bonjour à tous

J'ai un graphique que je code en VBA Access.
Il contient deux courbes. Ces deux courbes sont deux choses différentes et d'échelles différentes.
Je souhaiterai sélectionner une des deux courbes et lui ajouter un axe secondaire à droite, afin d'avoir trois axes : une abscisse et deux ordonnées.
De plus j'aimerai savoir comment afficher le nom des axes sur le graphique en code VBA.

Merci, je débute en VBA et je bloque dessus depuis un moment !!

Pour plus d'info, mon graphique est un objet Microsoft Graph Chart !!!!

**alexandrebergercyr** · 11/05/2007, 20h52

Je ne crois pas que c'est possible dans un objet " Microsoft Graph Chart "
Pour ce qui est des noms des axes, tu dois double-cliquer en mode création sur ton graphique. Ensuite, tu cliques sur le bouton droite da ta souris et tu vais dans option du graphique.

Désolé pour la mauvaise nouvelles des deux axes...
Le seul type que je vois qui pourrais avoir deux axes est celui de surfaces...

Bonne chance Jannie
Alexxx

**Janny** · 14/05/2007, 08h30

Merci pour cette réponse, c'est vrai que je commençais à douter car je n'ai trouvé aucune info sur internet.

En revanche, étant donné qu'il est possible de mettre un second axe manuellement (clic droit sur la série en question, format de la série de données, axes, cocher axe secondaire) il doit etre possible normalement de le faire avec le code !

Je ne sais pas trop ce que je vais faire.....

Merci

**Jusomi31** · 14/05/2007, 13h35

Bonjour Janny,

J'ai essayé de rajouter un axe secondaire (pour obtenir 2 axes en ordonnées).
J'arrive à les rajouter mais pas à définir une échelle correcte (ça dépend aussi de tes données). J'espère que le morceau de code pourra t'aider.

Bon courage !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Sub secondAxe()
    Charts.Add
    ActiveChart.ChartType = xlLineMarkers
    ActiveChart.SetSourceData Source:=Sheets("liste").Range("C6:E13"), PlotBy:= _
        xlColumns
    ActiveChart.Location Where:=xlLocationAsObject, Name:="liste"
    ActiveChart.HasLegend = True
    ActiveChart.Legend.Select
    Selection.Position = xlRight
    ActiveChart.SeriesCollection(2).Select
    ActiveChart.SeriesCollection(2).AxisGroup = 2
    ActiveChart.Axes(xlValue, xlSecondary).Select
    With ActiveChart.Axes(xlValue, xlSecondary)
        .MinimumScaleIsAuto = True
        .MaximumScale = 22
        .MinorUnitIsAuto = True
        .MajorUnitIsAuto = True
        .Crosses = xlAutomatic
        .ReversePlotOrder = False
        .ScaleType = xlLinear
        .DisplayUnit = xlNone
    End With
End Sub

**micniv** · 14/05/2007, 21h38

Bonsoir,

Pour continuer sur la bonne note de Jusomi31 ... et pour faire avancer le schmilblick , voici un bout de code qui permet de rafraichir les échelles et de mettre un titre a l'axe secondaire , reste encore à "créer cet axe" via VBA (ici, je l'ai créé manuellement)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub cmdAddSecondAxeY_Click()
 
    Dim AxeY2 As Object
    Dim GraphObj As Object
    'On Error GoTo Erreurs
 
    Set GraphObj = Me![xChart2]
 
    'Set AxeDesX = GraphObj.Object.Application.Chart.Axes(1)
    Set AxeY2 = GraphObj.Object.Application.Chart.Axes(2, xlSecondary)
 
    With AxeY2
        .ScaleType = xlScaleLinear     '  -4133:xlScaleLogarithmic
        .MinimumScale = 20
        .MinimumScaleIsAuto = False
        .MaximumScale = 50
        .MaximumScaleIsAuto = False
        .MinorUnit = 2
        .MinorUnitIsAuto = False
      '  .HasMinorGridlines = True      'Not applicable
        .MajorUnit = 10
       .MajorUnitIsAuto = False
     '   .HasMajorGridlines = True     'Not applicable
        .Crosses = xlAutomatic
        .ReversePlotOrder = False
        .ScaleType = xlLinear
        .DisplayUnit = xlNone
        .HasTitle = True
    .AxisTitle.Text = "July Sales"
 
    End With
 
    GraphObj.Requery
 
    Set AxeY2 = Nothing
    Set GraphObj = Nothing
 
End Sub

**Janny** · 15/05/2007, 09h32

Merci pour ces réponses je vais essayer cela de suite !!!!
(Même si j'avais déjà essayé avec xlsecondary et que ça ne marchait pas (erreur) peut etre parce qu'on est pas sous Excel mais sous Access)

**Janny** · 15/05/2007, 10h43

c'est bon ça marche !!!!
voici le code pour ceux que ça intéresse :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
Public Function graph_capteur_change(id_capteur As Long, erreur As String) As Boolean
On Error GoTo ErrHandler
 
    Dim strquery As String
    Dim myrec As Recordset
    Dim str_graph As String
    Dim str_graph1 As String
    Dim str_graph2 As String
    Dim sensibilite As Double
    Dim linearite As Double
    Dim date_etal As Date
    Dim isgraph As Boolean
    Dim AxeY2 As Object
 
    'initialisation
    Form_frm_information_capteur.graph_capteur.RowSource = ""
    isgraph = False
    str_graph = "Date d'étalonnage;Sensibilité à 25°C;Erreur de linéarité (en %)"
 
    ' On sélectionne la sensibilite à 25°C, la linearite et la date de relevee selon le capteur sélectionné à l'arrivée
    strquery = "SELECT date_arrivee, sensibilite_25, linearite FROM tbl_209_capteur " & _
               "WHERE id_capteur = " & id_capteur & ";"
    If Not mod_sql.sql_open_recordset_v1(strquery, myrec, erreur) Then Err.Raise 513, , erreur
 
    While Not (myrec.EOF)
        ' On les ajoute dans le graphe
        sensibilite = myrec.Fields(1)
        linearite = myrec.Fields(2)
        date_etal = myrec.Fields(0)
        ' Chaîne de construction du graphe
        str_graph = str_graph & ";" & date_etal & ";" & sensibilite & ";" & linearite
        myrec.MoveNext
        'construction du graph
        graph_capteur.RowSource = str_graph
        graph_capteur.Object.Application.PlotBy = 1
        graph_capteur.Object.Application.PlotBy = 2
        isgraph = True
    Wend
 
    ' On sélectionne les sensibilites à 25°C, les linearites et les dates de relevees selon le capteur sélectionné lors des étalonnages
    strquery = "SELECT date_calib, sensibilite_25, linearite FROM tbl_209_calib_capteur " & _
               "WHERE idx_capteur = " & id_capteur & " " & _
               "ORDER BY date_calib ;"
    If Not mod_sql.sql_open_recordset_v1(strquery, myrec, erreur) Then Err.Raise 513, , erreur
 
    While Not (myrec.EOF)
        ' On les ajoute dans le graphe
        sensibilite = myrec.Fields(1)
        linearite = myrec.Fields(2)
        date_etal = myrec.Fields(0)
        ' Chaîne de construction du graphe
        str_graph = str_graph & ";" & date_etal & ";" & sensibilite & ";" & linearite
        myrec.MoveNext
        'construction du graph
        graph_capteur.RowSource = str_graph
        graph_capteur.Object.Application.PlotBy = 1
        graph_capteur.Object.Application.PlotBy = 2
        isgraph = True
    Wend
    'type du graphique
    graph_capteur.ChartType = xlXYScatterLines
    'création du deuxième axe
    graph_capteur.SeriesCollection(2).AxisGroup = 2
    Set AxeY2 = graph_capteur.Object.Application.Chart.Axes(2, xlSecondary)
 
    graph_capteur.Refresh
    graph_capteur_change = True
 
Exit Function
ErrHandler:
    graph_capteur_change = False
    erreur = "graph_capteur_change : " & Err.Number & " : " & Err.Description
End Function

J'ai mis le nom de l'axe manuellement et il a l'air de le conserver.

Mon problème maintenant concerne l'échelle de l'abcsisse.
En effet, ce sont des dates. Le problème survient quand je n'est qu'une donnée sur mon graph, l'échelle commence au 00/01/1900.
Quand je suis allée dans les propriétés de l'axe pour modifier l'échelle, je me suis rendue compte que les dates sont transformées en nombre et je ne vois pas à quoi ça correspond !!!!
Quelqu'un peut-il m'aider ???

**Janny** · 15/05/2007, 16h11

J'ai résolu ce problème : on peut mettre des dates en bornes qui sont automatiquement transformé en chiffres !!!!!

**micniv** · 15/05/2007, 19h31

Envoyé par Janny

:
J'ai mis le nom de l'axe manuellement et il a l'air de le conserver.

Pour info, mon code ci-dessus s'applique un graphe access
et pour mettre à jour le titre via VBA tu as donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
    With AxeY2
        .HasTitle = True
        .AxisTitle.Text = "July Sales"
    End With

Vale !

VBA ACCESS : Axes des graphiques

VBA Access

Discussions similaires

Partager

Partager