Discussion :

[hnokia]

Bonjour !

Je voudrais pouvoir piloter une base de données Access depuis VBA excel, et importer ainsi des fichiers csv sous forme de table.
la raison est que ces fichiers csv seront victimes de traitement par la suite, et qu'il serait plus facile d'avoir ces fichiers csv en entrée sous forme de tables access.

en fait, je voudrais pouvoir faire depuis excel ce qu'on peut faire sous access par les menus; comme ça :

sous MSAccess :
file>get external data>import
'on sélectionne alors le fichier csv à importer; les champs étant délimités par des ";"
on importe le csv dans une nouvelle table, dont on choisit le nom
la 1ère ligne du csv contient les identifiants des colonnes, donc idéalement ils apparaissent comme les noms des champs de la nouvelle table.

je souhaite automatiser ca en VBA sous Excel.

pour le moment, je suis parti sur ça : (mais ça ne marche pas du tout :-( )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
'un getopenfilename pour sélectionner le fichier csv qu'on souhaite traiter:
NomFichier = Application.GetOpenFileName(filefilter:=("Fichier texte (*.csv),*.csv"), Title:="Ouvrir un fichier")
 
docmd.transferspreadsheet acImport, acspreadsheettypeexcel9, "maTable", "maBdD", True, "A1:B10"

si je tapes directement ca dans VBA, ca ne marche pas, j'ai des messages d'erreur au niveau du "docmd". y'a t'il des mots clé à taper ou je sais pas au début du code pour dire qu'on travaille sur la BdD access ? ou faut-il procéder autrement ?

[ouskel'n'or]

Pourquoi ne pas importer directement les csv dans Access ?

[SilkyRoad]

bonjour

Tu peux tester cette procédure qui transfère directement le contenu du fichier CSV vers une nouvelle table Access, à partir d'une macro Excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Sub tranfertCSV_Vers_NouvelleTableAccess()
    'Transfére un fichier CSV vers une nouvelle table Access
    'depuis une macro Excel.
    '
    'Nécessite d'activer la référence
    '"Microsoft ActiveX Data Objects x.x Library
    '
 
    Dim AccessCn As ADODB.Connection
    Dim AccessRst As ADODB.Recordset
    Dim Csv_CN As New ADODB.Connection
    Dim Csv_Rst As New ADODB.Recordset
    Dim DossierCSV As String, NomTable As String
    Dim FichCSV As String, MaBase As String
    Dim nbEnr As Long
 
    'Répertoire du fichier CSV
    DossierCSV = "C:\Documents and Settings\mimi\dossier"
    'Nom du fichier CSV à transfèrer
    FichCSV = "LeFichierCSV.csv"
    'Chemin et nom de la base Access
    MaBase = "C:\Documents and Settings\mimi\dossier\dataBase.mdb"
    'Nom de la nouvelle Table Access
    NomTable = "MaNouvelleTable"
 
 
    'Connection au fichier CSV
    Csv_CN.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
        DossierCSV & ";Extended Properties='text;FMT=Delimited'"
    'Requète dans le fichier CSV
    Csv_Rst.Open "SELECT * FROM " & FichCSV, Csv_CN, _
        adOpenStatic, adLockOptimistic
 
    'Connection à la base de données Access
    Set AccessCn = New ADODB.Connection
    AccessCn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                   "Data Source=" & MaBase
 
 
    Csv_CN.Execute "SELECT * INTO [" & NomTable & "] IN '" & _
        MaBase & "' From [" & FichCSV & "]", nbEnr
 
 
    AccessCn.Close
    Csv_Rst.Close
    Csv_CN.Close
    Set AccessRst = Nothing
    Set AccessCn = Nothing
    Set Csv_Rst = Nothing
    Set Csv_CN = Nothing
End Sub

michel