Discussion :

[Bubut]

Bonjour forum,

Donc je vais vous expliquer mon petit problème avec access et VBA.

Donc j'ai une table Produit et une table Devis je souhaiterai, par l'intermédiaire d'un formulaire récupérer des valeurs sélectionné dans le formulaire (formulaire rattaché à la table devis) en utilisant la Fonction DLookup.

Mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub Référence_AfterUpdate()
On Error GoTo Err_Référence_AfterUpdate
 
    Dim strFiltre As String
 
     ' Définit le filtre avant d'être utilisé dans la fonction DLookup.
    strFiltre = "[Référence] = " & Me![Référence]
 
     ' Recherche le Commentaire Réf du produit et l'assigne au contrôle Commentaire Réf.
    Me![Commentaire Réf] = DLookup("[Commentaire Réf]", "T_Référence / Type", strFiltre)
 
     ' Recherche le Descriptif Réf du produit et l'assigne au contrôle Descriptif Réf.
    Me![Descriptif Réf] = DLookup("[Descriptif Réf]", "T_Référence / Type", strFiltre)
 
     ' Recherche le Prix Tarif Réf du produit et l'assigne au contrôle Prix Tarif Réf.
    Me![Prix Tarif Réf] = DLookup("[Prix Tarif Réf]", "T_Référence / Type", strFiltre)
 
     ' Recherche la Remise Réf (%) du produit et l'assigne au contrôle Remise Réf (%).
    Me![Remise Réf (%)] = DLookup("[Remise Réf (%)]", "T_Référence / Type", strFiltre)
 
 
Quitte_Référence_AfterUpdate:
    Exit Sub
 
Err_Référence_AfterUpdate:
    MsgBox Err.Description
    Resume Quitte_Référence_AfterUpdate
End Sub

Lorsque j'excecute mon formulaire et que je choisis la référence, ilo me met un message d'erreur :

Erreur de syntaxe (opérateur abscent) dans l'expression 'Référence = TSX 37 21 101'

Donc si quelqu'un peut m'aider, merci d'avance.
Bubut

[mout1234]

Comme trés frquément évoqué sur ce forum, il ne faut pas oublier en SQL les syantaxes propres à chque type de données.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

strFiltre = "[Référence] = '" & Me![Référence] & "'"

En passant, ton code peut être optimisé en remplaçant tes 4 dlookup (représentant donc l'équivalent de 4 requêtes) par un recordset.

C'est mon jour de bonté : voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
    Dim orst As DAO.Recordset
 
    Set orst = CurrentDb.OpenRecordset("SELECT * FROM [T_Référence / Type] WHERE [Référence] = '" & Me![Référence] & "'")
    If Not orst.EOF Then
        Me![Commentaire Réf] = orst![Commentaire Réf]
        Me![Descriptif Réf] = orst![Descriptif Réf]
        Me![Prix Tarif Réf] = orst![Prix Tarif Réf]
        Me![Remise Réf (%)] = orst![Remise Réf (%)]
   End If
   orst.Close: Set orst = Nothing

[jean-paul lepetit]

Salut,
je pense qu'il y a une erreur au niveau du strFiltre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub Référence_AfterUpdate()
On Error GoTo Err_Référence_AfterUpdate
 
    Dim strFiltre As String
 
     ' Définit le filtre avant d'être utilisé dans la fonction DLookup.
    strFiltre = "[Référence] = '" & Me![Référence] &"'"
 
     ' Recherche le Commentaire Réf du produit et l'assigne au contrôle Commentaire Réf.
    Me![Commentaire Réf] = DLookup("[Commentaire Réf]", "T_Référence / Type", strFiltre)
 
     ' Recherche le Descriptif Réf du produit et l'assigne au contrôle Descriptif Réf.
    Me![Descriptif Réf] = DLookup("[Descriptif Réf]", "T_Référence / Type", strFiltre)
 
     ' Recherche le Prix Tarif Réf du produit et l'assigne au contrôle Prix Tarif Réf.
    Me![Prix Tarif Réf] = DLookup("[Prix Tarif Réf]", "T_Référence / Type", strFiltre)
 
     ' Recherche la Remise Réf (%) du produit et l'assigne au contrôle Remise Réf (%).
    Me![Remise Réf (%)] = DLookup("[Remise Réf (%)]", "T_Référence / Type", strFiltre)
 
 
Quitte_Référence_AfterUpdate:
    Exit Sub
 
Err_Référence_AfterUpdate:
    MsgBox Err.Description
    Resume Quitte_Référence_AfterUpdate
End Sub

comme ta référence est du texte, il faut lui rajouter un apostrophe avant et après

[Bubut]

Merci beaucoup de m'avoir aidé aussi rapidement, je ne voyai pas mon erreur.

A+
Bubut