Controler la saisie d'une cellule

**HAFNI84** · 27/05/2007, 17h53

bonjour tout le monde j'ai un souci d'excel je veux savoir comment je peux
controler la saisie d'une cellule excel par exemple je veux que la valeur de la cellule soit numérique et soit composé de 5 chiffres seulement

**dadavyvy** · 27/05/2007, 20h21

Conformément à ce que tu demandes... ("5 chiffres" me parait bizarre, car 12345 c'est ok, mais 1.2345 aussi)

A mettre dans le module de la feuille en question. Controle sur la plage de saisie A1:A5 (donc a adapter)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim sRange As Range, sCell As Range
    Set sRange = Range("A1:A5") 'zone de saisie
    If Not Intersect(Target, sRange) Is Nothing Then
    ' verifie seulement les cellules modifiées dans la plage de saisie
        For Each sCell In Intersect(Target, sRange)
            If sCell <> "" Then ' ignore les cellules vides
                If Not IsNumeric(sCell) Then  ' non numerique
                    MsgBox "Erreur cellule [" & sCell.Address(False, False) & "] : non numerique"
                Else  ' controle des 5 chiffres
                    ' donc 12345 = ok, 1.2345 = ok aussi
                    temp = CStr(sCell.Value)
                        ' supprime les virgules
                    temp = Replace(temp, ",", "", , , vbTextCompare)
                    temp = Replace(temp, ".", "", , , vbTextCompare)
                    If Len(temp) <> 5 Then ' 5 chiffres exactement
                        MsgBox "Erreur cellule [" & sCell.Address(False, False) & "] : 5 chiffres max"
                    End If
                End If
            End If
        Next sCell
    End If
End Sub