comparaison de fichiers LIGNE PAR LIGNE

**bzhbzh** · 14/07/2007, 22h17

Bonjour, j’ai un probleme de comparaison de fichiers.
j’ai 2 fichiers excel au même format et je voudrais les comparer ligne par ligne.
Si une ligne est presente dans les 2 fichiers : elle est commune
Si une ligne ne se trouve que dans un seul fichier : elle est spécifique
Après la comparaison : generer un fichier avec les communes et un autre avec les specifiques.
Exemple de lignes :
SPAG01445: Rev V MCA02C0111 - Rev :A ERO SPAG000598501 - Rev :V 3 092,47 -363,31 1 439,73 -176,52 19,95 -160,38 8200380896 --D 1.0 XES 8200380905 --C 1.5 XE_280_P_SL 8200380886 --E 0.65 XES

J’ai a peu près 1500 lignes dans chaque fichier et 25 colones
Je ne sais pas effectuer ce type de manipulation et je voudrais eviter de le faire manuelement.
ci-joint extrait de fichier
merci de me faire signe si qlq est disponible

**kiki29** · 15/07/2007, 00h18

voir sur http://frederic.sigonneau.free.fr/

**bzhbzh** · 15/07/2007, 09h35

merci,
je cherche et espère pouvoir regler ça pour demain

**kiki29** · 15/07/2007, 11h35

En plaçant tes 2 fichiers dans un même classeur et avec le lien que je t'ai donné ,j'ai ceci comme résultat : une feuille qui récapitule les similarités ainsi que les différences

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
 
Option Explicit
 
Sub Tst()
    Comparaison2Feuilles Sheets("Feuil1"), Sheets("Feuil2")
End Sub
 
Private Sub Comparaison2Feuilles(ByVal Sh1 As Worksheet, ByVal Sh2 As Worksheet)
Dim r As Long, c As Long
Dim r1 As Long, r2 As Long
Dim c1 As Long, c2 As Long
Dim RMax As Long, CMax As Long
Dim Formule1 As String, Formule2 As String
Dim Rapport As Workbook, Diff As Long
 
    Application.ScreenUpdating = False
    Set Rapport = Workbooks.Add
 
    With Sh1.UsedRange
        r1 = .Rows.Count
        c1 = .Columns.Count
    End With
    With Sh2.UsedRange
        r2 = .Rows.Count
        c2 = .Columns.Count
    End With
 
    RMax = r1: CMax = c1
    If RMax < r2 Then RMax = r2
    If CMax < c2 Then CMax = c2
 
    Diff = 0
    For c = 1 To CMax
        For r = 1 To RMax
            Formule1 = "": Formule2 = ""
            On Error Resume Next
                Formule1 = Sh1.Cells(r, c).FormulaLocal
                Formule2 = Sh2.Cells(r, c).FormulaLocal
            On Error GoTo 0
            If Formule1 <> Formule2 Then
                Diff = Diff + 1
                Cells(r, c).Formula = "'" & Formule1 & " <> " & Formule2
            End If
        Next r
    Next c
 
    With Range(Cells(1, 1), Cells(RMax, CMax))
        .Interior.ColorIndex = 19
        With .Borders
            .LineStyle = xlContinuous
            .Weight = xlHairline
        End With
    End With
 
    Columns("A:IV").ColumnWidth = 15
    Rapport.Saved = True
    If Diff = 0 Then Rapport.Close False
    Set Rapport = Nothing
 
    Application.ScreenUpdating = True
End Sub

**bzhbzh** · 15/07/2007, 11h57

merci,
j'ai creé mon fichier excel avec les 2 feuilles,
je fais : macro-visual basic editeur
apres quand j'essaye de coller le code je ne dois pas avoir la bonne manip

**bzhbzh** · 15/07/2007, 12h01

au fait quel temps à Quimper? je suis natif de Quimperlé mais habites a rennes et actuellement à Bucharest pour le boulot

**kiki29** · 15/07/2007, 12h03

Il faut coller le code dans ThisWorkbook

**bzhbzh** · 15/07/2007, 12h08

en fait ca le nouveau classeur etait générer mais les premières lignes sont vides.
l'ecriture démarre à 71 et les lignes inscrites ne sont pas du meme format que l'origine

**kiki29** · 15/07/2007, 12h30

Le fichier résultant avec les 2 exemples fournis

**bzhbzh** · 15/07/2007, 12h42

ok merci,
j'obtiens : SPAC00262: Rev Q <> SCPC05130: Rev G dans la premiere cellule mais pour pouvoir exploiter demain mes fichiers result j'ai besoin d'avoir:
dans un premier fichier la copie conforme de toutes les lignes qui sont communes dans la feuille1 et dans la feuille2 (peu importe la position de la ligne)
dans un autre fichier : toutes les autres lignes se trouvant dans une des 2 feuilles mais qui n'ont pas de doublons

**kiki29** · 15/07/2007, 13h49

vite fait, a adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
 
Option Explicit
 
Sub Tst()
    Comparaison2Feuilles Sheets("Feuil1"), Sheets("Feuil2")
End Sub
 
Private Sub Comparaison2Feuilles(ByVal Sh1 As Worksheet, ByVal Sh2 As Worksheet)
Dim r As Long, c As Long
Dim r1 As Long, r2 As Long
Dim c1 As Long, c2 As Long
Dim RMax As Long, CMax As Long
Dim Formule1 As String, Formule2 As String
Dim Ws As Worksheet
Dim RapportSim As Worksheet
Dim RapportDiff1 As Worksheet
Dim RapportDiff2 As Worksheet
 
    Application.ScreenUpdating = False
 
    Application.DisplayAlerts = False
        For Each Ws In Worksheets
            On Error Resume Next
                If Ws.Name = "Diff1" Then Ws.Delete
                If Ws.Name = "Diff2" Then Ws.Delete
                If Ws.Name = "Sim" Then Ws.Delete
            On Error GoTo 0
        Next Ws
    Application.DisplayAlerts = True
 
    Set RapportSim = ThisWorkbook.Worksheets.Add
    Set RapportDiff1 = ThisWorkbook.Worksheets.Add
    Set RapportDiff2 = ThisWorkbook.Worksheets.Add
 
    RapportSim.Name = "Sim"
    RapportDiff1.Name = "Diff1"
    RapportDiff2.Name = "Diff2"
 
    With Sh1.UsedRange
        r1 = .Rows.Count
        c1 = .Columns.Count
    End With
    With Sh2.UsedRange
        r2 = .Rows.Count
        c2 = .Columns.Count
    End With
 
    RMax = r1: CMax = c1
    If RMax < r2 Then RMax = r2
    If CMax < c2 Then CMax = c2
 
    For c = 1 To CMax
        For r = 1 To RMax
            Formule1 = "": Formule2 = ""
            On Error Resume Next
                Formule1 = Sh1.Cells(r, c).FormulaLocal
                Formule2 = Sh2.Cells(r, c).FormulaLocal
            On Error GoTo 0
            If Formule1 <> Formule2 Then
                RapportDiff1.Cells(r, c).Formula = "'" & Formule1
                RapportDiff2.Cells(r, c).Formula = "'" & Formule2
            Else
                RapportSim.Cells(r, c).Formula = "'" & Formule1
            End If
        Next r
    Next c
 
    RapportDiff1.Columns("A:IV").ColumnWidth = 15
    RapportDiff2.Columns("A:IV").ColumnWidth = 15
    RapportSim.Columns("A:IV").ColumnWidth = 15
 
    RapportSim.Move After:=Sheets(5)
    RapportDiff1.Move After:=Sheets(5)
    RapportDiff2.Move After:=Sheets(5)
 
    Set RapportSim = Nothing
    Set RapportDiff1 = Nothing
    Set RapportDiff2 = Nothing
    Application.ScreenUpdating = True
End Sub

**bzhbzh** · 15/07/2007, 14h20

merci beaucoup,
c'est en forme, il me reste qlq petites modifs a faire mais c'est exploitable.
déjà comme ça, je pourrais la lancer sur mes fichiers plus lourds.
(plus tard)
en fait c'est nickel, j'ai supprimé les lignes-collones vides ou incompletes et j'obtiens un fichier ok.

Merci kiki29
connais-tu un livre ou dictatiel qui tienne la route, pour pouvoir me former?

**kiki29** · 15/07/2007, 14h46

une modif , à toi de voir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
....
    For c = 1 To CMax
        For r = 1 To RMax
            Formule1 = "": Formule2 = ""
            Formule1 = Sh1.Cells(r, c)
            Formule2 = Sh2.Cells(r, c)
 
            If Formule1 <> Formule2 Then
                If IsNumeric(Formule1) Then
                    RapportDiff1.Cells(r, c) = CDbl(Formule1)
                Else
                    RapportDiff1.Cells(r, c) = Formule1
                End If
 
                If IsNumeric(Formule2) Then
                    RapportDiff2.Cells(r, c) = CDbl(Formule2)
                Else
                    RapportDiff2.Cells(r, c) = Formule2
                End If
            Else
                If IsNumeric(Formule1) Then
                    RapportSim.Cells(r, c) = CDbl(Formule1)
                Else
                    RapportSim.Cells(r, c) = Formule1
                End If
            End If
        Next r
    Next c
...

sinon http://office.developpez.com/

**bzhbzh** · 15/07/2007, 15h23

ça devient bon.
j'ai (après nettoyage lignes vides):
dans ma feuille1: 173 lignes
dans ma feuille2: 329 lignes
Total: 502 lignes

sym 70 lignes exploitables
diff1 103 lignes exploitables
diff2 259 lignes exploitables
Total: 432 lignes

je devrais avoir : ((feuille1+feuille2)-2x sym) = diff1+diff2
c'est bon = 362

je dois descendre un petit moment, je reprends dans une petite heure
merci, merci

**kiki29** · 15/07/2007, 16h44

Une petite derniere pour la route

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
 
Option Explicit
 
Sub Tst()
    Comparaison2Feuilles Sheets("Feuil1"), Sheets("Feuil2")
End Sub
 
Private Sub Comparaison2Feuilles(ByVal Sh1 As Worksheet, ByVal Sh2 As Worksheet)
Dim r As Long, c As Long
Dim r1 As Long, r2 As Long
Dim c1 As Long, c2 As Long
Dim RMax As Long, CMax As Long
Dim Formule1 As String, Formule2 As String
Dim Ws As Worksheet
Dim RapportSim As Worksheet
Dim RapportDiff1 As Worksheet
Dim RapportDiff2 As Worksheet
 
    Application.ScreenUpdating = False
 
    Application.DisplayAlerts = False
    For Each Ws In Worksheets
        On Error Resume Next
        If Ws.Name = "Diff1" Then Ws.Delete
        If Ws.Name = "Diff2" Then Ws.Delete
        If Ws.Name = "Sim" Then Ws.Delete
        On Error GoTo 0
    Next Ws
    Application.DisplayAlerts = True
 
    Set RapportSim = ThisWorkbook.Worksheets.Add
    Set RapportDiff1 = ThisWorkbook.Worksheets.Add
    Set RapportDiff2 = ThisWorkbook.Worksheets.Add
 
    RapportSim.Name = "Sim"
    RapportDiff1.Name = "Diff1"
    RapportDiff2.Name = "Diff2"
 
    With Sh1.UsedRange
        r1 = .Rows.Count
        c1 = .Columns.Count
    End With
    With Sh2.UsedRange
        r2 = .Rows.Count
        c2 = .Columns.Count
    End With
 
    RMax = r1: CMax = c1
    If RMax < r2 Then RMax = r2
    If CMax < c2 Then CMax = c2
 
    For c = 1 To CMax
        For r = 1 To RMax
            Formule1 = "": Formule2 = ""
            Formule1 = Sh1.Cells(r, c)
            Formule2 = Sh2.Cells(r, c)
 
            If Formule1 <> Formule2 Then
                If IsNumeric(Formule1) Then
                    RapportDiff1.Cells(r, c) = CDbl(Formule1)
                Else
                    RapportDiff1.Cells(r, c) = Formule1
                End If
 
                If IsNumeric(Formule2) Then
                    RapportDiff2.Cells(r, c) = CDbl(Formule2)
                Else
                    RapportDiff2.Cells(r, c) = Formule2
                End If
            Else
                If IsNumeric(Formule1) Then
                    RapportSim.Cells(r, c) = CDbl(Formule1)
                Else
                    RapportSim.Cells(r, c) = Formule1
                End If
            End If
        Next r
    Next c
 
    RapportSim.Cells.Columns.AutoFit
    RapportDiff1.Cells.Columns.AutoFit
    RapportDiff2.Cells.Columns.AutoFit
 
    RapportSim.Move After:=Sheets(5)
    RapportDiff1.Move After:=Sheets(5)
    RapportDiff2.Move After:=Sheets(5)
 
    DetruireLignesVides RapportSim
    DetruireLignesVides RapportDiff1
    DetruireLignesVides RapportDiff2
 
    Set RapportSim = Nothing
    Set RapportDiff1 = Nothing
    Set RapportDiff2 = Nothing
 
    Application.ScreenUpdating = True
End Sub
 
Sub DetruireLignesVides(ByVal Ws As Worksheet)
Dim i As Long, iMax As Long
 
    Ws.Activate
    iMax = ActiveSheet.UsedRange.Rows.Count
 
    For i = iMax To 1 Step -1
        If Application.CountA(Ws.Cells(i, 1).EntireRow) = 0 Then
            Ws.Cells(i, 1).EntireRow.Delete
        End If
    Next i
End Sub

**bzhbzh** · 15/07/2007, 18h07

la dernière pour la route est toujours la meilleure:
Nickel et exploitable tout de suite.
en fait: ce sont des fichiers de points de soudure pour une nouvelle version de vehicule.ceci va me faire gagner enormement de temps.
normalement, il existe un logiciel du client qui me fait le tri de tout ces points, ceux commun aux autres versions et ceux que je dois integrer sur le nouveau.
le probleme c'est que à l'étranger la base de donnée est differente et le soft n'est pas exploitable.
ce n'est qu'un exemple pour ce cas car en fait je bosse actuellement avec des methodes que j'utilisais il y a + de 10 ans(catia fonctionne 1 heure par jour par exemple)!!!!
ceci va me faire gagner enormement de temps et comme je suis prestataire ( sous-traitant) et que la date butée pour rendre la faisabilité du processus ne sera pas repousséee , je suis un peu sur les dents.
je te remercie beaucoup.
promis: dès que je retourne en france, j'achete un bouquin en francais afin de me mettre correctement en VB.je me rend compte que la philosophie ressemble enormement au VMS mais la syntaxe est moins parlante! VMS, les commandes sont comprehensibles en anglais.

en attendant je te remercie de m'avoir aidé, n'hesite pas à me contacter au besoin : bzhbzh@free.fr
kenavo ma breur

**kiki29** · 15/07/2007, 18h45

qqs utilitaires Excel qui pourraient te rendre service
http://www.asap-utilities.com/downlo...-utilities.php
XLG Favourites Add-in http://www.excelguru.ca/node/64

**bzhbzh** · 15/07/2007, 20h33

MERCI
je regarde tout ces liens.
passe une bonne fin de WE
je vais pouvoir bosser demain sur de bonnes bases.

kenavo
je clos cette discusion comme répondue.

comparaison de fichiers LIGNE PAR LIGNE

Excel

Discussions similaires

Partager

Partager