Discussion :

[bach_caravel]

Bonjour,

afin d'ajouter un tableau de résultats dans un rapport, je voudrais disposer les résultats sortant d'une régression linéaire dans la façon suivante:

le nom de la variable suivi par la valeur du coefficient estimé suivi par une ou deux étoile selon la significativité du coefficient. En dessous du coefficient estimé je voudrais mettre l'écart-type en parenthèses. Qui peut me donner un coup de main?

Merci,
Bach

[Saseuse]

Bonjour,
soit tu crées une sortie ods en html ou en rtf, tu récupéres les tableaux et tu l'arranges sous excel
c'est ce que je te conseille si tu as une seule analyse
soit tu crées un fichier de sortie sas avec la commande "output out = ..."qui se place sur la ligne proc ou avant le run il faut que tu regarde la syntaxe
il faudra que tu identifies les parametres que tu peux récupérer dans la doc
ensuite tu créeras un étape data sur ce fichier et en fonction de la valeur de ta p-value en utilisant des if then tu pourras créer une variable signi ='*...'
bon courage !!

[olivier.decourt]

Je sais que je réponds à un problème vieux d'un an, mais je me suis dit que la solution pouvait peut-être être utile à quelqu'un d'autre...
Pour ce genre de choses, on peut toujours aller modifier le modèle (template) sur lequel la proc s'appuie.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
PROC TEMPLATE ;                                                                
   DEFINE TABLE Stat.Reg.ParameterEstimates ;                                  
      COLUMN Variable (Estimate StdErr std) Probt ;
      HEADER h1 ;
      DEFINE h1 ;                                                              
         TEXT "Coefficients de la régression linéaire" ;                             
         SPACE = 1 ;                                                           
         SPILL_MARGIN ;                                                        
      END ;                                                                    
      DEFINE Variable ;                                                        
         HEADER = "Variable" ;                                                 
         STYLE = RowHeader ;                                                   
         ID;                                                                  
      END;                                                                    
      DEFINE Estimate ;                                                        
         HEADER = ";Coefficient;(Ecart-type)" ;                          
         PARENT = Common.ParameterEstimates.Estimate ;                         
         FORMAT = d11.3 ;                                                      
      END ;                                                                    
      DEFINE StdErr ;                                                          
         PARENT = Common.ParameterEstimates.StdErr ;  
		 PRINT = OFF ; /* colonne non affichée, créée uniquement pour s'en servir ensuite */
      END ;            
	  DEFINE std ;
         COMPUTE AS "("!!TRIM(LEFT(PUT(StdErr,12.2)))!!")" ;
		 JUST = RIGHT ;
	  END ;
      DEFINE Probt ;
		  HEADER = ";P-value;(H0:coeff=0)" ; 
	      TRANSLATE _val_<.01 INTO "**",
	                _val_<.05 INTO "*",
					_val_>0   INTO " "
		  ;
		 JUST = RIGHT ;
      END ;                                                                    
      REQUIRED_SPACE = 5 ;                                                     
      USE_NAME ;                                                               
   END;                                                                       
RUN;
PROC REG DATA = sashelp.class ;
	MODEL weight = height age ;
RUN ; QUIT ;
PROC TEMPLATE ;                                                                
   DELETE Stat.Reg.ParameterEstimates ;
RUN ;

Olivier

[OROZCO]

merci Olivier.

Ta réponse était peut être tardive à l'époque, mais bien utile aujourd'hui pour moi, et ma question arrive un an après! :-)
Comment savoir quelle "proc template" modifier et où la trouver?

j'utilise la "proc model" et je souhaiterai modifier de la même manière que pour ton exemple de la "proc reg" mes paramètres estimés (et mes combinaisons de paramètres estimés dans l'étape ESTIMATE) de telle sorte d'avoir les étoiles de significativité dans mes sorties....
merci d'avance.