Discussion :

[hervé_débutant]

Bonjour le forum,

j'ai une petite question pour les pro du VBA.

Je souhaiterais récupérer dans une feuille Excel
le nom,
le format,
éventuellement l'auteur et la date de création

de tous les fichiers contenus dans un répertoire sur un réseau.
ces fichiers peuvent être des pdf, word, wordpad, blocnote ou Excel.

Est il possible de rentrée dans une cellule de ma feuille excel l'arborescence conduisant au répertoire et après lancement d'une macro, d'avoir dans une colonne le nom dans une autre colonne le format....?

la cerise sur le gateau serait d'avoir une colonne avec les liens hypertexte vers le fichier

Est ce que une telle macro peut aller chercher les fichiers dans des sous-répertoires ?

j'imagine que cela doit être un peu compliqué, merci beaucoup pour votre aide.

je suis aller voir dans les archives mais je n'ai pas trouver ce genre de macro.

à bientôt hervé_débutant

PS: je ne connais rien au vba

[SilkyRoad]

bonjour


J'espère que cet exemple pourra t'aider:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Option Explicit
 
Sub TestListeFichiers()
    Dim Dossier As String
 
    Dossier = "C:\Documents and Settings\mimi\dossier"
 
    ListeFichiers Dossier
 
    Columns("A:E").AutoFit
    MsgBox "Terminé"
End Sub
 
 
 
Sub ListeFichiers(Repertoire As String)
    '
    'Nécessite d'activer la référence "Microsoft Scripting RunTime"
    '
    Dim Fso As Scripting.FileSystemObject
    Dim SourceFolder As Scripting.Folder
    Dim SubFolder As Scripting.Folder
    Dim FileItem As Scripting.File
    Dim i As Long
 
    Set Fso = CreateObject("Scripting.FileSystemObject")
    Set SourceFolder = Fso.GetFolder(Repertoire)
 
    i = Range("A65536").End(xlUp).Row + 1
 
    For Each FileItem In SourceFolder.Files
        Cells(i, 1) = FileItem.Name
        ActiveSheet.Hyperlinks.Add Anchor:=Cells(i, 1), _
            Address:=FileItem.ParentFolder & "\" & FileItem.Name
        Cells(i, 2) = FileItem.DateCreated
        Cells(i, 3) = FileItem.DateLastAccessed
        Cells(i, 4) = FileItem.DateLastModified
        Cells(i, 5) = FileItem.ParentFolder
 
        i = i + 1
    Next FileItem
 
 
    For Each SubFolder In SourceFolder.subfolders
        ListeFichiers SubFolder.Path
    Next SubFolder
 
End Sub

Pour les documents Office, tu peux récupérer le nom des auteurs (ainsi que d'autres propriétés) sans ouvrir les fichiers, en utilisant la librairie DSO:

http://silkyroad.developpez.com/VBA/...lasseurs/#LIII



bonne journée
michel

[hervé_débutant]

Bonjour le Forum , bonjour Michel,

merci beaucoup pour ce script et le lien je vais regarder tout ça, cela semble correspondre à ce que je cherchais c'est génial !

je test et je reviens sur le forum pour vous dire...

à bientôt donc et merci!!

hervé_débutant