Discussion :

[dev-man]

Bonjour,

J'essaye de lancer un exe à partir d'une appli VB6, et faire en sorte que l'application continue à s'exécuter qu'une fois l'exe lancé est terminé.

J'utilse pour cela la fonction CreatProcess

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, lpProcessAttributes As SECURITY_ATTRIBUTES, lpThreadAttributes As SECURITY_ATTRIBUTES, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDriectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long

jusque la il n'y a aucun problème, sauf que mon application ne marche plus dans les postes XP (l'exécution continue avant la fin de l'exe).

je me demande s'il ne s'agit pas la d'une incompatibilité de la méthode creatProcess avec XP, et si c'est le cas, y aurait-il un moyen pour contourner ce problème.

merci beaucoup

[Phifi]

Bonjour,

essaye d'être plus clair, je ne comprends pas :

Bonjour,
l'application continue à s'exécuter qu'une fois l'exe lancé est terminé.

ou

(l'exécution continue avant la fin de l'exe).

[dev-man]

finalement la fonction CreateProcess fonctionne aussi sous xp. en procédant comme suit:
1-déclarations

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
Public Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" _
                                      (ByVal lpApplicationName As Long, ByVal lpCommandLine As String, _
                                       ByVal lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
                                       ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
                                       ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
                                       lpStartupInfo As STARTUPINFO, _
                                       lpProcessInformation As PROCESS_INFORMATION) As Long
Public Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Public Declare Function GetExitCodeProcess Lib "kernel32" (ByVal hProcess As Long, lpExitCode As Long) As Long
 
Enum enSW
    SW_HIDE = 0
    SW_NORMAL = 1
    SW_MAXIMIZE = 3
    SW_MINIMIZE = 6
End Enum
 
 
'Type pour gérer les lancements de processus
Type STARTUPINFO
    cb As Long
    lpReserved As String
    lpDesktop As String
    lpTitle As String
    dwX As Long
    dwY As Long
    dwXSize As Long
    dwYSize As Long
    dwXCountChars As Long
    dwYCountChars As Long
    dwFillAttribute As Long
    dwFlags As Long
    wShowWindow As Integer
    cbReserved2 As Integer
    lpReserved2 As Long
    hStdInput As Long
    hStdOutput As Long
    hStdError As Long
End Type
 
'Info sur un processus
Type PROCESS_INFORMATION
    hProcess As Long
    hThread As Long
    dwProcessID As Long
    dwThreadID As Long
End Type
 
Public Const NORMAL_PRIORITY_CLASS = &H20&
Public Const STILL_ACTIVE = &H103&

2-implémentation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Public Sub AttendreFinProcess(proc As PROCESS_INFORMATION, Optional timeout As Long = 60)
 
Dim Ret As Long
Dim tms As Single
Dim exitcode As Long
 
'Attendre la fin de la commande
tms = Timer
Ret = GetExitCodeProcess(proc.hProcess, exitcode)
Do While Ret <> 0 And exitcode = STILL_ACTIVE
    Ret = GetExitCodeProcess(proc.hProcess, exitcode)
    DoEvents
    Sleep 100
    If Timer - tms > timeout Then
        Err.Raise STILL_ACTIVE, "AttendreFinProcess", "Timeout sur l'attente de la fin d'un process"
    End If
Loop
If Ret = 0 Then
    Err.Raise Err.LastDllError, "AttendreFinProcess", "Erreur systeme N° " & Err.LastDllError
End If
 
End Sub
 
Public Sub LancerProcess(sExe As String, proc As PROCESS_INFORMATION, ByVal StartSize As enSW)
 
Dim start As STARTUPINFO
Dim Ret As Long
 
'StartupInfo pour le processus qui lancera la commande
start.cb = Len(start)
start.dwFlags = &H1 'l'exe tourne en tâche de fond
start.wShowWindow = StartSize
'Lancement de la commande
Ret& = CreateProcess(0&, sExe, 0&, 0&, 0&, NORMAL_PRIORITY_CLASS, 0&, 0, start, proc)
If Ret = 0 Then
    Err.Raise Err.LastDllError, "LancerProcess", "Erreur systeme N° " & Err.LastDllError
End If
 
End Sub

3- appel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Dim proc As PROCESS_INFORMATION
    proc.hProcess = -1
    proc.hThread = -1
 
    Call LancerProcess(cheminExe, proc, SW_HIDE)
    Call AttendreFinProcess(proc)
 
    Call CloseHandle(proc.hProcess)
    Call CloseHandle(proc.hThread)

Ce code permettre d'exécuter le programme cheminExe à partir de votre application VB6, en arrêtant cette dernière jusqu'à la fin de l'exécution de cheminExe.