Discussion :

[stephanies_1977]

Bonjour à tous,

Je travail sous xls
j'ai un code qui me permet d'envoyer mon fichier xls en cours par mail en piece jointe.
Mais je voudrais rajouter une 2ième piece jointe qui est un fichier Word, que je viens de creer, que j'ai sauvegarder et fermer. le chemin de ce document Word est toujours le même mais pas le nom évidemment.

existe-t-il un moyen facile de retrouver ce fichier et de le mettre en attach dans mon mail en plus de mon fichier xls ?

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub testmail()
 
Dim ol As New Outlook.Application
   Dim olmail As MailItem
   Dim CurrFile As String
   Set ol = New Outlook.Application
   Set olmail = ol.CreateItem(olMailItem)
   With olmail
    .To = Range("C1").Value 'VLOOKUP MAIL WITH NAME
    .Subject = "OFFER " & Range("B3").Value
    .Body = "Hello This is the comparison and offer for the customer " & Range("b3").Value
    .Attachments.Add ActiveWorkbook.FullName
    .Display '.Send'On peut switcher entre .send et .display selon que l'on veut envoyer le mail (send) ou seulement le préparer et le vérifier(display)
    End With
 
 
End Sub

D'avance merci pour votre aide
Stéph

[Plateforme3]

Bonjour
Si je comprends bien (ce qui n'est pas toujours le cas, l'age surement!)
Est ce qu'une boite de dialogue te conviendrait?
Si oui:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub truc()
With Application.FileDialog(msoFileDialogOpen)
    .AllowMultiSelect = False
    .Filters.Clear
    .Filters.Add "Fichier Word", "*.doc"
    .FilterIndex = 1
    .InitialFileName = "c:\chemin..."
    .Show
    Nom_Fichier = .SelectedItems(1)
End With
End Sub

Pour ce qui est de le joindre, je maitrise pas
Slts

[SilkyRoad]

bonjour


Pour joindre plusieurs fichiers, tu peux utiliser:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
'
'
.Attachments.Add ActiveWorkbook.FullName
.Attachments.Add "C:\chemin\deuxieme fichier.xls"
'
'

michel

[stephanies_1977]

Re,

une boite de dialogue serait evidement super, seulement je ne trouve nulle part un code pour apppeler la boite de dialogue en outlook "Insert File"

j'ai testé le code de Plateforme 3 mais :
avec mon code un nouveau mail s'ouvre et le code de Plateforme 3 ne continue pas en outlook
je suis obligé de retourner en xls ou la son code me demande d'ouvrir un fichier en excel

Quant au code de Skillyroad il ne me permet pas de choisir un document

Help !!!!

[SilkyRoad]

rebonsoir

une boite de dialogue serait evidement super, seulement je ne trouve nulle part un code pour apppeler la boite de dialogue en outlook "Insert File"

Quelle version d'Excel utilises tu ?
La procédure de Plateforme te permet de sélectionner directement des fichiers que tu pourras ensuite ajouter à ton mail.

j'ai testé le code de Plateforme 3 mais :
avec mon code un nouveau mail s'ouvre et le code de Plateforme 3 ne continue pas en outlook
je suis obligé de retourner en xls ou la son code me demande d'ouvrir un fichier en excel

Effectivement si tu as juste fait un copier/coller ça ne fonctionnera pas.

Quant au code de Skillyroad il ne me permet pas de choisir un document

Je souhaitais simplement montrer comment ajouter plusieurs pieces jointes dans une message.



michel

[SilkyRoad]

un exemple complet à tester

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub ChoixMultiFichiers_EnvoiMail()
    Dim Fichiers As Variant
    Dim i As Integer
    Dim Ol As Outlook.Application
    Dim olMail As MailItem
 
    'Affiche la boîte dialogue "Ouvrir"
    '(C'est l'argument True qui autorise la multisélection)
    Fichiers = Application.GetOpenFilename("Tous les fichiers (*.*),*.*", , , , True)
 
 
   Set Ol = New Outlook.Application
   Set olMail = Ol.CreateItem(olMailItem)
 
    With olMail
        .To = "dest.provider.fr"
        .Subject = "OFFER "
        .Body = "Hello"
 
        .Attachments.Add ActiveWorkbook.FullName
 
        'Boucle sur le tableau pour récupérer le nom du ou des classeurs sélectionnées.
        '(IsArray(Fichiers) renvoie False si aucun fichier n'a été sélectionné).
        If IsArray(Fichiers) Then
            For i = 1 To UBound(Fichiers)
                .Attachments.Add Fichiers(i)
            Next
        End If
 
        .Display
    End With
 
End Sub

michel

[stephanies_1977]

super !

en effet de cette manière ça marche (j'avoues que j'ai parfois du mal à mettre en place différents bouts de codes)

merci Michel !!!!!