Discussion :

[hector2]

je veux créer un module de classe qui a comme attributs entrez autres des tableaux de double ( à 2 entrées, de dimension quelconque?)
voulant les droits en lecure-écriture, ai-je bien le droit -je débute- de définir:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private CC() As Double
Public Property Let C(Cb() As Double)
    ReDim CC(1 To n, 1 To p) As Double
    For j = 1 To p
        For i = 1 To n
            CC(i, j) = Cb(i, j)
        For j = 1 To p
    For i = 1 To n
End Property
Public Property Get C() As Double()
    For j = 1 To p
        For i = 1 To n
            C(i, j) = CC(i, j)
        Next i
    Next j
End Property

j'ai un doute... car vbe crashe à ce niveau...
Merci

déjà il faudrait sans doute passer n et p en arguments, non?

[philben]

bonjour,

a priori la méthode suivante fonctionne pour les tableaux dynamiques...

l'objet nommé <POO2> :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Private CC() As Double
Public Property Let c(ByRef cb() As Double)
   CC = cb
End Property
Public Property Get c() As Double()
   c = CC
End Property

Une fonction de test :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
 
Private Sub MonTest()
   Dim cb() As Double, ce() As Double
   Dim i As Integer, j As Integer, Minij As Integer
   Dim oo As POO2
   Randomize
   Minij = 1
   ReDim cb(Minij To 5, Minij To 2)
   Set oo = New POO2
Debug.Print vbCrLf & "1) initialise cb()"
Debug.Print "'i'", "'j'", "'cb(i,j)'"
   For j = Minij To UBound(cb, 2)
      For i = Minij To UBound(cb)
         cb(i, j) = Int(Rnd * 50)
Debug.Print i, j, cb(i, j)
      Next i
   Next j
   oo.c = cb
Debug.Print vbCrLf & "2) Affectation de cb() à l'objet"
Debug.Print vbCrLf & "3) Efface cb()"
Debug.Print "'i'", "'j'", "'cb(i,j)'"
   For j = Minij To UBound(cb, 2)
      For i = Minij To UBound(cb)
         cb(i, j) = 0
Debug.Print i, j, cb(i, j)
      Next i
   Next j
Debug.Print vbCrLf & "4) Réaffectation de cb() via l'objet"
   cb = oo.c
Debug.Print vbCrLf & "5) Affectation directe ce() via l'objet"
   ce = oo.c
Debug.Print "'i'", "'j'", "'cb(i,j)'", "'ce(i,j)'"
   For j = Minij To UBound(cb, 2)
      For i = Minij To UBound(cb)
Debug.Print i, j, cb(i, j), ce(i, j)
      Next i
   Next j
Debug.Print vbCrLf & "6) Détruit l'objet"
   Set oo = Nothing
Debug.Print vbCrLf & "7) Vérification des tableaux cd() et ce()"
Debug.Print "'i'", "'j'", "'cb(i,j)'", "'ce(i,j)'"
   For j = Minij To UBound(cb, 2)
      For i = Minij To UBound(cb)
Debug.Print i, j, cb(i, j), ce(i, j)
      Next i
   Next j
End Sub

A vérifier selon votre utilisation...

Philippe

[Garuda]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private CC() As Double
Public Property Let C(Cb() As Double)
    ReDim CC(1 To n, 1 To p) As Double
    For j = 1 To p
        For i = 1 To n
            CC(i, j) = Cb(i, j)
        For j = 1 To p        |
    For i = 1 To n            |<== Petit problème !!!!
End Property
Public Property Get C() As Double()
    For j = 1 To p
        For i = 1 To n
            C(i, j) = CC(i, j)
        Next i
    Next j
End Property

[hector2]

effectivement, merci garuda, j'avais mal copié-collé mais ça n'était pas à l'origine du problème ...
Sinon, merci philben pour ta réponse détaillée:
ton test marche, je comprends mieux mais j'ai toujours un truc (théorique) qui me bloque :
pourquoi par exemple un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

debug.print oo.C(1,1)

me retourne une erreur (oo.C est bien signalé comme un tableau de double ...) ?

Merci!

[philben]

bonjour,

debug.print oo.C(1,1)me retourne une erreur (oo.C est bien signalé comme un tableau de double ...) ?

c'est normal puisque la propriété Get C() n'attend pas de paramètre.

Deux possibilités :

* soit écrire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Debug.Print oo.c()(1, 1)

ce qui en clair, on demande le contenu de la cellule 1,1 du tableau retourné par la propriété get C().

* soit ajouter une propriété qui retourne un élément particulier du tableau (j'ai pas mis les vérifs d'usage des paramètres) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Public Property Get GetElement(ByVal i As Integer, ByVal j As Integer) As Double
   GetElement = CC(i, j)
End Property

Appel par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Debug.Print oo.GetElement(1, 1)

Philippe

[hector2]

Merci beaucoup!