Discussion :

[sharrascript]

Bonjour,

Tout d'abord sachez que je poste après avoir passé plus d'une heure à chercher, sans trouver une réelle réponse.

Voilà, j'utilise outloock 2007 et il y a un truc qui me prend la tête c'est l'enregistrement de plusieurs mails au format text.

On peu facilement faire un enregistrer sous pour un seul mail, mais dès qu'il y en a plusieurs il ne les séparent pas et me met tout sous un seul fichier.

J'ai vraiment besoin de les séparer et qu'ils soient au format .txt. J'en ai plus de 6000!! Cela serait dommage de les faire un par un^^

Donc, (j'ai peur de la réponse^^), serait il possible de faire un enregistrer sous... au format txt de plusieurs mail en même temps et avec un fichier bien distinct de chaque mail?

Je vous remercie par avance.
SHARR

P.S.: si vous avez une solution sous vb, je prend

++

[Heureux-oli]

Avec une petite macro, on peut le faire.
Si tu n'a point peur du code !

[sharrascript]

bonjour Heureux-oli,

Merci pour la rapidité de la réponse.

Non en effet, le code ne me fait pas peur (enfin pour l'instant^^), j'ai de très bonnes notions en php, sql etc... (je ne vais pas étaler mon cv c'est pas le but :p)

J'ai des bases en VB.NET et java.

Si tu as un tuto ou juste des liens pour la conception de macro pour OUTLOOCK je prend.

Merci d'avance.

[Heureux-oli]

Je vais regarder, normalement, il y a moyen d'exploiter certaines choses sur le forum.

[Heureux-oli]

Voilà déjà un morceau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub SaveMessage()
 
    Dim oFold As MAPIFolder
 
    Dim oItem As MailItem
    Dim oNS As NameSpace
    Dim repert As String
 
    repert = "c:\temp\"
 
    On Error Resume Next
    Set oNS = Application.GetNamespace("MAPI")
    Set oFold = oNS.PickFolder
 
    For Each oItem In oFold.Items
        oItem.SaveAs repert & oItem.Subject & ".txt", olTXT
    Next oItem
 
 
 
End Sub

Mais il faut combiner à ce code :

http://www.developpez.net/forums/sho...81&postcount=1

Pour les caractères non autorisés dans les noms de fichiers.

[sharrascript]

franchement Heureux-oli,

Déjà merci pour la rapidité de réponse et d'avoir pris la peine de venir à mon secours

Je vais tester cela rapidement et dans tous les cas je vous tiens au courant.

++

Rien a dire developpez.net a une communauté que l'on retrouve nul par ailleurs...

[sharrascript]

Yop des nouvelles,

Et bien merci beaucoup, parce que c'est nickel et cela fonctionne impeccable!!!

MERCI 1000 fois

Pour ceux que cela intéresse je met le code que j'ai utilié, mes modifs sont pas optimisées, mais ça marche nickel !!!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Sub mails_format_txt()
Dim oFold As MAPIFolder
 
    'merci à  Heureux-oli de developpez.net qui m'a aider pour cette petite macro utile
 
    Dim oItem As MailItem
    Dim oNS As NameSpace
    Dim repert As String
 
    'Répertoire destination
    repert = "c:\mes_mails\"
 
    On Error Resume Next
    Set oNS = Application.GetNamespace("MAPI")
    Set oFold = oNS.PickFolder
 
    'variable nom du sujet
    Dim NomExport As String
 
    'variable pour le nom du sujet qui sera nettoyé
    Dim titre As String
 
    'variable d'incrémentation pour un nom unique
    Dim n As Integer
 
    'On la démarre de 1
    n = 1
 
    'boucle pour l'exporattion des messages et enregistrement au format txt
    For Each oItem In oFold.Items
 
        'Le titre original
        NomExport = oItem.subject
 
        'le titre nettoyé commençant par txt
        titre = "txt" & Left(Replace(Replace(Replace(Replace(Replace(Replace(Replace(Replace(Replace(Replace(Replace(Replace(NomExport, "\", ""), "/", ""), ":", ""), "*", ""), "?", ""), "<", ""), ">", ""), "|", ""), ".", ""), """", ""), vbTab, ""), Chr(7), ""), 160)
 
        'enregistrement
        oItem.SaveAs repert & titre & n & ".txt", olTXT
 
        'incrémentation
        n = n + 1
 
    Next oItem
 
End Sub

++