[VBA]excel vers pdf

**Oussbaba au rhum** · 12/10/2007, 14h34

bonjour,
comment fait on pour passer le chemin du sendkey?
un bout de code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Const ThePath As String = "C:\documents an settings\admin\bureau" 
Const TheFile As String = "Essai"
 
Sub pdf()
SendKeys ThePath & TheFile + "~"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True
End Sub

lorsque que je fais ca, la boite de dialogue s'ouvre et me dit que
"and settings\admin\bureau\essai" n'est pas un chemin valide

quelqu'un peut m'aider??

**Jean-Philippe André** · 12/10/2007, 15h09

salut,
il faut faire un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Replace(ThePath,"\","\\")

je crois

**Oussbaba au rhum** · 12/10/2007, 15h13

merci de la reponse

pourquoi faire un replace? le sendkey ne prend pas les slash en charge?

**Jean-Philippe André** · 12/10/2007, 15h15

non justement ^^

**fred65200** · 12/10/2007, 15h15

bonjour

mets un slash à la fin
Const ThePath As String = "C:\documents an settings\admin\bureau\"
et ça doit fonctionner.

Salutations
frd65200

**Jean-Philippe André** · 12/10/2007, 15h17

lol, au passage, il manque un d à and :p

**Oussbaba au rhum** · 12/10/2007, 15h22

ca marche pas!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Option Explicit
 
Const ThePath As String = "C:\documents an settings\admin\bureau\"
Const TheFile As String = "TheTestingFile.pdf"
 
Sub pdf()
SendKeys ThePath & TheFile + "~"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True
End Sub

**fred65200** · 12/10/2007, 15h24

re

le D

Const ThePath As String = "C:\documents and settings\admin\bureau\"

Si tu n'est pas sous Vista, télécharge Clickie pour copier les noms de dossier /fichier,
Sur Vista, Shift + Clic sur le dossier / Fichier
ligne "Copier en tant que chemin d'accès"
@+

**Oussbaba au rhum** · 12/10/2007, 15h28

Oups, c'est corrigé
mais cela ne change rien.........

**Jean-Philippe André** · 12/10/2007, 15h30

essaie de récupérer le path du bureau par les variable environ()

**fred65200** · 12/10/2007, 15h31

re

et ça

SendKeys ThePath & TheFile + "~"

SendKeys ThePath & TheFile & "~"

cordialement

**Oussbaba au rhum** · 12/10/2007, 17h24

jpcheck,
je ne connais pas ce type de variables(eh oui un newb

)

fred65200,
le fait de mettre l& ne change rien

Auriez une autre methode pr automatiser la saisie du nom de fichier?

**fred65200** · 12/10/2007, 17h44

re bonjour,
résumons le chemin est bon

Si tu le fais manuellement, tu choisis ton fichier et tu cliques sur ENTER

Essaies de mettre une temporisation, je t'ai mis 5, fais tes essais et réduis le délai d'attente

SendKeys ThePath & TheFile , True
Attendre 5
Sendkeys "~", true
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Function Attendre(Secondes As Integer)
' Cette procédure temporise pendant le nombre de secondes qu'on lui transmet en argument
Dim Début As Long, fin As Long, Chrono As Long
Début = Timer
fin = Début + Secondes
Do Until Timer >= fin
    DoEvents
Loop
End Function

fred65200

**Oussbaba au rhum** · 15/10/2007, 08h46

merci de ton aide fred
j'ai fait les tests.tout d'abord, j'ai du integrer la function attendre dans le sub car la pile était insuffisante
voilà le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub pdf2()
 
SendKeys ThePath & TheFile, True
'attente
Dim Début As Long, fin As Long, Chrono As Long
Début = Timer
fin = Début + 1
Do Until Timer >= fin
    DoEvents
Loop
'envoi touche entrée
SendKeys "~", True
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:="Adobe PDF", collate:=True
 
End Sub

en fonction, ce code m'ouvre indefiniment la fenetre windows d'enregistrement de fichier

je ne sais plus quoi faire...

**ouskel'n'or** · 15/10/2007, 09h12

Envoyé par fred65200

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Function Attendre(Secondes As Integer)
' Cette procédure temporise pendant le nombre de secondes qu'on lui transmet en argument
Dim Début As Long, fin As Long, Chrono As Long
Début = Timer
fin = Début + Secondes
Do Until Timer >= fin
    DoEvents
Loop
End Function

Hello Fred, tu sais qu'on peut remplacer cette fonction par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Wait Secondes

Ceci dit, je n'ai toujours pas compris le problème.
Oussbaba au rhum, tu as toujours le message sur "C:\Documents and Settings\admin\bureau\essai" n'est pas un chemin valide ?

**Oussbaba au rhum** · 15/10/2007, 09h49

bonjour ouskel'nor
je vais essayer de faire au plus simple
mon but est d'automatiser la sortie en pdf d'un excel sans le passage par la fenetre d'enregistrement windows
l'impression pdf fonctionne jusqu'à la fenetre d'enregistrement où celle ci me demande comment et où je veux enregistrer le pdf
c'est cette étape que je veux automatiser en codant le chemin et le nom

**ouskel'n'or** · 15/10/2007, 10h49

Désolé mais je n'ai pas la solution.
Printout a deux paramètres : PrintToFile et PrToFileName. Je n'ai jamais testé et en principe c'est fait pour créer un fichier d'impression mais tu peux toujours tester... Je ne peux pas le faire (j'utilise pdfcreator) A tout hasard...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

... , PrintToFile:=True, PrToFileName:=Chemin & NomFich

Je ne pense pas que ça fonctionnera mais sait-on jamais

J'ai vu passer une réponse où les paramètres de fichier, de path et de format étaient définis mais il s'agissait (ici) d'Acrobat Distiller.
Enfin, quelle version d'Excel as-tu ? Avec 2007, tu as un export au format pdf disponible (voir la FAQ)
Après, je suis sec

**kiki29** · 15/10/2007, 11h02

Dans Acrobat Distiller ( si tu l'as )
Menu Fichier | Préférences
Décocher les Options idoines dans "Options de Sortie"
Sinon un code similaire , à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
'   sous VBE Menu Outils | Références
'   Cocher Acrobat Distiller
 
Sub Tst_Adobe_PDF_02()
Dim sNomFichierPS As String
Dim sNomFichierPDF As String
Dim PDFDist As PdfDistiller
 
'   sur un PC Personnel : a priori Choix libre du Nom et de l'emplacement du fichier de sortie
'
'   Sur un PC "Entreprise"
'   Il faut être logué en Administrateur ou en Avoir les droits pour utiliser Distiller
'   Les chemins doivent être de la forme :
'       "C:\Documents and Settings\UserName\Mes documents\....."
 
    sNomFichierPS = ThisWorkbook.Path & "\" & "Essai_AdobbePDF.ps"
    sNomFichierPDF = ThisWorkbook.Path & "\" & "Essai_AdobbePDF.pdf"
 
    ActiveSheet.Range("Zone").PrintOut copies:=1, Preview:=False, _
        ActivePrinter:="Acrobat PDF", PrintToFile:=True, _
        Collate:=True, PrToFilename:=sNomFichierPS
 
    Set PDFDist = New PdfDistiller
    PDFDist.FileToPDF sNomFichierPS, sNomFichierPDF, ""
    Set PDFDist = Nothing
 
    Kill sNomFichierPS
    Kill ThisWorkbook.Path & "\" & "Essai_AdobbePDF.log"
End Sub

**Oussbaba au rhum** · 15/10/2007, 13h31

merci bcp kiki
mon pb est resolu grace a ton code que j'ai un peu modifié

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub Adobe_PDF()
 
Dim NomPS, NomPDF, NomLog As String
Dim nom, path, dte As String
Dim PDFm As PdfDistiller
 
    nom = ActiveSheet.Range("E13").Value '& ActiveSheet.Range("C36")
    path = "\\*****\partage\"
 
    NomPS = path & nom & ".ps"
    NomPDF = path & nom & ".pdf"
    NomLog = path & nom & ".log"
 
    ActiveSheet.PrintOut copies:=1, Preview:=False, _
        ActivePrinter:="Acrobat PDF on Ne00:", PrintToFile:=True, _
        Collate:=True, PrToFilename:=NomPS
 
    Set PDFm = New PdfDistiller
    PDFm.FileToPDF NomPS, NomPDF, ""
    Set PDFm = Nothing
 
    Kill NomPS
    Kill NomLog
End Sub

Encore merci pour votre aide et votre rapidité

**kiki29** · 15/10/2007, 16h05

Re
Une remarque dans Dim NomPS, NomPDF, NomLog As String seul NomLog sera de type String mais pas NomPS ni NomPDF qui seront de type Variant
donc : Dim NomPS As String, NomPDF As String , NomLog As String
-d°- pour le reste

Une autre remarque : à quoi bon répéter un code simlilaire à celui proposé sinon pour encombrer le paysage ?

[VBA]excel vers pdf

Macros et VBA Excel

Discussions similaires

Partager

Partager