Récupérer des valeurs d'un fichier dat

**triaguae** · 22/11/2007, 14h15

Bonjour,

Il faut que je récupère dans un fichier excel certaines valeurs qui sont stockées dans un fichier dat (que j'ouvre avec le blocnote)
Les données se présentent comme suit :
$
0001710602 060 22.11.07 01.04 08:38
0489 376 2003 0513
0489 401 2674 0585
0480 492 7948 0583
0467 422 5108 0561
0520 373 1655 0278
$
5000221105 001 22.11.07 01.04 10:33
0423 342 0186 0281
0422 378 1601 0424
0459 369 5558 0319
0364 304 1060 0445
Je veux récupérer les 4 premiers chiffres des valeurs qui sont sous la ligne qui commence par un 5 soit : 0423, 0422, 0459, 0364
je ne sais pas si c'est clair mais c'est pas facile à expliquer

**Singular** · 22/11/2007, 14h29

Tu commences par importer le fichier texte dans Excel en précisant le type de délimiteur (espaces, dans ce cas ci), ce qui te créera une feuille nommée comme ton fichier texte, sans l'extension.
Dans cette feuille, tu cherches la cellule qui contient la valeur référence. Par la suite, tu n'as qu'à copier les valeurs situées en dessous et à la droite de cette cellule dans une autre feuille que tu nommes comme tu veux.
Voila pour la description des opérations. Pour ce qui est du code, ça c'est ton boulot.

À moins que tu ne saches vraiment pas comment utiliser VBA...

**triaguae** · 22/11/2007, 14h37

... à moins que je ne sache pas utiliser vba.... ça me correspond bien!!
effectivement, je commence à m'y intéresser car je m'aperçois que ça pourrait résoudre pas mal de problème que je rencontre au quotidien.
Donc je veux bien un petit coup de pouce pour démarrer!
merci

**Singular** · 22/11/2007, 15h06

Le problème est que c'est plus qu'un petit bout de code que tu demandes. Je vais voir ce que je peux faire, sans promesse.

**triaguae** · 22/11/2007, 15h07

merci

**fred65200** · 22/11/2007, 15h37

bonjour

En supposant que tu n'as que 6 lignes entre chaque $.
Adapte le chemin et teste

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub recherche5()
Open "C:\Users\Fred\Desktop\1.dat" For Input As #1
While Not EOF(1)
Line Input #1, a$
  If Left(a$, 1) Like "5" Then
    For i = 1 To 5
      Line Input #1, a$
      If i = 1 Then text1 = Left(a$, 4) Else text1 = text1 & ", " & Left(a$, 4)
    Next
  End If
Wend
Close #1
Debug.Print text1
MsgBox text1
End Sub

cordialement

**triaguae** · 22/11/2007, 16h25

Merci pour ce code mais le problème est que je n'ai pas forcément 6lignes avant et je peux avoir plusieurs séquences à récupérer. je joint un exemple complet de fichier dat

**fred65200** · 22/11/2007, 17h24

re

que dois tu récupérer dans

$
5000221105 001 22.11.07 01.04 10:33
0423 342 0186 0281
$
5001710701 012 22.11.07 99.04 10:13
0417 338 0488 0439
0313 327 0328 0395
0423 328 0272 0359
0434 337 0602 0116
0426 351 0367 0231
0413 304 0283 0309
0413 306 0210 0339
0473 368 0216 0261
0476 326 0103 0105
0440 337 0312 0323
0454 379 0256 0421
0418 336 0466 0389
$

et sous quelle forme, une seule chaîne?

0423, 0417, 0313,...
ou

0423
0417, 0313,...
@+

**fred65200** · 22/11/2007, 17h40

bon, ce sera sur plusieurs lignes.
ce n'est certainement pas optimisé mais je crois que ça marche.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub recherche5()
Dim maStr As String, a$ 
Dim i As Integer
Dim T As Variant
Open "C:\Users\Fred\Desktop\MGMPLDAT.txt" For Input As #1
While Not EOF(1)
  Line Input #1, a$
   If Left(a$, 1) Like "5" And Len(a$) = 35 Then 'à vérifier pour le 35
      Do
        Line Input #1, a$
        maStr = maStr & ", " & Left(a$, 4)
      Loop Until a$ = "$"
  End If
Wend
Close #1
 
maStr = Right(maStr, Len(maStr) - 2)
maStr = Left(maStr, Len(maStr) - 3)
T = Split(maStr, ", $,")
 
For i = 0 To UBound(T)
  Debug.Print T(i)
  MsgBox T(i)
Next i
End Sub

cordialement

**triaguae** · 23/11/2007, 10h02

Merci pour le code, j'ai même réussi à l'adapter pour coller mes valeurs dans des cellules, le seul problème est que j'ai les $ qui subistent! voici ce que j'ai fait:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub CommandButton1_Click()
Dim maStr As String, a$
Dim i As Integer
Dim T As Variant
l = 3
Open "C:\Documents and Settings\VALERIE\Mes documents\MGMPLDAT.DAT" For Input As #1
While Not EOF(1)
  Line Input #1, a$
   If Left(a$, 1) Like "5" And Len(a$) = 35 Then 'à vérifier pour le 35
      Do
        Line Input #1, a$
        Range("B" & l).Value = Left(a$, 4)
      l = l + 1
      Loop Until a$ = "$"
  End If
Wend
Close #1
 
End Sub

**fred65200** · 23/11/2007, 14h29

bonour,

dans le code que e t'ai laissé, il y avait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
maStr = Right(maStr, Len(maStr) - 2)
maStr = Left(maStr, Len(maStr) - 3)
T = Split(maStr, ", $,")

C'est ce qui retire les $

@+

**Singular** · 23/11/2007, 14h35

Petite précision: Le $ dans

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Line Input #1, a$

devrait disparaitre. Il ne sert que lors de la déclaration de la variable (Dim) pour préciser au compilateur qu'il s'agit d'une variable de type String. Pour faire référence à la variable partout ailleurs dans le code, il faut écrire simplement a.

Voici ton code remanié de façon à s'y retrouver facilement (avec des noms de variables plus éloquants) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Sub RecupererDonneesDansFichierTexte()
    Dim sRef As String
    Dim sLigne As String
    Dim nLigne As Integer
    Dim sNomFichier As String
    Dim sDelimiteur As String
    Dim sColonne As String
 
    sNomFichier = "C:\Documents and Settings\VALERIE\Mes documents\MGMPLDAT.DAT"
    sRef = "0000000005"
    sDelimiteur = "$"
    sColonne = "B"
 
    nLigne = 3
    Open sNomFichier For Input As #1
    While Not EOF(1)
        Line Input #1, sLigne
        If Left(sLigne, Len(sRef)) = sRef Then
            Do
                Line Input #1, sLigne
                If sLigne = sDelimiteur Then Exit Do
                Range(sColonne & CStr(nLigne)).Value = "'" & Left(sLigne, 4)
                nLigne = nLigne + 1
            Loop
        End If
    Wend
    Close #1
    ActiveSheet.Name = sRef
End Sub

NB : Tu remarqueras que j'ajoute un ' avant l'entrée dans Excel de façon à conserver le 0 en préfixe de chaque donnée.

Note de modif : J'ai remplacé le Like par =.

**fred65200** · 23/11/2007, 14h54

bonjour Singular, elnipal

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
maStr = Right(maStr, Len(maStr) - 2)
maStr = Left(maStr, Len(maStr) - 3)
T = Split(maStr, ", $,")
 
For i = 0 To UBound(T)
 Range("B" & i + 2).Value = T(i)
  'MsgBox T(i)
Next i

doit donner ce que tu demandes.

Tu peux aussi faire un replace dans ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("B" & l).Value =  "'" & Replace(Left(a$, 4), "$","")

@+

**triaguae** · 23/11/2007, 16h09

j'ai fait ça et ça marche:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub CommandButton1_Click()
Dim maStr As String, a$
Dim i As Integer
Dim T As Variant
l = 3
Open "E:\MGMPLDAT.DAT" For Input As #1
While Not EOF(1)
  Line Input #1, a$
   If Left(a$, 1) Like "5" And Len(a$) = 35 Then 'à vérifier pour le 35
      Do
        Line Input #1, a$
        If Left(a$, 1) Like "0" Then
        Range("B" & l).Value = (Left(a$, 4) / 10)
        End If
        l = l + 1
        If Left(a$, 1) Like "$" Then l = l - 1
      Loop Until a$ = "$"
  End If
Wend
Close #1
 
End Sub

**Singular** · 23/11/2007, 19h11

Je vois pas ce que le code que je t'ai donné ne faisait pas, elnipal. J'ai tenté de limiter le nombre de comparaisons au minimum et même essayé de garder la forme originale des données.

Une des lignes de ton code qui me chicote particulièrement est:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Left(a$, 1) Like "5" And Len(a$) = 35 Then 'à vérifier pour le 35

Pourquoi un Like quand tu as un numéro de référence précis à chercher?

C'est dangereux de rechercher des valeurs nébuleuses quand tu peux faire autrement.

**fred65200** · 23/11/2007, 20h14

Bonour Singular,

Cette ligne est là car

Envoyé par elnipal

Je veux récupérer les 4 premiers chiffres des valeurs qui sont sous la ligne qui commence par un 5 soit : 0423, 0422, 0459, 0364

Mais comme je l'ai écrit ce code n'est pas optimisé, ton code est plus synthétique

Cordialement

**Singular** · 23/11/2007, 20h18

Ah! Bien vu, fred65200

**triaguae** · 26/11/2007, 13h07

je n'ai peut être pas été très clair dans mes explications: je veux récupérer mes données à la suite les unes des autres sans cellule vide, sans $.
Maintenant, j'ai un autre problème! : dans mon ficher DAT, les lignes qui commencent par le 5 sont existantes dans un fichier excel mais pas forcément dans l'ordre de mon fichier DAT.
Entre chaque lot (puisque ces lignes commençant par 5 sont des numéros de lot) j'ai un certain nombre d'articles qui est égal au nombre de données à récupérer!
Dans le fichier xls joint, les lots sont dans le même ordre dans les 2 fichiers donc ça marche, mais ce n'est pas toujours le cas.

**Singular** · 26/11/2007, 13h42

Si le format final des données n'a pas à être respecté, la méthode la plus simple est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub RecupererDonneesDansFichierTexte()
    Dim sRef As String
    Dim sLigne As String
    Dim nLigne As Integer
    Dim sChemin As String
    Dim sNomFichier As String
    Dim sExtFichier As String
    Dim sCheminFichier As String
    Dim sDelimiteur As String
    Dim sColonne As String
 
    sChemin = "C:\Documents and Settings\VALERIE\Mes documents\MGMPLDAT.DAT"    sNomFichier = "MGMPLDAT"
    sExtFichier = ".DAT"
    sCheminFichier = sChemin & sNomFichier & sExtFichier
    sRef = "0000000005"
    sDelimiteur = "$"
    sColonne = "B"
 
    nLigne = 3
    Open sCheminFichier For Input As #1
    While Not EOF(1)
        Line Input #1, sLigne
        If Left(sLigne, Len(sRef)) = sRef Then
            Do
                Line Input #1, sLigne
                If sLigne = sDelimiteur Then Exit Do
                Range(sColonne & CStr(nLigne)).Value = "'" & sLigne
                Range(sColonne & CStr(nLigne)).Parse Destination:=Range(sColonne & CStr(nLigne))
                nLigne = nLigne + 1
            Loop
        End If
    Wend
    Close #1
    ActiveSheet.Name = sRef
End Sub