Discussion :

[bstages2000]

Bonjour,
voici mon souci
je souhaite transformer le fichier CRA ci-dessous en fichier csv resultat RES en utilisant la commande awk

CRA
id;code;date;attribut;valeur
1;23;1207;compte;val1
1;23;1207;telephone;t1
1;23;1207;adresse;test
2;25;1107;compte;val2
2;25;1107;telephone;t2
2;25;1107;adresse;titi

le but c'est de transformer certains champs de lignes de même id en colonne

RES
id;code;date;compte;telephone;adresse
1; 23 ;1207;val1 ;t1 ;test
2; 25 ;1107;val2 ;t2 ;titi

je cherche l'astuce mais je ne trouve pas, si vous pouvez, m'aider, ça m'aiderais beaucoup.

[ripat]

Essaye ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

$awk -f cmdes-awk ton-fichier-a-modifier

cmdes-awk

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
BEGIN {
    FS = ";"
    previous = ""
    new = ""
}
 
{
    if ( $1 $2 $3 == previous) {
        new = new ";" $5
    } else {
        if(new != "") print new
        previous = $1 $2 $3
        new = $1 ";" $2 ";" $3 ";" $5
    }
}
 
END {
        print  new
}

[bstages2000]

Bonjour,
Merci pour ton aide.
je viens d'exécuter le script que tu propose, ça à l'air de marcher.
il m'affiche ceci :

id; code ; date ; valeur
1; 23 ;1207 ; val1 ; t1 ; test
2; 25 ;1107 ; val2 ; t2 ; titi

je cherche encore à l'affiner pour avoir exactement ce que je souhaite (ci-dessous).

id;code ; date ; compte ; telephone ; adresse
1; 23 ; 1207 ; val1 ; t1 ; test
2; 25 ; 1107 ; val2 ; t2 ; titi

[ripat]

Dans le bloc BEGIN, ajoute simplement:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

print "id;code;date;compte;telephone;adresse"

[bstages2000]

éffectivement ce serait plus simple pour moi mais je ne souhaite pas figer les colonne puisque ma table peut varier, je souhaite recuper les colonne par $x (x=1;...)

[BlaireauOne]

Procédure awk :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
awk '
BEGIN {
    FS = ";"
    FlagFirstKey=1
    PreviousKey = ""
    NewRecord = ""
}
 
{
    #-- Record Number 1, ecr. 1ere partie du titre
    if (NR == 1) {
	printf("%s;%s;%s",$1,$2,$3)
	next
    }
    if ( $1 $2 $3 == PreviousKey) {
    	if (FlagFirstKey == 1) {
    		#-- ecr. complement de titre (1ere clé traitée)
		printf(";%s",$4)
	}
        NewRecord = NewRecord ";" $5
	next
    }
    if (NewRecord != "") {
	if (FlagFirstKey == 1) {
		#-- fin de traitement de la 1ere clé 
		print ""
    		FlagFirstKey=0
	} 
	print NewRecord
    } else {
	#-- ecr. complement de titre (1ere clé traitée)
	printf(";%s",$4)
    }
    PreviousKey = $1 $2 $3
    NewRecord = $1 ";" $2 ";" $3 ";" $5
}
END {
	print NewRecord
} ' CRA > RES.csv

RES.csv :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
id;code;date;compte;telephone;adresse
1;23;1207;val1;t1;test
2;25;1107;val2;t2;titi

[bstages2000]

Merci beaucoup,
ça marche !!

milles merci !!