Discussion :

[GruZloR]

Bonjour,

Novice en Excel, je suis confronté à un problème qui me fait rager.

J'ai une feuille qui fait office de base de données et une feuille "Devis". Mon idée est de remplir la base de données et d'intégrer les éléments dans le devis via une liste déroulante.

Lorsque je sélectionne un item de la BD, la totalité de la ligne de mon devis se remplie (Prix, remise...) : Ca, ça fonctionne

Mais lorsque je rajoute un enregistrement à la BD, la formule de remplissage du devis se fausse :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI($A9="";"";RECHERCHEV($A9;BD!$B$4:$O$1000;2;FAUX))

La table de matrice de la feuille BD se décale, et le dernier enregistrement de la BD n'est pas pris en compte. Commment toujours avoir une table à la bonne dimension??? (Le O1000 n'est pas très élégant non plus...)

Je joins un fichier pour être un peu plus clair. Merci par avance pour votre aide.

A plus

[Pierre Fauconnier]

Bonjour

Voici une discussion qui devrait t'aider, le but étant de nommer une plage en utilisant DECALER puis d'utiliser le nom de cette plage comme argument dans les fonctions, notamment de recherche...

Bon travail

[Bigalo]

Bonjour,

Si j’ai bien compris, tu ajoutes un élément à la base en insérant une ligne après la ligne 1, ce qui explique le "BD!$B$4" dans ta formule, alors que visiblement les données de la base commencent en ligne 2.

Dans tes RECHERCHEV, remplace la référence par le nom "Base" (ou un autre), défini ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(BD!$B$1;1;0):DECALER(BD!$O$1;MAX(BD!$A:$A);0)

La fonction MAX nécessite que tu continues à donner à chaque enregistrement un N° supérieur aux précédents. Sinon tu peux définir le nom ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(BD!$B$1;1;0):DECALER(BD!$O$1;NBVAL(BD!$A:$A) - 1;0)

Si tu envisages l’ajout de colonnes supplémentaires, il faut utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(BD!$B$1;1;0):DECALER(DECALER(BD!$A$1;0;NBVAL(BD!$1:$1) - 1);MAX(BD!$A:$A);0)

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(BD!$B$1;1;0):DECALER(DECALER(BD!$A$1;0;NBVAL(BD!$1:$1) - 1);NBVAL(BD!$A:$A) - 1;0)

Cordialement,

[GruZloR]

Ca marche du tonnerre de dieu. Merci beaucoup !

[Bigalo]

Quel enthouiasme Merci

Ca marche du tonnerre de dieu. Merci beaucoup !