Afficher des dates par défaut

**Nessie37** · 11/01/2008, 17h15

Bonjour,

Je ne sais pas si je poste dans le bon forum, au quel cas redirigez-moi.
Voilà mon problème :
Sur la miniature jointe, j'ai 2 zones de texte indépendantes dans lesquelles se trouvent des dates (période de consultation). Mon souci est que j'aimerais que les dates par défaut soient celle de l'exercice en cours 12 mois (du 01 aout au 31/juillet) :
- si date d'aujourd'hui est > au 01/08 de l'année en cours N, alors affichage date 1 = 01/08/N à date 2=aujourd'hui
- si date d'aujourd'hui est < au 01/08 de l'année en cours N, alors affichage date 1 = 01/08/N-1 et date 2 = aujourd'hui.

Ces zones de texte qui abritent les dates ont un évènement sur perte focus du type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Date1_LostFocus()
Me.camensuel2_sous_formulaire.Requery
Me.essai_sous_formulaire.Requery
Me.essaimoymens_sous_formulaire.Requery
 
End Sub

Cela est-il possible sans supprimer le code déjà présent ?

Merci par avance

**LedZeppII** · 11/01/2008, 19h34

Bonsoir,

Un exemple de code à mettre dans l'événement Sur Chargement du formulaire.

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Form_Load()
Dim dtDate As Date
 
dtDate = Date
If dtDate > DateSerial(Year(dtDate), 7, 31) Then
   Me.txtDateDu = DateSerial(Year(dtDate), 8, 1)
Else
   Me.txtDateDu = DateSerial(Year(dtDate) - 1, 8, 1)
End If
Me.txtDateAu = dtDate
End Sub

txtDateDu et txtDateAu sont les zones de textes des dates de début et fin de période.

A+

**Nessie37** · 14/01/2008, 10h04

Bnjour et merci !

Cela fonctionne, exemple : en ouvrant aujourd'hui mon appli, j'avais bien en date de début 01/08/2007 et la date d'aujourd'hui !

Euh...j'abuse si je demande à ce que la date de fin soit 31/07/N de l'année en cours si date d'aujourd'hui < 01/08 et date fin = 31/07/N+1 si date d'aujourd'hui > 01/08...

J'ai essayé de reprendre le code que tu m'as donné mais tu te doutes bien que j'ai du mal l'utiliser et çe ne fonctionne pas.

Cependant, je ne peux plus sélectionner moi-même une période de consult, du moins si, je peux changer le date de début et la date de fin mais ça n'affiche plus les info correspondant à ces périodes ! (exemple je veux consulter sur un mois ou une période antérieure bah...ça ne change plus mes infos). en fait ça a supprimé mes codes sur perte focus que j'avais sur les zones de texte qui abritaient mes dates. Peut-être est-ce normal et préférable, je ne sais guère...

Que faire ?

**LedZeppII** · 14/01/2008, 20h47

Bonsoir,

La fonction DateSerial(Année, Mois, Jour) renvoie la date correspondant à Jour/Mois/Année.
Si tu veux la date de fin de période au lieu de la date du jour :

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Form_Load()
Dim dtDate As Date
 
dtDate = txtDate
If dtDate > DateSerial(Year(dtDate), 7, 31) Then
   Me.txtDateDu = DateSerial(Year(dtDate), 8, 1)
   Me.txtDateAu = DateSerial(Year(dtDate) + 1, 7, 31)
Else
   Me.txtDateDu = DateSerial(Year(dtDate) - 1, 8, 1)
   Me.txtDateAu = DateSerial(Year(dtDate), 7, 31)
End If
End Sub

Ce code est à mettre dans l'événement Sur Chargement du formulaire.
A l'ouverture du formulaire les deux champs dates auront les dates de début et fin de la période en cours. Il n'est exécuté qu'une seule fois.

Tu laisses le code (celui qui fait un .Requery sur les sous-formulaires) que tu avais pour les deux zones de textes contenant tes dates.

A+

**Nessie37** · 15/01/2008, 12h15

Merci pour ta réponse.

Je fais les modif nécessaires et te tiens au courant.

**Nessie37** · 15/01/2008, 15h34

Impec ! Merci.
Par contre, quand j'ouvre mon form (mes dates étant celles voulues 01/08 au 31/07), les infos affichées ne sont pas automatiquement fonction de cette période, malgré les code sur perte focus (.requery etc..).
Il faut que, une fois ouvert, je mette mon form en mode crétion puis que je le passe en mode consult pour que s'opèrent les changement

...

**LedZeppII** · 15/01/2008, 18h11

Bonsoir,

Ajoute les .requery aussi dans l'événement Sur Chargement, après la mise à jour des dates.

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Form_Load()
Dim dtDate As Date
 
dtDate = txtDate
If dtDate > DateSerial(Year(dtDate), 7, 31) Then
   Me.txtDateDu = DateSerial(Year(dtDate), 8, 1)
   Me.txtDateAu = DateSerial(Year(dtDate) + 1, 7, 31)
Else
   Me.txtDateDu = DateSerial(Year(dtDate) - 1, 8, 1)
   Me.txtDateAu = DateSerial(Year(dtDate), 7, 31)
End If
 
Me.camensuel2_sous_formulaire.Requery
Me.essai_sous_formulaire.Requery
Me.essaimoymens_sous_formulaire.Requery
End Sub

A+

**Nessie37** · 16/01/2008, 11h04

Bonjour et merci.

C'est parfait. MAIS (il y en a toujours un avec moi), je ne comprends pas le phénomène suivant :
Par défaut, j'ai donc dans mes zones de texte en date1 01/08 et en date2 31/07. Si par exemple je ne touche pas à la date1 et que je change la date2, mes info correspondantes ne changent pas ! Il n'y a que si je change la date1 ou que si je place le curseur dans la date1 et que je tabule sur la date2 ou que je fasse "entrée" que cela change les infos qui s'afficheront alors selon les dates choisies.
Une explication à ce phénomène ?

**LedZeppII** · 16/01/2008, 18h43

Bonjour,

cela vient de ta gestion des évènements.
C'est ce code qui actualise tes sous-formulaires

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Me.camensuel2_sous_formulaire.Requery
Me.essai_sous_formulaire.Requery
Me.essaimoymens_sous_formulaire.Requery

Il est présent dans l'événement Sur Chargement du formulaire et dans l'évènemet "Sur perte de focus" de Date1.
Quand tu modifies la valeur de Date2 et que tu quittes Date2 l'événement "Perte de focus" de Date1 ne se déclenche pas.
Normal. Tu n'es pas entré dans le contrôle Date1 puis sorti.
Gère l'évènement "Sur perte de focus" de Date2 et mets y le même code que pour Date1.

Tu peux même créer un Sub qui sera appelée par les trois évéments gérés, t'évitant ainsi de dupliquer le même code.

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
' Actualiser les sous-formulaires
Sub ActualiserSousFormulaires()
Me.camensuel2_sous_formulaire.Requery
Me.essai_sous_formulaire.Requery
Me.essaimoymens_sous_formulaire.Requery
End Sub
 
Private Sub Form_Load()
Dim dtDate As Date
 
dtDate = Date
If dtDate > DateSerial(Year(dtDate), 7, 31) Then
   Me.Date1 = DateSerial(Year(dtDate), 8, 1)
   Me.Date2 = DateSerial(Year(dtDate) + 1, 7, 31)
Else
   Me.Date1 = DateSerial(Year(dtDate) - 1, 8, 1)
   Me.Date2 = DateSerial(Year(dtDate), 7, 31)
End If
' Appelle Sub ActualiserSousFormulaires
Call ActualiserSousFormulaires
End Sub
 
Private Sub Date1_LostFocus()
' Appelle Sub ActualiserSousFormulaires
Call ActualiserSousFormulaires
End Sub
 
Private Sub Date2_LostFocus()
' Appelle Sub ActualiserSousFormulaires
Call ActualiserSousFormulaires
End Sub

Autre point à vérifier : Dans les propriétés du contrôle Date2 vérifier qu'on a bien "Procédure événementielle" en face de l'événement "Sur perte de focus".

Dernière remarque : J'aurai plutôt choisi l'évément "Après MAJ" pour les zones de texte des dates 1 & 2.
Cela présente l'avantage de n'actualiser les sous-formulaires que si c'est réellement nécessaire.
L'événement "Perte de focus" a lieu systématiquement lorsque tu quittes le contrôle.

A+

**Nessie37** · 16/01/2008, 19h20

e suis vraiment désolée !!!!

Je n'avais pas vu que l'événement sur date2 avait disparu !!!!!
Mon dernier post n'aurait jamais eu lieu d'être.

Toutefois, ta réponse me permet de rebondir, quand tu dis

Envoyé par LedZeppII

Dernière remarque : J'aurai plutôt choisi l'évément "Après MAJ" pour les zones de texte des dates 1 & 2.
Cela présente l'avantage de n'actualiser les sous-formulaires que si c'est réellement nécessaire.
L'événement "Perte de focus" a lieu systématiquement lorsque tu quittes le contrôle.

Je l'ai mis là parce qu'on me l'a dit ainsi. T'avouant que je suis vraiment débutante, je n'ai pas réfléchi. En le mettant sur MAJ, j'aurai le même résultat, c'est-à-dire actualiser les données en fonction de la période choisie ?
"Actualiser qui si c'est réellement nécessaire", c'est-à-dire ? (désolée mais je m'instruis, je veux saisir les nuances)

Crdt

**LedZeppII** · 16/01/2008, 20h02

Pas grave

.

L'évènement "Après MAJ" ne se déclenche pour un contrôle que si son contenu change.
Trois exemples pour comparer les deux événements.

J'entre dans le contrôle Date1. Je ne change rien. Je quitte le contrôle.
=> événement "Sur perte de focus" se déclenche
J'entre dans le contrôle Date1. J'active un autre formulaire ou la fenêtre base de données.
=> événement "Sur perte de focus" se déclenche
J'entre dans le contrôle Date1. Je change la date. Je quitte le contrôle.
=> événement "Sur MAJ" se déclenche
=> événement "Sur perte de focus" se déclenche

Tu vois que l'évènement "Sur perte de focus" se déclenche souvent et que sur les trois exemples, un seul nécessite l'actualisation des sous-formulaires.
Dit autrement, il n'est utilise d'actualiser les sous-formulaires que si une date change.
C'est juste pour optimiser.
Ça fonctionne avec "perte de focus", mais potentiellement ça fait travailler l'application pour rien.

En espèrant que tu saisisse mieux la différence maintenant.
A+

**Nessie37** · 17/01/2008, 10h55

Très clair ! Merci.
Cela me permet de mieux comprendre un peu tout ça. Autant il y a des événements qui me sont clairs autant "sur perte focus" je ne voyais pas trop !

Envoyé par LedZeppII

Tu peux même créer un Sub qui sera appelée par les trois évéments gérés, t'évitant ainsi de dupliquer le même code.

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
' Actualiser les sous-formulaires
Sub ActualiserSousFormulaires()
Me.camensuel2_sous_formulaire.Requery
Me.essai_sous_formulaire.Requery
Me.essaimoymens_sous_formulaire.Requery
End Sub
 
Private Sub Form_Load()
Dim dtDate As Date
 
dtDate = Date
If dtDate > DateSerial(Year(dtDate), 7, 31) Then
   Me.Date1 = DateSerial(Year(dtDate), 8, 1)
   Me.Date2 = DateSerial(Year(dtDate) + 1, 7, 31)
Else
   Me.Date1 = DateSerial(Year(dtDate) - 1, 8, 1)
   Me.Date2 = DateSerial(Year(dtDate), 7, 31)
End If
' Appelle Sub ActualiserSousFormulaires
Call ActualiserSousFormulaires
End Sub
 
Private Sub Date1_LostFocus()
' Appelle Sub ActualiserSousFormulaires
Call ActualiserSousFormulaires
End Sub
 
Private Sub Date2_LostFocus()
' Appelle Sub ActualiserSousFormulaires
Call ActualiserSousFormulaires
End Sub

Là encore, j'avais déjà vu faire et je voulais utiliser cela mais je ne savais pas exactement comment. tu viens de mettre une fois pour toute dans ma tête le "manuel d'utilisation" pour créer une sub.

Je te remercie infiniment pour ta patience et ton aide.

Dernière petite question (du moins demande de confirmation), si j'ai bien saisi, si je veux que la MAJ en fonction des dates choisies se fasse uniquement après avoir validé la date2 (même sans changer celle-ci), je dois supprimer l'événement sur MAj de date1 et garder uniquement date2 ?

Je te dis à bientôt sûrement car j'aurai très certainement besoin de ton savoir précieux

(d'ailleurs, si tu peux, tu pourrais jeter un oeil sur mon post [URL="http://www.developpez.net/forums/showthread.php?t=439436"], sans vouloir facher Vodiem qui m'aide déjà bcp)

**LedZeppII** · 17/01/2008, 20h25

Envoyé par Nessie37

Dernière petite question (du moins demande de confirmation), si j'ai bien saisi, si je veux que la MAJ en fonction des dates choisies se fasse uniquement après avoir validé la date2 (même sans changer celle-ci), je dois supprimer l'événement sur MAj de date1 et garder uniquement date2 ?

Oui dans ce cas pas besoin de gestion d'évènement sur Date1.
Par contre si par valider tu entends passer par le contrôle Date2, modifier Date2 si besoin ou laisser telle quelle, alors il y a un problème avec l'évènement "Sur MAJ" de Date2.
Si on ne modifie pas le contenu de Date2 l'événement ne se déclenche pas.
Dans ce contexte d'utilisation, "Perte de focus" est plus adapté pour le contrôle Date2.

A+

**Jack78960** · 17/01/2008, 22h36

sur la propriét Default de ta table d'origine tu écris la formule suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=IIf( now() > DateSerial(Year(now()), 7, 31),DateSerial(Year(now()), 8, 1),DateSerial(Year(now()) - 1, 8, 1))

cette écriture permet de ne pas faire de VBA ==> si tu mets la colonne de ta table en remplacement de la même colonne de ton formulaire , ton formulaire profitera de la règle que tu viens de poser pour chaque enregistrement Nouveau

Il t'est possible de poser cette formule sur la propriété default de ta zone de saise de ton formulaire. ==> bien sur, le prochain formulaire n'en profite pas

==> voilà comment on limite le nombre de ligne VBA dans une application Access ==> moins on a de ligne vba , moins on aura de boggues dans l'avenir

==> la qualité d'une application access est inversionnement proportionnel au nombre de lignes VBA écrites

**Nessie37** · 18/01/2008, 09h26

Envoyé par LedZeppII

Oui dans ce cas pas besoin de gestion d'évènement sur Date1.
Par contre si par valider tu entends passer par le contrôle Date2, modifier Date2 si besoin ou laisser telle quelle, alors il y a un problème avec l'évènement "Sur MAJ" de Date2.
Si on ne modifie pas le contenu de Date2 l'événement ne se déclenche pas.
Dans ce contexte d'utilisation, "Perte de focus" est plus adapté pour le contrôle Date2.

A+

Merci bcp Zep' !
C'est vraiment très clair !

Au plaisir

**Nessie37** · 18/01/2008, 09h31

Envoyé par Jack78960

sur la propriét Default de ta table d'origine tu écris la formule suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=IIf( now() > DateSerial(Year(now()), 7, 31),DateSerial(Year(now()), 8, 1),DateSerial(Year(now()) - 1, 8, 1))

cette écriture permet de ne pas faire de VBA ==> si tu mets la colonne de ta table en remplacement de la même colonne de ton formulaire , ton formulaire profitera de la règle que tu viens de poser pour chaque enregistrement Nouveau

Il t'est possible de poser cette formule sur la propriété default de ta zone de saise de ton formulaire. ==> bien sur, le prochain formulaire n'en profite pas

==> voilà comment on limite le nombre de ligne VBA dans une application Access ==> moins on a de ligne vba , moins on aura de boggues dans l'avenir

==> la qualité d'une application access est inversionnement proportionnel au nombre de lignes VBA écrites

Bonjour,

Je te remercie pour ton intervention mais je n'ai pas très bien saisi ce que tu voulais me dire.
Tu peux reprendre ?

**Jack78960** · 18/01/2008, 19h24

salut, excuse moi pour cette réponse inadapté.

La propossition que je te fais est d'utiliser les proriétés standard d'une table en access; en effet , chaque champ d'une table peut avoir une "valeur par défaut"
==> exemple: quand tu crées un champ d'une table en Numérique , access affecte automatiquement la valeur 0 ,
à la propriété "valeur par défaut" (propriété default de l'ojet field d'un tabledef en VBA)
Sur ce genre de propriété , comme sur excel, tu peux initialiser cette propiété par une formule (note que l'expression commence par "=", comme les formules en excel)
celle que je t'ai proposée, exécute ce que tu désire obtenir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=IIf( now() > DateSerial(Year(now()), 7, 31),DateSerial(Year(now()), 8, 1),DateSerial(Year(now()) - 1, 8, 1))

Dès que tu mettra cette table dans un nouveau formulaire, ton formulaire profitera de la formule que tu as posée au niveau de la table
L'expression de la formule que je te fourni est en anglais ==> Access traduira les fonctions en français.

L'avantage de cette méthode est que pour effectuer la fonctionnalité que tu essais d'obtenir, nous n'avons eu aucune ligne vba à écrire . cqfd

**Nessie37** · 15/02/2008, 10h24

Merci pour le conseil Jack

Afficher des dates par défaut

VBA Access

Discussions similaires

Partager

Partager