Discussion :

[sophiesophie]

bonjour
s'il vous plait j'ai un petit problème j'ai utilisé ce code si dessous que j'ai trouvé dans ce site et je veux supprimer la table "nomtable" puis la reconstruire par ce code
je sais pas comment ajouter le code qui me permet de supprimer la table puis la reconstruire, s'il vous plait aidez moi.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
/*******************************************/
Sub tranfertCSV_Vers_NouvelleTableAccess(nomf, cheminf)
'Transfére un fichier CSV vers une nouvelle table Access
'depuis une macro Excel.
'
'Nécessite d'activer la référence
'"Microsoft ActiveX Data Objects x.x Library
'
Dim AccessCn As ADODB.Connection
Dim AccessRst As ADODB.Recordset
Dim Csv_CN As New ADODB.Connection
Dim Csv_Rst As New ADODB.Recordset
Dim DossierCSV As String, nomtable As String
Dim FichCSV As String, MaBase As String
Dim nbEnr As Long
 
'Répertoire du fichier CSV
DossierCSV = cheminf
'Nom du fichier CSV à transfèrer
FichCSV = nomf
'Chemin et nom de la base Access
MaBase = "C:\gestiondepaie1\base.mdb"
'Nom de la nouvelle Table Access
nomtable = "nbheure"
 
'Connection au fichier CSV
Csv_CN.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
DossierCSV & ";Extended Properties='text;FMT=Delimited'"
'Requète dans le fichier CSV
Csv_Rst.Open "SELECT * FROM " & FichCSV, Csv_CN, _
adOpenStatic, adLockOptimistic
 
'Connection à la base de données Access
Set AccessCn = New ADODB.Connection
AccessCn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=" & MaBase
 
Csv_CN.Execute "SELECT * INTO [" & nomtable & "] IN '" & _
MaBase & "' From [" & FichCSV & "]", nbEnr
 
AccessCn.Close
Csv_Rst.Close
Csv_CN.Close
Set AccessRst = Nothing
Set AccessCn = Nothing
Set Csv_Rst = Nothing
Set Csv_CN = Nothing
End Sub
 
 
/*******************************************/

merci pour tout

[wape]

Bonjour,

Essaye avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
(...)
AccessCn.Execute "DROP TABLE [" & nomtable & "]" '<-- Nouvelle ligne à ajouter
Csv_CN.Execute "SELECT * INTO [" & nomtable & "] IN '" & _
MaBase & "' From [" & FichCSV & "]", nbEnr
(...)

wape