Discussion :

[drthodt]

Bonjour,
à l'aide d'une macro je tente de recopier une valeur d'un fichier excel à un autre (les deux ont la même structure) à partir d'un numéro qu'ils ont en commun (sur la première colonne) et qui sert de référence.

C'est un bout de code que j'avais déjà utilisé tel quel sans souci et pourtant j'obtiens une erreur 1004 "la propriété Range de l'objet worksheet a échoué".
Voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
Sub Copieinfos()
Dim FL1 As Worksheet
Dim FL2 As Worksheet
Dim NoLigneF2 As Integer
Dim DerniereLigneF2 As Integer
DerniereLigneF1 As Integer
Dim identifiant As String
Dim PlageFL1 As Range
Dim c As Range
 
    Set FL2 = ThisWorkbook.ActiveSheet
    'nom du classeur secondaire
    Set FL1 = Workbooks("Classeur2.xls").Worksheets("Feuil1")
 
    'test si le filtre du fichier Classeur2 est actif
    If FL1.FilterMode Then
 
    'si c'est le cas on l'enlève
    FL1.ShowAllData
 
    End If
 
 
 
 
 'Plage de recherche de l'identifiant dans FL1
    DerniereLigneF1 = FL1.Range("A65535").End(xlUp).Row
    MsgBox DerniereLigneF1
 
    Set PlageFL1 = FL1.Range(Cells(2, 1), Cells(DerniereLigneF1, 1))
 
    'Dernière ligne renseignée dans FL2
    DerniereLigneF2 = FL2.Range("A65535").End(xlUp).Row
 
    'Lecture de la cellule ds Classeur A (noligne commence à 2 car en-tête)
    For NoLigneF2 = 2 To DerniereLigneF2
 
                     'on a un affaire alors on lit l'identifiant
             identifiant = FL2.Cells(NoLigneF2, 1).Value
             'la recherche de l'identifiant lu dans FL2 se fait dans FL1
             With PlageFL1
                  Set c = .Find(identifiant, LookIn:=xlValues, Lookat:=xlWhole)
                  If Not c Is Nothing Then 'donnée trouvée
                       'on colle les infos dans FL1
                       'Récupération de l'info
                        FL2.Activate
                        FL2.Cells(NoLigneF2, 47).Select
                        Selection.Copy
                        FL1.Activate
                        FL1.Cells(c.Row, 47).Select
                     End If
                  Set c = Nothing
              End With
 
    Next
    Set PlageFL1 = Nothing
    End Sub

Mon erreur 1004 sur la propriété Range apparaît à cet endroit:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set PlageFL1 = FL1.Range(Cells(2, 1), Cells(DerniereLigneF1, 1))

D'ou peut provenir cette erreur sachant que, comme je l'ai dit au-dessus, j'ai déjà utilisé de nombreuses fois le même code sans aucun problème.
Merci pour vos remarques,
M

[Gorfael]

Salut
Déjà, un dim manquant, mais bof

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub Copieinfos()
Dim FL1 As Worksheet
Dim FL2 As Worksheet
Dim NoLigneF2 As Integer
Dim DerniereLigneF2 As Integer
Dim DerniereLigneF1 As Integer
Dim identifiant As String
Dim PlageFL1 As Range
Dim c As Range
Set FL2 = ThisWorkbook.ActiveSheet
Set FL1 = Workbooks("Classeur2.xls").Worksheets("Feuil1")
If FL1.FilterMode Then FL1.ShowAllData
DerniereLigneF1 = FL1.Range("A65535").End(xlUp).Row
MsgBox DerniereLigneF1
Set PlageFL1 = FL1.Range(FL1.Cells(2, 1), FL1.Cells(DerniereLigneF1, 1))
DerniereLigneF2 = FL2.Range("A65535").End(xlUp).Row
For NoLigneF2 = 2 To DerniereLigneF2
    identifiant = FL2.Cells(NoLigneF2, "A")
    With PlageFL1
        Set c = .Find(identifiant, LookIn:=xlValues, Lookat:=xlWhole)
        If Not c Is Nothing Then FL2.Cells(NoLigneF2, 47).Copy FL1.Cells(c.Row, 47)
        Set c = Nothing
    End With
Next
End Sub

devrait sans doute mieux fonctionner
J'en ai profité pour simplifier, mais pas forcément utile
A+

[LeForestier]

Bonjour,
si tu a plus de 32000 lignes et quelques,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim DerniereLigneF2 As Integer
'devrair être remplacer par...
Dim DerniereLigneF2 As long

et je ne sais pas si c'est une erreur de copier/coller mais..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DerniereLigneF1 As Integer.....??

A+

[Bigalo]

Bonsoir,

Ce code ne peut pas marcher. Tu as dû le modifier depuis l’utilisation précédente :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    Set FL2 = ThisWorkbook.ActiveSheet
    'nom du classeur secondaire
    Set FL1 = Workbooks("Classeur2.xls").Worksheets("Feuil1")
 'Plage de recherche de l'identifiant dans FL1
    DerniereLigneF1 = FL1.Range("A65535").End(xlUp).Row
    Set PlageFL1 = FL1.Range(Cells(2, 1), Cells(DerniereLigneF1, 1))

Cells sans qualificatif fait référence à la feuille active, FL2 dans ton code. Tu essaies donc de définir une plage de FL1, composée exclusivement de cellules de FL2. Logique que cela plante.

Essaie de corriger ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Set PlageFL1 = Range(FL1.Cells(2, 1), FL1.Cells(DerniereLigneF1, 1))

Je n’ai pas testé, mais je suis à peu près sûr que cela résoud le problème

[Bigalo]

Bonsoir,

Bonjour,
si tu a plus de 32000 lignes et quelques

Si le problème venait de là, ce ne serait pas une erreur 1004, mais plutôt une erreur 6 (dépassement de capacité) !

[LeForestier]

Bonsoir,



Si le problème venait de là, ce ne serait pas une erreur 1004, mais plutôt une erreur 6 (dépassement de capacité) !

Excact... répondu un peu trop vite

[Bigalo]

[drthodt]

Bonsoir,

Ce code ne peut pas marcher. Tu as dû le modifier depuis l’utilisation précédente :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    Set FL2 = ThisWorkbook.ActiveSheet
    'nom du classeur secondaire
    Set FL1 = Workbooks("Classeur2.xls").Worksheets("Feuil1")
 'Plage de recherche de l'identifiant dans FL1
    DerniereLigneF1 = FL1.Range("A65535").End(xlUp).Row
    Set PlageFL1 = FL1.Range(Cells(2, 1), Cells(DerniereLigneF1, 1))

Cells sans qualificatif fait référence à la feuille active, FL2 dans ton code. Tu essaies donc de définir une plage de FL1, composée exclusivement de cellules de FL2. Logique que cela plante.

Essaie de corriger ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Set PlageFL1 = Range(FL1.Cells(2, 1), FL1.Cells(DerniereLigneF1, 1))

Je n’ai pas testé, mais je suis à peu près sûr que cela résoud le problème

Salut, merci effectivement cela fonctionne!

PS. Pour le Dim oublié c'était bien ne erreur de copier/coller, par contre j'avais oublié de mettre mon paste sur ma feuille de destination.
Ca fonctionne impec à présent grand merci à tous!

[Bigalo]

Bonjour,

Ca fonctionne impec à présent grand merci à tous!

De rien

Comme quoi une bonne relecture du code, sans même ouvrir Excel, peut suffire.