1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67
|
@echo on
rem How do I open Regedit.exe at any specific key ? (http://www.jsifaq.com/SUBM/tip6200/rh6211.htm)
rem If you wish to open Regedit.exe at a specific key:
setlocal
if {%1}=={} goto prompt
set key=%1
if {^%key:~0,1%}=={^"} goto open
set key="%key%"
:open
if /i {^%key:~0,5%}=={^"HKLM} set key=%key:"HKLM="HKEY_LOCAL_MACHINE%&goto get
if /i {^%key:~0,5%}=={^"HKCU} set key=%key:"HKCU="HKEY_CURRENT_USER%&goto get
if /i {^%key:~0,5%}=={^"HKCR} set key=%key:"HKCR="HKEY_CLASSES_ROOT%&goto get
if /i {^%key:~0,4%}=={^"HKU} set key=%key:"HKU="HKEY_USERS%&goto get
if /i {^%key:~0,5%}=={^"HKCC} set key=%key:"HKCC="HKEY_CURRENT_CONFIG%
:get
rem Ajout uniquement pour HKCU
if /i {^%key:~0,11%}=={^"HKEY_USERS} set key=%key:"HKEY_USERS="Poste de travail\HKEY_USERS%&goto next
if /i {^%key:~0,30%}=={^"HKEY_LOCAL_MACHINE\System\CCS} set key=%key:"HKEY_LOCAL_MACHINE\SYSTEM\CCS="HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet%
:next
rem généraliser l'ajout sur toutes les ruches, dans ce cas supprimer l'ajout uniquement pour HKCU
rem à vérifier
rem if /i {^%key:~0,2%}=={^"H} set key=%key:"HK="Poste de travail\HK%&goto next
set regedt=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Applets\Regedit
reg.exe ADD %regedt% /v LastKey /d %key% /f>nul 2>&1
if NOT %ERRORLEVEL% EQU 0 @echo %regedt% NOT found.
endlocal
start regedit.exe
goto :EOF
:prompt
set /p key=Enter the key to open.
if {^%key:~0,1%}=={^"} goto open
set key="%key%"
goto open
rem 2. There are 3 ways to use RegKey.bat:
rem A.1. Create a shortcut to the RegKey.bat file.
rem A.2. Set the icon of this shortcut to Regedit.exe.
rem A.3. Set it to run in a normal window.
rem A.4. Double-click the icon and enter the key or "".
rem
rem B.1. Start / Run / RegKey <The Key> / OK or
rem B.2. Start / Run / RegKey "" / OK.
rem
rem C.1. Open a CMD prompt.
rem C.2. Type RegKey <The Key> and press Enter or
rem C.3. Type RegKey "" and press Enter.
rem
rem NOTE: Reg.exe is from the Windows 2000 Support Tools or the Reg.exe that is built into Windows XP and later.
rem
rem NOTE If you implemented tip 2358, How do I prevent Regedit from using the last state, you must undo the permissions change.
rem
rem NOTE: You could also implement tip 6200, How do I prevent Regedit from remembering the last key, without altering registry permissions, and use it instead of RegKey "".
rem
rem NOTE: I have implemented the following abbreviations that you can use:
rem
rem Abbreviation Key
rem HKLM HKEY_LOCAL_MACHINE
rem HKLM\SYSTEM\CCS HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet
rem HKCU HKEY_CURRENT_USER
rem HKU HKEY_USERS
rem HKCR HKEY_CLASSES_ROOT
rem HKCC HKEY_CURRENT_CONFIG |
Partager