[XSLT]Des balises dans du texte

**Natim87** · 25/01/2008, 13h12

Bonjour,

J'ai le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
<?xml version="1.0" ?>
<?xml-stylesheet type="text/xsl" href="template.xsl"?>
<racine>
     <text>
       blabla ...
       <balise target="http://www.google.ca"> MOI </balise>
       blalal...
       <balise target="http://www.yahoo.ca"> MOI </balise>
       blall...
     </text>
</racine>

Et je voudrais afficher le texte avec les liens déjà traité.
Qu'est-ce qu'il faudrait que je modifie dans mon XSLT :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" encoding="utf-8" version="4.0" indent="yes" />
 
  <xsl:template match="/">
    <html lang="fr" xml:lang="fr">
      <head><title>Essayons de faire les choses bien ;)</title></head>
      <body>
        <xsl:apply-templates select="racine" />
      </body>
    </html>
  </xsl:template>
 
  <xsl:template match="racine">
    <div>
      <xsl:apply-templates select="text" />
    </div>
  </xsl:template>
 
  <xsl:template match="text">
    <p>
      <xsl:value-of select="." />
      <xsl:apply-templates select="balise" />
    </p>
  </xsl:template>
 
  <xsl:template match="balise">
    <a href="{@target}"><xsl:value-of select="." /></a>
  </xsl:template>
</xsl:stylesheet>

Si vous souhaitez le code en action : http://download.trunat.fr/xslt/template.xml
Merci de votre aide

Natim

**Erwy** · 26/01/2008, 08h22

essaye

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
  <xsl:template match="text">
    <p>
      <xsl:apply-templates select="node()" />
    </p>
  </xsl:template>
 
  <xsl:template match="balise">
    <a href="{@target}"><xsl:value-of select="." /></a>
  </xsl:template>
  <xsl:template match="text/text()">
 
      <xsl:value-of select="." />
       </xsl:template>

**Natim87** · 26/01/2008, 11h48

Ta solution fonctionne, mais voici finalement la mienne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
<xsl:template match="text">
    <p>
      <xsl:apply-templates />
    </p>
  </xsl:template>
 
  <xsl:template match="balise">
    <a href="{@target}"><xsl:value-of select="." /></a>
  </xsl:template>

Merci
Natim

**Erwy** · 26/01/2008, 12h13

Oui, parce que tu utilises une template par defaut (peut être sans le savoir ?) sur text() qui ressemble à celle que j'ai fourni.
Attention donc, si tu ne connais pas bien les templates par défaut tu risques d'avoir des surprises en cas de modif

[XSLT]Des balises dans du texte

XSL/XSLT/XPATH XML

Discussions similaires

Partager

Partager