Discussion :

[spookyz]

Bonjour voila j'aimerai savoir quel est le code qui me permeterai de copier une plage de cellules dans excel et qui lenregistrerai en tant que feuille excel ne prenant pas en compte les macros tout les 3 du mois en cours et qui lui donnerai comme nom "Archive du mois de (en cours)"
exemple:Archive du mois de Fevrier si nous sommes en Fevrier etc...
et tout ça sans modifier a la feuille qui a servie a l'edition de cette nouvelle feuille
ps:peut etre qu'il faut comprendre classeur a la
place de feuille ???
d'avance merci pour votre aide
je suis novice je pense qu'il est bon de le preciser

[fring]

Bonjour,

On pourrait imaginer quelque chose mais avant que je mette mon neurone en surchauffe j'ai une petite question...

Le fichier dans lequel se trouvera la macro sera d'office ouvert tout les jours ?

Sinon je ne vois pas comment il pourra détecter qu'on est le 3 du mois

[spookyz]

bonjour et merci de votre aide le dossier contenant la macro sera ouvert presque tout les jours mais peut etre qu'il faudrait alors parametrer pour que ce sois a partir du 3 jusqu'au 12 mais qu'il le sauve 1 seul fois par mois
d'avance merci et toutes mes excuses a votre neurones

[fring]

Bonjour,

J'aurais encore besoin d'une petite précision, la plage de cellule à copier sera toujours identique ou elle sera variable ?

[fring]

Bonjour,
Voici ce que je propose :

1. Code à insérer dans un Module, j'ai laissé en commentaire les adaptations à faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub archivage()
Dim Chemin$, Nom$
 
If Sheets(1).Range("IV1") = 1 Then Exit Sub
Application.ScreenUpdating = False
 
Chemin = "D:\Temp\" '<-- adapter le chemin pour la sauvegarde du fichier
Nom = "Archive_" & Format(Date, "mmmm\_yyyy")
 
Sheets(1).Range("A1:H30").Copy '<-- adapter le n° de la feuille et la plage à copier
Application.Workbooks.Add xlWBATWorksheet
With ActiveSheet
.Paste
.Name = Nom
.Range("A1").Select
End With
Application.DisplayAlerts = False
With ActiveWorkbook
.SaveAs Chemin & Nom & ".xls"
.Close
End With
 
Application.CutCopyMode = False
Application.DisplayAlerts = True
Application.ScreenUpdating = True
Sheets(1).Range("IV1") = 1 '<-- adapter le n° de la feuille
MsgBox "Archivage effectué"
End Sub

2. Code à insérer dans ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Workbook_Open()
Dim Jour As Byte
Jour = Format(Date, "d")
Select Case Jour
Case 3 To 12
archivage
Case Is > 12
Sheets(1).Range("IV1") = 0 '<-- adapter le n° de la feuille
End Select
End Sub

Cela devrait répondre à ta demande
@+