Discussion :

[iandeleury]

Bonjour à tous,

J'ai développé une application en VB.net qui gère les données dans une BDD Access(97).
Est ce possible de générer une sauvegarde de ma BDD automatiquement (toute les semaine ou tous les moi) à un emplacement spécifique? Une option pour ça dans Access?

Si oui, comment dois-je processder?

Merci par avance

IaN

[cbleas]

Bonjour,
Access est un fichier contrairement à sql server. Donc il te suffit de faire une sauvegarde du fichier MDB.
Bonne journée

[iandeleury]

Bonjour cbleas,

Merci pour ta réponse
Ok pour la sauvegarde mais comment faire pour qu'elle soit faite automatiquement?
On peut faire ça avec du code ? en VBA ou depuis mon application VB.net?
Si jamais tu as un code à balancer n'hésite pas

Encore merci pour ta rèponse cbleas

[Invité]

Salut

Je ne connais pas VB.net, mais un simple copier de fichier (ton .mdb) devrait suffire, sans passer par du VBA.

En t'assurant avant que ta base n'est pas utilisée (par exemple en contrôlant qu'il n'y a pas de fichier .ldb

Starec

[le.dams]

Bonjour,

Passe par la commande DOS "xcopy" (pour connaître les paramètres tapes "xcopy /?" dans une fenêtre DOS) que tu configures dans un fichier x.bat
Puis tu programmes ce dernier par le planificateur et hop le tour et joué !

[vodiem]

en complément à le.dams et dans l'idée de Starec:
en dos: if not exist "chemin\fichier.ldb" (x)copy "source" "destination"

mais tu peux aussi jeter une oeil sur FileSystemObject et faire un VBScript.
cf FAQ VBScript.

[francishop]

Bonsoir,

Pour faire une sauvegarde mensuelle de notre base de données, depuis ACCES, et VBA. (VB.net?... Inconnu au bataillon!)

Pour cela, on va créer :
Un dossier destiné à la sauvegarde mensuelle de la base. Ce dossier, "Sauve", est placé dans le même répertoire que la base.

Une table "tblSauvegarde" avec un champ date "Date_Sauvegarde"
La fonction suivante sera placée dans un module général.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Public Function SauvegardeMois()
 
    Dim varDernierSauvegarde As Variant, Madate As Date
    Dim MoisCourant As Integer, MoisSauve As Integer
    Dim fso As Object, strDest As String
 
    MoisCourant = Month(Date)
    Madate = Date
    varDernierSauvegarde = DMax("Date_Sauvegarde", "tblSauvegarde")
 
    If IsNull(varDernierSauvegarde) Then
        MoisSauve = 0
    Else
        MoisSauve = Month(varDernierSauvegarde)
    End If
 
    If MoisSauve <> MoisCourant Then ''premier démarrage du mois--> Sauvegarde
 
    strDest = CurrentProject.Path & "\Sauve\" & _
          Left(CurrentProject.Name, Len(CurrentProject.Name) - 4) & _
          "_Sauve_" & Format(Now, "yyyy mm dd hh nn ss") & "." _
          & Right(CurrentProject.Name, 3)
    Set fso = CreateObject("Scripting.FileSystemObject")
    fso.CopyFile CurrentProject.FullName, strDest
    Set fso = Nothing
 
        CurrentDb.Execute "Insert Into tblSauvegarde Values (" _
                  & CDbl(Madate) & ")"
        MsgBox "La sauvegarde mensuelle a été réalisée", vbInformation
    End If
 
End Function

Par une macro "AutoExec" qui va "ExécuterCode", suivant action,(Comme au tiercé : dans le désordre) on va appeller la fonction "SauvegardeMois()"

L'action sera ainsi réalisée au premier démarrage de la base chaque mois une seule fois.

Cordialement.

[vodiem]

salut francishop,
moi je ne suis pas trop chaud pour la sauvegarde à l'ouverture de la base.
c'est plus compliqué de vérifier si les tables ne sont pas en édition avant de faire la copie si on est sur une appli dorsale/frontales.

[francishop]

Bonsoir à toi Vodiem,
Et tiens, pendant que j'y suis, Bonsoir à tous,

Effectivement je suis tombé dans la facilité de répondre à cette demande de sauvegarde automatique comme pour un seul et même utilisateur.

Par contre, rien n'empêche de mettre le code concernant la sauvegarde derrière un bouton. (Ce que je fais lors de développement.)

Il est également vrai, qu'on peut indiquer les risques d'une procédure tout en prescrivant le remêde. L'un n'empêche pas l'autre....

Cordialement.

[Oliv'83]

Bonjour à tous,

Je suis extrêmement intéressé par cette idée de sauvegarde automatique. J'ai donc suivi scrupuleusement le code que j'ai mis derrière un bouton et cela semble fonctionner.

Mais j'ai deux questions à ce sujet :

a) le fichier de sauvegarde porte une extension .cdb, je ne connais pas ce type d'extension kesako?

b) J'ai bien réussi à ouvrir la sauvegarde avec Access mais il me semble au vu de la taille du fichier qu'il ne s'agisse que de la sauvegarde de la partie frontale de ma base. Moi ce qui m'intéresse ce serait plutôt (le chien de Mickey ) une sauvegarde de la dorsale dont les données sont beaucoup plus sensibles. Mon niveau en VBA est bien en dessous de celui requis pour la modification adéquate du code de francishop alors si quelqu'un pouvait m'aider ce serait super. Bien évidement ma dorsale n'est pas dans le même dossier que ma frontale...

Merci d'avance

Oliv'

[francishop]

Bonsoir,

Il est possible de copier directement la base. Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub cmd_SauveBase_Click()
 Dim strCurrent, strDest As String '
    strCurrent = CurrentProject.Path & "\RptSmp00.mdb" 'Remplace par le chemin complet si besoin
    strDest = CurrentProject.Path & "\Sauvegarde\RptSmp00.mdb"
 FileCopy strCurrent, strDest
End Sub

Mais Comme on ne veut pas écraser l'ancienne sauvegarde
.......Comme on veut du "Sur mesure"
.......Comme dit le Barbier:
......"Comme il a le menton on va lui faire la barbe!"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Public Function SauveDorsaleMois()
 
    Dim varDernierSauvegarde As Variant, Madate As Date
    Dim MoisCourant As Integer, MoisSauve As Integer
    Dim strCurrent, strDest As String
 
    MoisCourant = Month(Date)
    Madate = Date
    varDernierSauvegarde = DMax("Date_Sauvegarde", "tblSauvegarde")
 
    If IsNull(varDernierSauvegarde) Then
        MoisSauve = 0
    Else
        MoisSauve = Month(varDernierSauvegarde)
    End If
 
    If MoisSauve <> MoisCourant Then ''premier démarrage du mois--> Sauvegarde
 
 
    strCurrent = CurrentProject.Path & "\RptSmp00.mdb"
    strDest = CurrentProject.Path & "\Sauve\" & _
          "RptSmp00_Sauve_" & Format(Now, "yyyy mm dd hh nn ss") & ".mdb"
 
    FileCopy strCurrent, strDest
 
 
        CurrentDb.Execute "Insert Into tblSauvegarde Values (" _
                  & CDbl(Madate) & ")"
        MsgBox "La sauvegarde mensuelle a été réalisée", vbInformation
    End If
 
End Function

a) le fichier de sauvegarde porte une extension .cdb, je ne connais pas ce type d'extension kesako?

Alors comme ça on est en "2007"...Extension 4, et pas 3 comme les "Vétérans" qui sont toujours avec .mdb. Rectifie dans le module....

Cordialement.

[Oliv'83]

Merci de ta réponse.

Je dois faire une erreur de libellé dans la définition de mes adresses car cela ne fonctionne pas et MVB m'indique "numéro ou nom de fichier incorrect"

voici mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
Private Sub btn_Sauvegarde_Click()
Dim strCurrent, strDest As String
    strCurrent = CurrentProject.Path & "\CAG_2008_V4_beDorsale_(8).accdb"
    strDest = CurrentProject.Path & "\Sauve\CAG_2008_V4_beDorsale_(8).accdb"
 FileCopy strCurrent, strDest
End Sub

L'adresse complète est
C:\Users\Oliv'\Desktop\Access\TRAVAIL\Fractionnée\Dorsales\CAG 2008 V4 beDorsale (8).accdb

Je ne maîtrise pas encore assez VBA et je ne comprends pas l'expression :
CurrentProject.Path

serait il possible d'avoir des explications?

Alors comme ça on est en "2007"...Extension 4, et pas 3 comme les "Vétérans" qui sont toujours avec .mdb. Rectifie dans le module....

En fait "comme ça" j'ai pris ce qu'il y avait "sur le marché" au moment où j'ai décidé de faire le grand saut ACCESS. J'en déduis que .cdb concerne les sauvegardes d'Access 2007??

Bonne soirée

Oliv'

[francishop]

Bonsoir,

Je soupçonne que ta frontale est dans le dossier-->Fractionnée
et la dorsale dans le dossier suivant-->Dorsales

On pourrait reprendre l'intégralité du chemin et faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub cmdComplet_Click()
Dim strCurrent, strDest As String '
'On indique l'endroit, et quelle base copier
    strCurrent = "C:\Users\Oliv'\Desktop\Access\TRAVAIL\Fractionnée\Dorsales\CAG 2008 V4 beDorsale (8).accdb"
'On indique ou aller copier et sous quel nom 
'(Qu'est-ce-->Oliv': qu'apporte cet accent?)
strDest = "C:\Users\Oliv'\Desktop\Access\TRAVAIL\Fractionnée\Sauve\Dorsales\CAG 2008 V4 beDorsale (8).accdb"
'(Ici le dossier "Sauve" a été placé dans "Fractionnée")
 FileCopy strCurrent, strDest
End Sub

Avec ce genre de "Laïus" tu commences à comprendre pourquoi on préfères partir de l'emplacement de la base ou on est positionné.
Si ce n'est pas possible ou si besoin de changer les emplacements on va créer une table ou stocker les emplacements.
tblChemin-->2 champs textes-->CheminBase et -->CheminDestin (Tu peux être généreux sur la taille des champs au vu du nom de tes dossiers.
A cet effet il faut retenir : Des noms courts, et tes bases domiciliées au plus près possible de "C"
Dans le formulaire qui va être notre rampe de lancement de notre sauvegarde, on lui donne pour source cette table et sur les champs :
Sur CheminBase :
C:/Users/Oliv'/Desktop/Access/TRAVAIL/Fractionnée/Dorsales/CAG 2008 V4 beDorsale (8).accdb

Sur CheminDestin :
C:/Users/Oliv'/Desktop/Access/TRAVAIL/Fractionnée/Sauve/Dorsales/CAG 2008 V4 beDorsale (8).accdb

Et sur un bouton de ce formulaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub cmdComplet_Click()
Dim strCurrent, strDest As String
    strCurrent = Me.CheminBase
    strDest = Me.CheminDestin
 FileCopy strCurrent, strDest
End Sub

Nota :Une attention particulière à / ou \

D'autre part, dans le module tu sélectionnes-->"CurrentProject.Path" puis touche F1.

... J'en déduis que .cdb concerne les sauvegardes d'Access 2007??

Devinette :
.accdb
.mdb
Sachant que j'ai fais une erreur en écrivant :"Extension 4, et pas 3"(3 était bon...)

Cordialement.

[Oliv'83]

UN GRAND MERCI pour ce cours magistral

J'ai réussi à faire ce que je souhaitais

Je soupçonne que ta frontale est dans le dossier-->Fractionnée
et la dorsale dans le dossier suivant-->Dorsales

Perdu ma frontale était dans le dossier Frontales lui même dans le dossier Fractionnée

A cet effet il faut retenir : Des noms courts, et tes bases domiciliées au plus près possible de "C"

J'avais lu en effet cela dans un très bon tutoriels concernant le déploiement d'une base et je l'ai mis en pratique sur le réseau utilisateur. Malheureusement je ne suis pas connecté à ce réseau pour le développement de mon appli et donc je me permets quelques libertés sur mon PC.
Je n'ai pas retenu pour cette application ton idée de table supplémentaire mais je la garde sous le coude au cas où, un jour j'ai plusieurs sauvegardes à faire. En revanche j'ai introduit la sauvegarde "timecodée" que tu décris plus haut afin de savoir de quand elle a été réalisée.

D'autre part, dans le module tu sélectionnes-->"CurrentProject.Path" puis touche F1.

J'ai l'impression que j'ai un problème avec l'aide de la version 2007. Quand je clique sur F1, Access se connecte à l'aide en ligne et je n'obtiens jamais aucune réponse ou plutôt toujours la même : Aucun résultat n'a été trouvé pour « CurrentProject.Path ».

Soit je merdois lamentablement soit c'est l'aide de la version 2007


Quant à ta devinette je ne suis pas sur de l'avoir comprise...

Bonne journée

Oliv'

P.S. L'apostrophe après Oliv c'est un peu comme une signature, comme la virgule de Nike. Olive je trouve cela trop féminin et Oliv il manque quelque chose

[jeanpierre78]

Bonjour,

J'ai une base de données composée d'une BD "Compta_ASC_data.mdb" et d'une BD "Compta_ASC_prog.mdb". Les tables sont liées. Pour déclencher une sauvegarde mensuelle des données ("Compta_ASC_data.mdb") au démarrage (ExécuterCode, SauveDorsaleMois(), dans la macro autoexec), j'ai utilisé la fonction "SauveDorsaleMois()" définie par francishop. J'ai alors une erreur 53 "Fichier introuvable" sur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FileCopy strCurrent, strDest

Ce qui est normal puisque mes BD sont ouvertes. Si je demande une sauvegarde d'une BD non liée, "SauveDorsaleMois()" fonctionne.

Comment faire pour sauvegarder ma BD "data" alors que la BD "prog" est ouverte?

Jean-Pierre

[jeanpierre78]

Bonsoir,

En recherchnant j'ai trouvé une solution :
* de créer une table tblSauvegarde avec un champ date Date_Sauvegarde
* définir le modules defSauvegardeMois()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Public Function SauvegardeMois()
 
    Dim varDernierSauvegarde As Variant, Madate As Date
    Dim MoisCourant As Integer, MoisSauve As Integer
    Dim fso As Object, strDest As String
 
    MoisCourant = Month(Date)
    Madate = Date
    varDernierSauvegarde = DMax("Date_Sauvegarde", "tblSauvegarde")
 
    If IsNull(varDernierSauvegarde) Then
        MoisSauve = 0
    Else
        MoisSauve = Month(varDernierSauvegarde)
    End If
 
    If MoisSauve <> MoisCourant Then ''premier démarrage du mois--> Sauvegarde
 
        strName = CurrentProject.Path & "\Compta_ASC_data_2003.mdb"
        strDest = CurrentProject.Path & "\Sauve\" & Left("Compta_ASC_data_2003.mdb", Len("Compta_ASC_data_2003.mdb") - 4) & "_Sauve_" & Format(Now, "yyyy_mm_dd") & "." & Right("Compta_ASC_data_2003.mdb", 3)
 
        Set fso = CreateObject("Scripting.FileSystemObject")
        fso.CopyFile strName, strDest
        Set fso = Nothing
 
        CurrentDb.Execute "Insert Into tblSauvegarde Values (" & CDbl(Madate) & ")"
        MsgBox "La sauvegarde mensuelle a été réalisée et placée dans : " & vbCrLf & " " & vbCrLf & strDest, vbInformation
    End If
 
End Function

* l'appeler dans la macro AutoExec

Jean-Pierre

[Commandeur]

Bonjour,

Tout d'abord merci de ton code que tu a créé, il est tres utile.
Juste une question, comment je peux précisé les chemin des fichiers de destination?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Public Function SauvegardeMois()
 
    Dim varDernierSauvegarde As Variant, Madate As Date
    Dim MoisCourant As Integer, MoisSauve As Integer
    Dim fso As Object, strDest As String
 
    MoisCourant = Month(Date)
    Madate = Date
    varDernierSauvegarde = DMax("Date_Sauvegarde", "tblSauvegarde")
 
    If IsNull(varDernierSauvegarde) Then
        MoisSauve = 0
    Else
        MoisSauve = Month(varDernierSauvegarde)
    End If
 
    If MoisSauve <> MoisCourant Then ''premier démarrage du mois--> Sauvegarde
 
        strName = CurrentProject.Path & "c:\Budget compte.mdb"
        strDest = CurrentProject.Path & "d:\Sauve\" & Left("Budget compte.mdb", Len("Budget compte.mdb") - 4) & "_Sauve_" & Format(Now, "yyyy_mm_dd") & "." & Right("Budget compte.mdb", 3)
 
        Set fso = CreateObject("Scripting.FileSystemObject")
      fso.CopyFile strName, strDest
        Set fso = Nothing
 
        CurrentDb.Execute "Insert Into tblSauvegarde Values (" & CDbl(Madate) & ")"
        MsgBox "La sauvegarde mensuelle a été réalisée et placée dans : " & vbCrLf & " " & vbCrLf & strDest, vbInformation
    End If
 
End Function

quant je precise mes destanations le code ne fonctionne plus.

Merci de ton coup main.