Discussion :

[kenobyalex]

Bonjour à tous,

Voici mon prob, j'ai créé un formulaire de type Graphique et je souhaiterais l'exporter sous Excel.
Je cherche depuis hier soir sur le forum, sur le net, je ne trouve pas ce que je veux.
Quelqu'un aurait-il une idée, sachant que je ne veux rien de bien compliqué, juste le graph copié dans Excel, même en format image.

Merci d'avance.

[micniv]

Bonsoir, voici un code qui pourrait t'être utile pour exporter ton graphe :
Xchart2 est mon graphe et je l'exporte en graphe2.GIF (ou dans un autre format, comme tu veux) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
 Dim grpApp As Graph.Chart
 
 
    Set grpApp = Me.xChart2.Object
    grpApp.Export Application.CurrentProject.Path & "\graphe2.gif", FilterName:="GIF"
    Set grpApp = Nothing
    Me.xChart2.Action = acOLEClose  'nécessaire sinon erreur OLE :: http://support.microsoft.com/kb/824276/fr
 
    ...

Si ca peut aider

[Kloun]

Et un copier-coller, ça le fait pas ?

[kenobyalex]

Merci pour ton aide MicNiv, je vais essayer d'adapter ça dans mon code.
Je te tiens au courant.

Pour réponde au opier coller, ça me va mais s'il y a une solution automatique pour un copier coller je suis prenneur...

[kenobyalex]

J'ai réussi à exporter le graph en créant un bouton dans LE formulaire, en desous du graph.

Pourrais-je remplacer le "Me" par le nom du Formulaire à ouvrir, et cerise sur le gateau, exporter le graph dans un onglet Excel.

Merci encore, vous m'etes d'une aide très précieuse.

[micniv]

Bonsoir,
pour t'aider à avancer, voici du code, que tu sauras personnaliser, et qui fait les etapes suivantes :

1 On exporte le graphe dans le répertoire courant de l'application [rep application]
'comme dans le code donné ci-dessus
'je suis pas obligé de passer par cette étape mais c'est plus didactique

2 On ouvre un classeur Excel à partir d'un classeur modèle auparavant préparé sous le répertoire [rep application]\xls\ et nommé modeleXLS.xls (ce peut être un fichier vide mais aussi ton classeur déjà commencé dans lequel tu dois déposer ton graphe)

3 On insère ce fichier image dans la feuille Excel

4 le fichier excel incorporant l'image est automatiquement sauvegardé en ... sous sous [rep application]\

5 C'est fini

donc colle ce code sous un bouton et adapte le au nom de ton graphe et autres variables

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
 
' Ajouter la référence à Microsoft Excel ...
 
 ' Declarations Excel
    Dim objXL As Excel.Application, objSheet As Object  '
    Dim fichierModeleXL As String, nomSauvegarde As String
    Dim grpApp As Graph.Chart
 
 
    On Error GoTo Err_Click
 
    Set grpApp = Me.xChart2.Object
    grpApp.Export Application.CurrentProject.Path & "\graphe2.gif", FilterName:="GIF"
 
    Set grpApp = Nothing
 
    Me.xChart2.Action = acOLEClose  'nécessaire sinon erreur OLE :: http://support.microsoft.com/kb/824276/fr
    '                               'avec Enabled=OUI
 
  Me.Requery  'cette ligne si besoin ...
 
 
 
    ' *** EXCEL ***
Ouvre_feuille_excel:        '(si l'appli Excel est déjà lancée)
 
    On Error GoTo err_init_excel
    Set objXL = GetObject(, "Excel.application")    ' référence vers appli Excel
    On Error GoTo err_quit_excel
 
    objXL.Visible = True
    'objXL.Workbooks.Add                        ' ouvre nouveau fichier .xls
    fichierModeleXL = Application.CurrentProject.Path & "\XLS\modeleXLS.xls"
    objXL.Workbooks.Open (fichierModeleXL)      ' ouvre fichier modele existant
 
    'si Excel en icône, on le ré-ouvre
    If objXL.WindowState = xlMinimized Then objXL.WindowState = xlNormal
 
    Set objSheet = objXL.ActiveSheet
    objSheet.Activate
 
    objXL.ActiveSheet.Cells(2, 3).Value = "CECI EST MON TITRE"
 
     objXL.ActiveSheet.Pictures.Insert(Application.CurrentProject.Path & "\graphe2.gif").Select
 
    'on déplace le graphe au bon endroit
    objXL.ActiveSheet.Pictures.ShapeRange.IncrementLeft 76.5
    objXL.ActiveSheet.Pictures.ShapeRange.IncrementTop 39.75
 
    ' ********* Fin écriture dans EXCEL **************
 
    'Sauvegarde du fichier
'-----------------------
     'constitution du chemin/nom de fichier
    nomSauvegarde = Application.CurrentProject.Path & "\testXls" & "_édité_le_" & Format(Date, "dd\-mm\-yyyy") & ".xls"
    'on sauvegarde la feuille sous le nom contenu dans nomSauvegarde
   objXL.ActiveWorkbook.SaveAs Filename:=nomSauvegarde, _
                                FileFormat:=17, password:="", WriteResPassword:="", _
                                ReadOnlyRecommended:=False, CreateBackup:=False
 
 
    'Si on voulait quitter excel :
    'objXL.Application.Quit
 
    Set objSheet = Nothing
    Set objXL = Nothing
 
 
Exit_Click:
    Exit Sub
 
err_init_excel:
    On Error GoTo Err_Click
    Set objXL = CreateObject("Excel.application")    ' nouvelle instance Excel
    GoTo Ouvre_feuille_excel
 
err_quit_excel:
    MsgBox " Impossible d'ouvrir le fichier " & fichierModeleXL
    objXL.Quit
    Set objXL = Nothing
    GoTo Err_Click
 
Err_Click:
    MsgBox Err.Description, vbCritical, "Erreur n°" & Err.Number 
    Resume Exit_Click

[kenobyalex]

Bonjour, j'espère que vous avez passé un bon weekend,

Merci beaucoup pour ton code MicNiv, je vais le tester et je te tiens au courant.

[kenobyalex]

Re,

Le code fonctionne très bien, le seul hic, c'est que je ne sais toujours pas comment adapter ça dans une macro globale qui m'exportera plusieurs graph.
Je m'explique, le finalité de mon code doit donner un fichier excel, avec tous les graphs dans différents onglets.

Ici nous pouvons créer un bouton DANS UN FORMULAIRE, alors que je souhaiterai accéder au formuilaire depuis un autre FORMULAIRE ou un fichier Excel par exemple, enfin pouvoir ouvrir un Formulaire, exporter le graph en image, l'importer dans Excel, le tout avec plusieurs Graph dans plusieurs formulaires.

Je ne sais pas si je suis clair, en fait c'est le Me.xChart2... qui me pose problème; je souhaiterai, à la place du Me, mettre le nom du Formulaire.

Merci d'avance, je continue à faire des tests.

[micniv]

pas de pb.

Tu remplaces Me. qui représente le formulaire courant par Forms("FormName").
Note que ceci nécessite que Forms("FormName") soit déjà ouvert.

[kenobyalex]

Quand tu dis qu'il doit être déjà ouvert, cela veut dire de faire au préalable un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.OpenForm  "NomFormulaire"

En tout cas merci beaucoup de ton aide, j'avais presque mis le doigt dessus, enfin sur cette dernière partie!!!!, mais des erreurs apparaissaient tout le temps.

[kenobyalex]

ok nikel, ça fonctionne, je vais maintenant passer à la mise en place de cette automatisation, ça va pas être simple, mais avec tout l'aide que tu viens de m'apporter, je pense que ça va le faire.

Merci encore à toi MicNiv.