Discussion :

[bguillon]

Bonjour
dans une base sécurisée avec un mdw,
je voudrais pouvoir retester le mot de passe d'un utilisateur même
s'il ne s'agit pas de l'utilisateur loggé
comment est-ce possible ?
(j'utilise l'objet ADOX.user)
Merci

[LedZeppII]

Bonjour,

un petit exemple avec ADODB, base sur un formulaire comportant
-deux zones de texte txtUser et txtPSW pour saisir utilisateur et mot de passe
-une étiquette lblUserPwd pour afficher le résultat du test
-un bouton cmdCheckUserPwd pour effectuer le test
Le code tente d'ouvrir une connexion ADO sur la base de données en cours, avec le nom d'utilisateur et le mot de passe saisis dans le formulaire.

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub cmdCheckUserPwd_Click()
Dim oConn As ADODB.Connection
Dim strMDW As String, strUSR As String, strPWD As String
Dim strErrTxt As String
 
strMDW = DBEngine.SystemDB  'fichier MDW utilisé dans la bdd en cours
strUSR = Nz(Me.txtUser, ""): strPWD = Nz(Me.txtPSW, "")
 
Set oConn = New ADODB.Connection
oConn.ConnectionString = _
      "Provider=Microsoft.Jet.OLEDB.4.0;" & _
      "User ID=" & strUSR & ";Password=" & strPWD & ";" & _
      "Data Source=" & CurrentProject.FullName & ";" & _
      "Jet OLEDB:System database=" & strMDW
On Error Resume Next
oConn.Open
If Err.Number Then strErrTxt = Err.Description
On Error GoTo 0
If oConn.State = adStateOpen Then oConn.Close
Set oConn = Nothing
 
If Len(strErrTxt) = 0 Then
   Me.lblUserPwd.Caption = "Utilisateur et mot de passe valides"
Else
   Me.lblUserPwd.Caption = strErrTxt
End If
 
End Sub

A+