Discussion :

[jbf64]

Bonjour à tous,

Je suis fraichement inscrit sur ce forum et je vous présente mon premier pb!

1°/ Corps de message de mauvaise quailité

Je voudrais que le corps de message soit en fait un copié collé d'un document word. Plus precisement d'une zone de texte d'un .doc

J'ai essayé de le mettre en corps de message en utilisant plein de variantes, en vain.

Entre autre j'ai enregistré le doc word en format PAGE WEB dans word.
J'ai ouvert le document enregistré en PAGE WEB pour le copié.
Je l'ai collé sur le corps de message outlook (2003).

Jusque la pas de pb il s'affiche.

Dans les options je demande à ce que mon mail soit en format PAGE WEB.
Mais, quand je l'envoie, la qualité du mail est tres mediocre.
Elle est pixelisée, floue. bref, elle est moche et pas présentable du tout.

J'ai trouvé une solution palliative (mais qui ne me convient pas totalement). A savoir, j'utilise pdf creator pour "imprimer" le .doc en .jpeg et j'insère dans outlook une image. Le pb c'est que mon document a alors la qualité d'un scan! La police ne ressort pas nickel! Ce n'est pas aussi net que le .doc

2°/ Transfert du mail vers autre destinataire

D'autre part, lorsque j'envoie ce mail avec ce corps de message le destinataire le reçoit bien mais si il le transfère, le corps de message n'apparait plus

3°/ Signature carte de visite.

Et enfin, j'ai un peu le même pb que que le corps de message mais cette fois avec la signature que j'insère automatiquement à la fin de mes mails.
C'est en fait une image qui est ni plus ni moins le fichier de ma réelle carte de visite.
A l'ecran elle apparait trés nette mais le destinataire reçoit un truc trés moche.

Qq'un peut-il m'aiguiller s'il vous plait?

Merci d'avance

JB

[Dolphy35]

Salut,

pour le 1° :

Tu utilise quoi comme code, le code ci-dessous permet de récupérer le contenu d'un fichier Word et de l'ajouter dans le corps de message

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub WordInMail()
 
Dim objDoc As Word.Document
Dim objWord As Word.Application
Dim objOutlook As Outlook.Application
Dim objMail As Outlook.MailItem
 
 
    Set objWord = New Word.Application
    Set objOutlook = Outlook.Application
 
    objWord.Visible = False
    Set objDoc = objWord.Documents.Open("C:\Dolphy.docx")
 
    Set objMail = objOutlook.CreateItem(olMailItem)
 
    With objMail
        .Subject = "Ceci est un test"
        .To = "mail@domaine.com"
        .Body = objDoc.Content
        .Display
    End With
 
    objDoc.Close
    objWord.Application.Quit
 
    Set objWord = Nothing
    Set objOutlook = Nothing
    Set objDoc = Nothing
    Set objMail = Nothing
 
End Sub

2° Cela peut venir de son paramétrage d'outlook dans les options -> Options de messagerie


3° Comprend pas, j'utilise la même méthode et je n'ai pas de soucis, envoi moi un mail, tu trouveras mon adresse sur ma page perso dans la partie me contacter : http://dolphy35.developpez.com/


Dolphy

[Dolphy35]

re,

c'est clair que la qualité est moyenne, le fait est que ton fichier est considérer en tant qu'images et non en tant que corps de messages. Le code ci-dessus ne permet pas d'insérer les images contenues du Fichier Word. Il faut enregistrer ton document Word en tant que page Web et tu execute la macro WordWebInMail :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub WordWebInMail()
'---------------------------------------------------------------------------------------
' Procédure : WordWebInMail
' Auteur    : Dolphy35 - http://dolphy35.developpez.com/
' Date      : 22/04/2008
' Détail    : Créer un nouveau mail avec comme source le HTML du fichier Word
'---------------------------------------------------------------------------------------
'
'Déclaration des objets
    Dim objOutlook As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    'Instancie les Objets
    Set objOutlook = Outlook.Application
    Set objMail = objOutlook.CreateItem(olMailItem)
 
    'Objet Mail
    With objMail
        .BodyFormat = olFormatHTML      'Définition du Format du mail ici HTML
        .Subject = "Ceci est un test"   'Titre du Mail
        .To = "mail@domaine.com"        '@ Destinataire
        'Appel de la fonction pour récupérer la source HTML du fichier passé en paramètre
        'et charge le contenu dans le body du mail
        .HTMLBody = SourceHTML("C:\Essais.html")
        .Display                        'Affiche le mail
    End With
 
    'Libération des instances
    Set objOutlook = Nothing
    Set objMail = Nothing
 
End Sub

Fonction appelée par la macro et qui retourne la source de la page HTML :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Function SourceHTML(strFichier As String) As String
'---------------------------------------------------------------------------------------
' Procédure : SourceHTML
' Auteur    : Dolphy35 - http://dolphy35.developpez.com/
' Date      : 22/04/2008
' Détail    : Permet de lire un fichier HTML et de la retourner dans la Fonction
'---------------------------------------------------------------------------------------
'
'Déclaration de la variable
    Dim strLigne As String
 
    'Ouverture du Fichier
    Open strFichier For Input As 1
 
    'Boucle paracourant le fichier
    Do While Not EOF(1)
        Line Input #1, strLigne
        SourceHTML = SourceHTML & vbCr & strLigne
    Loop
 
    'Fermeture du fichier
    Close #1
 
End Function

Ps tu n'es pas obligé de mettre tous les destinataire à la suite dans le code, soit tu efface la ligne To et tu mets tes destinataires à la mano ou bien tu créer une liste de diffusion.

Dolphy