Discussion :

[rom05]

Bonjour à tous,
j'ai un classeur excel avec plusieurs feuilles qui sont toutes quasiment plaines... Chaque nouvelle feuille est en fait la suite de la précédente... Une feuille contient à chaque fois 6 colonnes et x lignes. J'aimerais donc obtenir un seul fichier : un fichier texte avec séparateur : tabulation... afin d'importer sous un logiciel de stat.
J'ai commencé à écrire un code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub Macro1()
 
    Dim CL1 As Workbook
    Dim FL2 As Worksheet
 
    ChDir "D:\romain\travail\extraction_sophy"
    Set CL1 = Workbooks.Open("D:\romain\travail\extraction_sophy\tabflo_sophy_1to715.xls")
    For Each FL2 In CL1.Worksheets
        Cells(1, 1).Select
        Selection.End(xlDown).Select
        Lf = ActiveCell.Row
        Cells(1, 1).Select
        Selection.End(xlToRight).Select
        Cf = ActiveCell.Column
        Open "essai.txt" For Output As #1 'Crée un fichier par ajout
        For i = 1 To Lf
            Print #1, Range(Cells(i, 1), Cells(i, Cf)).Select
        Next i
        Close #1
    Next
End Sub

le script marche mais ne me renvoit pas ce que je veux dans le fichier texte... il marque :
vrai
vrai
vrai
...

Et mon second problème c'est que j'ai peur que quand je passe à une autre feuille, mes données du fichier texte de la feuille précédente soient effacé ou écrasé par les données de la nouvelle feuille...

Un petit peu d'aide ne serait pas de refus...

[neupont]

Moi je le verrais mieux comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
    For Each FL2 In CL1.Worksheets
        Cells(1, 1).Select
        Selection.End(xlDown).Select
        Lf = ActiveCell.Row
        Cells(1, 1).Select
        Selection.End(xlToRight).Select
        Cf = ActiveCell.Column
        Open "essai.txt" For Output As #1 'Crée un fichier par ajout
        For i = 1 To Lf
            varChaine = cells(i,1)
            for j = 2 to Cf
                 varChaine = varChaine & chr(9) & cells(i,j)    'note : chr(9) équivaut à une tabulation            
            next j
            Print #1, varChaine
        Next i
        Close #1
    Next
End Sub

[neupont]

Et tu as raison d'avoir peur pour l'écrasement

Mets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Open "essai.txt" For Output As #1 'Crée un fichier par ajout

avant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each FL2 In CL1.Worksheets

et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Close #1

après

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Next

[rom05]

bien vu,.... t'as façon de faire marche... enfin jusqu'à la fin de la feuille une mais après erreur 52 (nom ou numéro de fichier incorrect...
je continue à chercher mais comprend pas trop ce qu'il me reproche!!!

[neupont]

Tu devrais avoir ça comme code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
Sub Macro1()
 
Dim CL1 As Workbook
Dim FL2 As Worksheet
 
ChDrive "D"
ChDir "D:\romain\travail\extraction_sophy"
Set CL1 = Workbooks.Open("D:\romain\travail\extraction_sophy\tabflo_sophy_1to715.xls")
 
Open "essai.txt" For Output As #1 'Crée un fichier par ajout
 
For Each FL2 In CL1.Worksheets
    Cells(1, 1).Select
    Selection.End(xlDown).Select
    Lf = ActiveCell.Row
    Cells(1, 1).Select
    Selection.End(xlToRight).Select
    Cf = ActiveCell.Column
    For i = 1 To Lf
        varChaine = Cells(i, 1)
        For j = 2 To Cf
            varChaine = varChaine & Chr(9) & Cells(i, j)   'note : chr(9) équivaut à une tabulation
        Next j
        Print #1, varChaine
    Next i
    Cells(1, 1).Select
Next
 
Close #1
 
End Sub

[rom05]

ouai c bien le code que j'ai...
en fait, c'est comme si la boucle for each ne marchait pas :
si j'ai 2 feuilles, il se place sur celle active et la copie 2 fois dans le fichier txt mais ne copie pas la feuille 2.
Etrange...
Merci de ton aide en tout cas

[neupont]

ah oui... ce doit être normal dans la mesure où en fait on ne lui dit nulle part de changer de feuille active, et comme on ne place pas non plus les Cells(...) dans FL2...

Tu pourrais essayer avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
For Each FL2 In CL1.Worksheets
   FL2.Activate
   ...

[rom05]

ALors moi je dis respect et bravo... je pensais que la feuille s'activait toute seule après chaque next...
merci çà marche!!!!!

[kiki29]

Salut

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Open "essai.txt" For Append As #1

[AlainTech]

Quel dommage de créer un objet FL2 et de ne pas s'en servir:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
For Each FL2 In CL1.Worksheets
    Lf = FL2.Cells(1, 1).End(xlDown).Row
    Cf = FL2.Cells(1, 1).End(xlToRight).Column
    For i = 1 To Lf
        varChaine = FL2.Cells(i, 1)
        For j = 2 To Cf
            varChaine = varChaine & Chr(9) & FL2.Cells(i, j)   'note : chr(9) équivaut à une tabulation
        Next j
        Print #1, varChaine
    Next i
    FL2.Cells(1, 1).Select
Next