Discussion :

[ClaudeLELOUP]

Bonne fête du travail à tous.
J’utilise Access2000.
Dans une table, je dois modifier le type de donnée d’un champ qui intervient dans des relations très complexes.
Access m’invite à d’abord supprimer ces relations.
Je devrai donc supprimer, modifier, rétablir les relations, tester et, sans doute recommencer le ce cycle jusqu’à mise au point finale.
Je voudrais alléger ce travail fastidieux. Quelqu’un aurait-il une astuce qui me permettrait de récupérer la relation originale ?
En quelque sorte l’équivalent ‘code’ de l’affichage graphique de la relation (comme le sql d’une requête)
Merci déjà.

[Jeannot45]

Bonjour et bonne fête aussi.

Lorsque tu es dans le QBE (c'est à dire l'interface graphique de la création de ta requête), tu trouveras juste sur le bord droit du bouton affichage, une liste déroulante qui te permet de passer en affichage SQL.

Là ce trouve la syntaxe de ta requete à copier et coller dans une doc word. Tu pourras la recoller comme tu veux plus tard

A+

[ClaudeLELOUP]

Merci d'essayer de m'aider.
Ce que tu me proposes, c'est l'exemple que je donnais pour illustrer ma question !
Ce que je souhaite, c'est récupérer le code de la relation entre plusieurs tables (si cela existe) qui correspond à ce que je vois lorsque je me trouve dans l'écran "relations" i.e. outils/relation ...
Bonne journée.

[FreeAccess]

Bonjour....

..récupérer le code de la relation entre plusieurs tables....qui correspond à......écran "relations" i.e. outils/relation ...

Tu peux déjà récupérer ces différentes relations sous forme de documentation (pas de code à proprement parlé....)

Outils > Analyse > Documentation.....
Onglet [Base de données en cours] > tu coche Relations > OK

Tu obtiens un état comportant toutes les relations existantes entres tes tables.....

[ClaudeLELOUP]

Merci.
Un antisèche, c'est déjà ça.
Je ne connaissais pas (J'aurais pris un printscreen).

[marot_r]

Tu peux trés bien sauvegarder et restaurer des relations par programme.

Regarde l'objet Relation de la collection Relations de l'objet DAO.Database.

Tu parcours la collection de relations, tu enregistres les propriété de la relation dans une table puis à partir de la table tu recrées ta relation.

A+

[ClaudeLELOUP]

Ah merci pour cette bonne nouvelle !
Bonne soirée

[ClaudeLELOUP]

Bonjour à tous,

marot_r
Tu peux trés bien sauvegarder et restaurer des relations par programme.
Regarde l'objet Relation de la collection Relations de l'objet DAO.Database.
Tu parcours la collection de relations, tu enregistres les propriété de la relation dans une table puis à partir de la table tu recrées ta relation."

J'ai essayé, mais je n'y arrive pas!

Quelqu'un aurait-il un bout de code
1° pour mémoriser les relations actuelles
2° les supprimer
3° les restaurer

Merci déjà

[ClaudeLELOUP]

Vingt fois sur le métier remettez votre ouvrage, polissez-le sans cesse, et le repolissez, ...
La piste de marot_r est la bonne !

Voici une solution :

J’ai une table : « Relations » qui contient les champs suivants :
Nom, Table1, Table2, ChampTable1, ChampTable2 (texte) et Attributs (entier long)

1ère étape Sauver la relation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public Sub SauverRelations()
Dim rel As DAO.relation
DoCmd.SetWarnings False
'purge de la table
DoCmd.RunSQL ("DELETE Relations.Nom FROM Relations;")
'alimentation de la table
For Each rel In CurrentDb.Relations
   DoCmd.RunSQL ("INSERT INTO Relations ( Nom, Table1, Table2, ChampTable1, ChampTable2, Attributs )  SELECT """ & rel.Name & """ AS Expr1, """ & rel.Table & """ AS Expr2, """ & rel.ForeignTable & """ AS Expr3, """ & rel.Fields(0).Name & """ AS Expr4, """ & rel.Fields(0).ForeignName & """ AS Expr5, " & rel.Attributes & " AS Expr6;")
Next rel
DoCmd.SetWarnings True
End Sub

2ème étape Supprimer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Function SupprimerRelations()
Dim rel As relation
For Each rel In CurrentDb.Relations
   CurrentDb.Relations.Delete rel.Name
Next rel
End Function

3ème étape Restaurer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Public Sub RestaurerRelations()
Dim rec As DAO.Recordset
Dim rel As DAO.relation
Dim chp As Field
Set rec = CurrentDb.OpenRecordset("Relations")
Do Until rec.EOF
  Set rel = CurrentDb.CreateRelation(rec("nom"), rec("table1"), rec("table2"))
  rel.Attributes = rec("Attributs")
  Set chp = rel.CreateField(rec("ChampTable1"))
  chp.ForeignName = rec("ChampTable2")
  rel.Fields.Append chp
  CurrentDb.Relations.Append rel
  rec.MoveNext
Loop
End Sub

Elémentaire, n'est-il pas ?