Discussion :

[johanaquatique]

Bonjour le forum.
J'ai un petit projet de gestion à réaliser en Access.

Le projet sera de gèrer une table contenant 20 colonnes et le formulaire devrait idéalement cotenir un système de tri de données par chacune des 20 colonne présente dans la table (une des colonnes est à réserver pour le stockage photo qui serait dans un dossier image) et lorsque on affiche la fiche article relative à la recherche, on sais atrouver un bouton ajouter photo et lorsque la photo et mise, on peu aussi cliquer sur la photo pour la voir en grand et la coller dans un présentation diverse...

Y aurait il quelqu'un qui serait capable de m'aider à concrétiser mon projet ?
Merci à tous

Johan

[FreeAccess]

Bonjour..

Pour ton projet, tu pourrais déjà commencer par lire les différents cours disponibles sur ce Forum.:
http://access.developpez.com/cours/?page=courstuto

En autre, tu y trouvera.....
http://cafeine.developpez.com/access...echerchemulti/ (Recherche multicritères...)
http://cafeine.developpez.com/access/tutoriel/photos/ (Une gestion d'images...)

....et ceci n'est qu'un petit échantillon...

N'hésite pas non plus à utiliser le menu [Rechercher] situé en haut de chaque page, de façon a effectuer une recherche dans les anciens posts parlant du même sujet...

...bonne lecture....

[johanaquatique]

Salut, merci pour l'info, j'ai maintenant construit quelque chose d'intéressant sur base "Cafeïne".
Mais maintenant le module multicritère n'est qu'un recherche approfoncdie... et en page d'accueil de ma BDD je voudrais un champ de recherche pour taper une ref et un bouton jumelle qui recherche dans ma table principale, je ne trouve pas d'exemple qui peux m'aider ?
je voudrais juste une zone texte et un bouton recherche, et le résultat m'affiche dans un formulaire...
Merci et bonne journée.
Johan

[johanaquatique]

personne ?

[johanaquatique]

Néant jamais eu de réponse, je suis dans un stade plus avancé maintenant. suite à ma demande et en espèrant que cela serve à d'autre qui cherche !

Voici comment j'ai fait

J'ai créé un champs texte
j'ai créé un bouton avec proccedure évenementiel sur clic
et j'ai mis ce code sur le bouton

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Commande49_Click()
 
On Error GoTo Err_Commande49_Click
 
    Dim stDocName As String
    Dim stLinkCriteria As String
 
    stDocName = "frmAutoMedias"
 
    stLinkCriteria = "[Désignation] Like '" & Me![txtRechTexte] & "*'"
    DoCmd.OpenForm stDocName, , , stLinkCriteria
 
Exit_Commande49_Click:
    Exit Sub
 
Err_Commande49_Click:
    MsgBox Err.Description
    Resume Exit_Commande49_Click
 
End Sub

[Remus91]

un bouton ajouter photo et lorsque la photo et mise, on peu aussi cliquer sur la photo pour la voir en grand

Tu peut utiliser la fonction explorer que tu peut trouver dans le FAQ (dsl je ne dispose pas du lien) elle te permettra de parcourir le contenue de ton Pc pour trouver l'image que tu souhaite envoyer dans ton repertoire image.

Voila le code que j'ai repris dans un de mes programmes.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
'Déclaration de l'API
Private Declare Sub PathStripPath Lib "shlwapi.dll" Alias "PathStripPathA" (ByVal pszPath As String)
Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias _
                   "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
 
 'Structure du fichier
Private Type OPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    lpstrFilter As String
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String
    flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type
 
 'Constantes
Private Const OFN_READONLY = &H1
Private Const OFN_OVERWRITEPROMPT = &H2
Private Const OFN_HIDEREADONLY = &H4
Private Const OFN_NOCHANGEDIR = &H8
Private Const OFN_SHOWHELP = &H10
Private Const OFN_ENABLEHOOK = &H20
Private Const OFN_ENABLETEMPLATE = &H40
Private Const OFN_ENABLETEMPLATEHANDLE = &H80
Private Const OFN_NOVALIDATE = &H100
Private Const OFN_ALLOWMULTISELECT = &H200
Private Const OFN_EXTENSIONDIFFERENT = &H400
Private Const OFN_PATHMUSTEXIST = &H800
Private Const OFN_FILEMUSTEXIST = &H1000
Private Const OFN_CREATEPROMPT = &H2000
Private Const OFN_SHAREAWARE = &H4000
Private Const OFN_NOREADONLYRETURN = &H8000
Private Const OFN_NOTESTFILECREATE = &H10000
 
Private Const OFN_SHAREFALLTHROUGH = 2
Private Const OFN_SHARENOWARN = 1
Private Const OFN_SHAREWARN = 0
 
 
Public Function OuvrirUnFichier(handle As Long, _
                                Titre As String, _
                                TypeRetour As Byte, _
                                Optional TitreFiltre As String, _
                                Optional TypeFichier As String, _
                                Optional RepParDefaut As String) As String
 'OuvrirUnFichier est la fonction a utiliser dans votre formulaire pour ouvrir _
 'la boîte de dialogue de sélection d'un fichier.
 'Explication des paramètres
    'Handle = le handle de la fenêtre (Me.Hwnd)
    'Titre = Titre de la boîte de dialogue
    'TypeRetour (Définit la valeur, de type String, renvoyée par la fonction)
        '1 = Chemin complet + Nom du fichier
        '2 = Nom fichier seulement
    'TitreFiltre = Titre du filtre
        'Exemple: Fichier Access
        'N'utilisez pas cet argument si vous ne voulez spécifier aucun filtre
    'TypeFichier = Extention du fichier (Sans le .)
        'Exemple: MDB
        'N'utilisez pas cet argument si vous ne voulez spécifier aucun filtre
    'RepParDefaut = Répertoire d'ouverture par defaut
        'Exemple: C:\windows\system32
        'Si vous laissé l'argument vide, par defaut il se place dans le répertoire de votre application
 
Dim StructFile As OPENFILENAME
Dim sFiltre As String
 
 'Construction du filtre en fonction des arguments spécifiés
If Len(TitreFiltre) > 0 And Len(TypeFichier) > 0 Then
  sFiltre = TitreFiltre & " (" & TypeFichier & ")" & Chr$(0) & "*." & TypeFichier & Chr$(0)
End If
sFiltre = sFiltre & "Tous (*.*)" & Chr$(0) & "*.*" & Chr$(0)
 
 
 'Configuration de la boîte de dialogue
  With StructFile
    .lStructSize = Len(StructFile) 'Initialisation de la grosseur de la structure
    .hwndOwner = handle 'Identification du handle de la fenêtre
    .lpstrFilter = sFiltre 'Application du filtre
    .lpstrFile = String$(254, vbNullChar) 'Initialisation du fichier '0' x 254
    .nMaxFile = 254 'Taille maximale du fichier
    .lpstrFileTitle = String$(254, vbNullChar) 'Initialisation du nom du fichier '0' x 254
    .nMaxFileTitle = 254  'Taille maximale du nom du fichier
    .lpstrTitle = Titre 'Titre de la boîte de dialogue
    .flags = OFN_HIDEREADONLY  'Option de la boite de dialogue
    If ((IsNull(RepParDefaut)) Or (RepParDefaut = "")) Then
        RepParDefaut = CurrentDb.Name
        PathStripPath (RepParDefaut)
        .lpstrInitialDir = Left(CurrentDb.Name, Len(CurrentDb.Name) - Len(Mid$(RepParDefaut, 1, _
InStr(1, RepParDefaut, vbNullChar) - 1)))
        Else: .lpstrInitialDir = RepParDefaut
    End If
  End With
 
If (GetOpenFileName(StructFile)) Then 'Si un fichier est sélectionné
    Select Case TypeRetour
      Case 1: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFile, InStr(1, StructFile.lpstrFile, vbNullChar) - 1))
      Case 2: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFileTitle, InStr(1, StructFile.lpstrFileTitle, vbNullChar) - 1))
    End Select
  End If
 
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

txb_info_fichier.Value = explorer.OuvrirUnFichier(Me.hwnd, "Sélectioner Fichier", 1, , , "c:")

Ici dans mon txb_info_fichier je stocke le nom du fichier que j'ai sélectioné, pour ensuite l'exploiter de la maniere suivant.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
If Me.txb_info_fichier.Value <> "" Then
 
    intI = InStrRev(Me.txb_info_fichier.Value, "\", , vbTextCompare)
    Filename = IIf(intI = 0, strPath, Mid(Me.txb_info_fichier.Value, intI + 1))
    FileCopy Me.txb_info_fichier.Value, CurrentProject.Path & "\image\img_" & Me.nom_image.Value & "\" + Filename
 
End If

je reprendre la valeur de mon txb_info_fichier que j'ai allimenté plus haut.
Je récupére les informations stocké apres le dernier \ donc le nom de l'image.
Ensuite je le copie dans mon repertoire image.

Ensuite moi j'affiche le contenue de mon repertoire image ce qui me laisse la possibilité de selectionner l'image soouhaiter et que sur un simple double clic dessus je peut ouvrire l'image (code suivant).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim chemin As String
chemin = CurrentProject.Path & ""\image\img_" & Me.nom_image.Value & "\"
'Ouvre fichier
ShellExecute Me.hwnd, "open", Me.lst_img.Value, "", chemin, 1

chemin elle là ou est stoké mes images.
lst_img ma listbox où qui affiche toute mes images du rep image.
ShellExecute ouvre mon fichier sur un simple double clic dans le tableau.


Jéspère que tout cela taurra aider.
Bon courage et bonne continuation

cordialement,
Rémy