Discussion :

[marchand_de_sable]

Bonjour à tous.

Explication : j'ai une librairie VB (très) peu documentée, qui utilise des collections.
Dans l'une d'elles, il est possible de récupérer les items grâce à une clé, mais je ne comprends pas vraiment comment les clés ont été choisies lors de l'alimentation de la Collection.

Du coup, j'aimerais lister les clés des items d'une Collection. (Comment) est-ce possible ?
J'ai cru entendre parler d'une méthode getKey() pour les items, mais les objets de cette Collection n'ont manifestement pas cette méthode.
J'ai aussi tenté un :
la_collection.getKey(la_collection.item(1));
et
la_collection.getKey(1);
mais évidemment, ça ne marche pas...

Merci d'avance pour l'aide.

PS : ma question n'est pas spécifique à VBA Access, mais je ne savais pas quel état le forum le plus adéquat...

[Kloun]

un for each ..., ça peut pas le faire ?

[marchand_de_sable]

un for each ..., ça peut pas le faire ?

Sauf que je mets quoi dans le For Each ??
Ca me permet de lister mes items, mais je fais comment pour connaître les clés correspondantes ?

L'idée, c'est d'essayer de comprendre comment est remplie cette collection (ou plutôt, comment sont choisies les clés lorsqu'elle a été alimentée). Tout ça, afin de pouvoir utiliser les clés afin d'accéder directement à mes items par la suite.
Parce que sinon, je serais effectivement obliger de faire des For Each à chaque fois que j'en cherche un en particulier.

Donc je cherche plutôt une fonction ou méthode, (si elle existe...) qui prendrait un index "i" en paramètre, et me retournerait la clé correspondante pour mon item.

[Kloun]

Un p'tit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim iVar_Element As Variant
    For Each iVar_Element In la_collection.ItemsSelected
    Next iVar_Element

Et en debug, tu jette un oeil sur les propriétés de iVar_Element et leurs valeurs.

[marchand_de_sable]

Je n'y avais même pas pensé

Problème : j'utilise Visual Basic Editor avec les outils Office pour utiliser une librairie VB fournie avec un logiciel.
Je ne sais pas si ça vient de la librairie, mais quand je mets un espion sur ma Collection et mon item (tous deux issus de cette librairie), dans la colonne "Valeur" de l'espion, j'ai "Aucune variable" pour mon item en particulier, et pour tous les items de la Collection en général, alors que je peux bien faire appel aux méthodes de l'item...

Est-ce normal ? Y'a-t-il une autre méthode pour voir les propriétés des objets ?

PS : c'est pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each iVar in la_Collection

plutôt que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each iVar in la_Collection.ItemsSelected

?

[Kloun]

Oui, c'est plutôt :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each iVar in la_Collection

Pour le reste, difficile de dire sans la librairie et le logiciel
T'as rien trouvé sur le net ?

[Arkham46]

Bjr,

Les collections en VBA ne proposent pas de méthode pour retrouver la clé d'un item.
De plus si on ajoute un item sans préciser la clé, le VBA ne génère pas de clé tout seul.
L'item ne sera alors accessible que par son indice.

En regardant un peu comment sont construtites les collections, on peut trouver l'emplacement du premier item, qui contient l'emplacement de l'item suivant, qui lui même contient l'emplacement de l'item suivant, etc jusqu'à la fin de la collection.
En fait c'est une liste liée.
Mieux encore on trouve un pointeur vers la clé pour chaque item.
S'il n'y a pas de clé, le pointeur est nul.

Bref voilà le code :

Code à mettre dans un module :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
 
Option Explicit
 
' API pour déplacement de zone mémoire
Private Declare Sub RtlMoveMemory Lib "kernel32" (pDst As Any, pSrc As Any, ByVal ByteLen As Long)
 
' --------------------------------------------------------------------
' Renvoit la clé d'un item d'indice pItem d'une collection pColl
' --------------------------------------------------------------------
Function CollGetKey(pColl As Collection, pItem As Long) As String
Dim lBuffer(1 To 8) As Long ' Buffer pour information sur la collection
Dim lItem(1 To 7) As Long ' Buffer pour information sur l'Item
Dim lKey() As Byte ' Buffer pour la clé de l'item
Dim lCpt As Long ' Compteur d'item
Dim lPtr As Long ' Pointeur
Dim lSize As Long ' Taille de la clé
On Error GoTo Gestion_Erreurs
' Test objet initialisé
If ObjPtr(pColl) <> 0 Then
    ' Lecture informations de la collection
    RtlMoveMemory lBuffer(1), ByVal ObjPtr(pColl), 8 * 4
    ' Lecture informations du premier item
    If lBuffer(7) <> 0 Then
        RtlMoveMemory lItem(1), ByVal lBuffer(7), 7 * 4
        ' Boucle pour lire les items
        Do
            lCpt = lCpt + 1
            ' Si l'indice de l'item correspond
            If lCpt = pItem Then
                ' Pointeur vers clé
                lPtr = lItem(5)
                ' Si une clé existe
                If lPtr <> 0 Then
                    ' Taille de la clé
                    RtlMoveMemory lSize, ByVal lPtr - 4, 4
                    ' Buffer de réception de la clé
                    ReDim lKey(1 To lSize)
                    ' Récupère la clé
                    RtlMoveMemory lKey(1), ByVal lPtr, lSize
                    ' Conversion unicode
                    CollGetKey = StrConv(lKey(), vbUnicode)
                    CollGetKey = StrConv(CollGetKey, vbFromUnicode)
                    Exit Do
                Else
                    ' Pas de clé
                    CollGetKey = ""
                    Exit Do
                End If
            Else ' Sinon, on passe à l'item suivant
                ' Pointeur vers item suivant
                lPtr = lItem(7)
                If lPtr <> 0 Then
                    ' Lecture informations de l'item
                    RtlMoveMemory lItem(1), ByVal lPtr, 7 * 4
                Else
                    ' On a parcouru tous les items => pas normal
                    CollGetKey = ""
                    Exit Do
                End If
            End If
        Loop
    Else
        CollGetKey = ""
    End If
Else
    CollGetKey = ""
End If
' Gestion des erreurs
On Error GoTo 0
Exit Function
Gestion_Erreurs:
    CollGetKey = ""
End Function

Remarque : j'ai testé sur quelques collections, c'est une usine à gaz mais ça a l'air de marcher...

Pour l'utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Function TestCollKey()
Dim lColl As New Collection
lColl.Add "Item1", "Clé1"
lColl.Add "Item2" ' Pas de clé
Debug.Print "1", CollGetKey(lColl, 1)
Debug.Print "2", CollGetKey(lColl, 2)
End Function

CollGetKey(lColl, 1) renvoit "Clé1"
CollGetKey(lColl, 1) renvoit une chaine vide

A tester sur ta collection pour voir s'il y a des clés dans la collection.
Avec un peu de chance ça trouvera des clés, sinon il ne reste plus qu'à utiliser l'indice.

[marchand_de_sable]

Ouch, j'aurais du mal à trouver ça tout seul !!!

Merci

Je teste ça.

[=JBO=]

Bonjour et BRAVO à Arkham46 !

Cette fonction CollGetKey() est une première il me semble (pas vu d'équivalent sur l'internet, ou alors j'ai peut être mal regardé).

Merci Arkham46 pour ce très bon travail, utile notamment pour déboguer des bibliothèques tierces !


En passant, juste une petite chose (j'ai honte mais c'est en toute simplicité) ...
La terminologie consacrée est: << liste chaînée >>.

En regardant un peu comment sont construtites les collections, on peut trouver l'emplacement du premier item, qui contient l'emplacement de l'item suivant, qui lui même contient l'emplacement de l'item suivant, etc jusqu'à la fin de la collection.
En fait c'est une liste liée.

[Arkham46]

Effectivement JBO, j'ai cherché il y a déjà quelque temps (y compris en anglais), et je n'ai pas trouvé ça sur le net.
Donc c'est empirique, j'ai créé une collection et ajouté des éléments un à un en regardant ce qui changeait en mémoire...

Pour le terme "liste chainée" ça me semble mieux effectivement.

Au passage j'ai ajouté deux tests dans le code pour éviter un plantage si collection non initialisée ou vide.

[marchand_de_sable]

Bonjour.

Malheureusement, ça ne fonctionne pas avec mes Collections...
Plus précisément, ces Collections sortent d'un SDK compatible avec VBA, mais elle est en fait censée tourner sur un "moteur" VB spécifique (fourni avec le SDK). L'implémentation de tout ça est assez obscure...
Et bien que des classes soient spécifiées (et vaguement documentées), lorsqu'on écrit un code, toutes les variables doivent être des "Object", sinon ça plante (erreur : incompatibilité de type). J'imagine que ça explique l'échec de CollGetKey() avec ces objets...

C'est rageant, mais un grand merci quand même

[ClaudeLELOUP]

Bonjour,

Avec ce que propose Arkham46, on le peut :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function TestCollKey()
  Dim lColl As New Collection
  Dim oItem As Variant
  Dim i As Integer
  'Peupler la collection
  lColl.Add "Belgique", "Bruxelles"
  lColl.Add "France", "Paris"
  lColl.Add "Italie", "Rome"
  'Lister son contenu
  i = 1
  For Each oItem In lColl
    Debug.Print lColl.Item(i), CollGetKey(lColl, Eval(i))
    i = i + 1
  Next oItem
 
End Function