Discussion :

[drthodt]

Bonjour à tous,
Je récupère en fait le nom d’un dossier dans une variable Object à travers une boîte de sélection de la manière suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 Dim Shell As Object, GetDossier As Object, Dossier As Object
 
'Initialisation de l'explorateur
Set Shell = CreateObject("Shell.Application")
'Boîte de dialogue pour la sélection du dossier
Set GetDossier = Shell.BrowseForFolder(&H0&, "Choisir un répertoire", &H1&)
 
On Error Resume Next
'Récupération du chemin
Set Dossier = GetDossier.Items.Item

J’aimerais en fait tronquer le nom du dossier pour ne garder que ce qui est à gauche du séparateur ‘_’ avec un code de type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 Pos = InStr(1, Dossier, "_", 1)
        nomDossierSansExtension = Left(Dossier, Pos - 1)

Cela ne semble possible que sur des chaînes String (cela ne fonctionne pas en tout cas avec ma variable Object), faudrait-il que je stocke le contenu de ma variable dans une variable de type String ? Si oui comment cela doit-il se faire ?

[Godzestla]

Salutn

tu definis une variable string en plus, et tu lui affectes le contenu de ta variable objet.

ca marche j'ai testé.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Sub explorer()
 
 Dim Shell As Object, GetDossier As Object, Dossier As Object
 Dim chemin As String
 
 
'Initialisation de l'explorateur
Set Shell = CreateObject("Shell.Application")
'Boîte de dialogue pour la sélection du dossier
Set GetDossier = Shell.BrowseForFolder(&H0&, "Choisir un répertoire", &H1&)
 
On Error Resume Next
'Récupération du chemin
Set Dossier = GetDossier.Items.Item
chemin = Dossier
Debug.Print chemin
 
End Sub

Génial ton code, je ne connaissais pas et j'en ai justement besoin.

[ucfoutu]

Bonjour,

Juste deux choses :

1) je ne vois nul besoin de passer par une variable tremplin chemin...

2) qu'est ce "On Error Resume Next" ? C'est pour quoi ? pour éviter une erreur si l'utilisateur a annulé ?

Pas bon (pas beau) !

Voilà ce que devrait être ton code, donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Option Explicit
Private Sub Command1_Click()
   Dim Shell As Object, GetDossier As Object, Dossier As Object
   Set Shell = CreateObject("Shell.Application")
   Set GetDossier = Shell.BrowseForFolder(&H0&, "Choisir un répertoire", &H1&)
   If GetDossier Is Nothing Then ' l'utilisateur n'a pas sélectionné un dossier
     Exit Sub
   End If
   Set Dossier = GetDossier.Items.Item
   Dim nomDossierSansExtension As String, pos As Integer
   pos = InStr(Dossier, "_")
   If pos > 0 Then
     nomDossierSansExtension = Left(Dossier, pos - 1)
   Else
     nomDossierSansExtension = Dossier
   End If
   MsgBox nomDossierSansExtension
End Sub

[drthodt]

Bonjour,

Juste deux choses :

1) je ne vois nul besoin de passer par une variable tremplin chemin...

2) qu'est ce "On Error Resume Next" ? C'est pour quoi ? pour éviter une erreur si l'utilisateur a annulé ?

Ton code fonctionne parfaitement, merci à toi.
Le On error resume next était bien en fait une saleté résiduelle qui n'avait rien à faire tel quel dans le code.
Bon après-midi,
M