Discussion :

[preverse]

Bonjour,

J'ai un problème qui doit être des plus classique, mais je ne trouve pas la réponse dans les forums.

Je voudrais imprimer sous VBA (Excel) une Form, au mieux en pouvant parametrer la mise en forme et au minimum en pouvant passer l'impression en paysage.

Je ne sais pas si Printer est la solution, si oui, comment le faire reconnaitre par VBA ?

Merci.

P.R

[leroissejp]

Bonjour,
Pour imprimer un UserForm, c'est simple, mais pour le mode paysage, je n'ais pas encore trouvé (vais chercher).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Private Sub CommandButton1_Click()
Application.ScreenUpdating = False
    UserForm1.PrintForm
  Application.ScreenUpdating = True
End Sub

jpleroisse

[preverse]

C'est gentil de répondre, mais ça ne fait pas avancer mon problème d'un pixel

P.R

[SilkyRoad]

bonjour

j'espere que cet exemple pourra t'aider

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Explicit
 
Private Declare Sub keybd_event Lib "user32" ( _
ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, _
ByVal dwExtraInfo As Long)
 
Private Sub CommandButton1_Click()
Dim Wrd As Object, WrdDoc As Object
 
'Copie d'écran de la forme active
keybd_event vbKeySnapshot, 1, 0&, 0&
DoEvents
 
Set Wrd = CreateObject("Word.Application") 'creation session Word
Wrd.Visible = False 'pour que Word reste masqué pendant l'opération
 
On Error Resume Next
Set WrdDoc = Wrd.Documents.Add
WrdDoc.PageSetup.Orientation = wdOrientLandscape
 
Wrd.Selection.PasteSpecial 'colle dans le document Word
 
With WrdDoc.Shapes(1) 'redimensionnement et positionnement de l'objet imprimé
.Left = 50 'bord gauche
.Top = 50 'bord haut
.Width = 400
End With
 
WrdDoc.PrintOut 'impression
 
WrdDoc.Close False 'ferme le document Word sans sauvegarde
WrdDoc.Quit 'ferme l'application Word
End Sub

cordialement
michel

[preverse]

C'est tordu, mais ça marche !

J'ai un peu simplifié le code, puisque je suis déjà dans Excel, autant faire l'impression sur une feuille Excel plutôt que d'ouvrir un objet Word.

Voila ce que cela donne et merci beaucoup.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
' Impression de la form active
Public Function imprimeFormActive()
'   On Error GoTo gestErreur
 
    ' Init
    Dim feuilleImp As Object
 
    ' Suppression de la mise a jour de l'affichage et des messages d'alerte
    application.ScreenUpdating = False
    application.DisplayAlerts = False
 
    ' Copie d'ecran de la forme active
    keybd_event vbKeySnapshot, 1, 0&, 0&
    DoEvents
 
    ' Creation d'une nouvelle feuille
    Set feuilleImp = ThisWorkbook.Sheets.Add
 
    ' Mise en page de la feuille
    With feuilleImp.PageSetup
        .LeftMargin = application.InchesToPoints(0.393700787401575)
        .RightMargin = application.InchesToPoints(0.393700787401575)
        .TopMargin = application.InchesToPoints(0.196850393700787)
        .BottomMargin = application.InchesToPoints(0.196850393700787)
        .HeaderMargin = application.InchesToPoints(0.511811023622047)
        .FooterMargin = application.InchesToPoints(0.511811023622047)
        .CenterHorizontally = True
        .CenterVertically = True
        .Orientation = xlLandscape
    End With
 
    ' Collage dans la feuille Excel
    feuilleImp.PasteSpecial
 
    ' Impression
    feuilleImp.PrintOut
 
    ' Suppression de la feuille
    feuilleImp.Delete
 
    ' Reactivation de la mise a jour de l'affichage et des messages d'alerte
    application.ScreenUpdating = True
    application.DisplayAlerts = True
 
Exit Function
gestErreur:
gestion_Erreur Err, "imprimeFormActive"
End Function

PR