Discussion :

[Dailyplanet]

Bonjour,

J'ai environ 300 documents Word (créés sous 2003+2007) sans pied de page.
Existe-il un moyen d'ajouter un pied de page (par exemple le nom du fichier) sur tous mes documents déjà créés.

Apparemment après avoir parcouru le forum, la seule solution serait de créer un modèle qui s'appliquerai pour les futurs documents.

Dailyplanet

[Heureux-oli]

Salut,

La solution du modèle ne fonctionnera que pour les nouveaux documents, mais je pense que tu l'as déjà compris.

Pour les documents existant, il faut ouvrir tous les documents, ajouter le pied de page contenant le texte que tu souhaites.
Avec 300 documents, on peut envisager une macro.

Le tout est de voir si tu veux investir dans une macro et de savoir ce que ton pied de page va contenir.

[Dailyplanet]

Salut et merci pour ta réponse très rapide.

C'est bien ce que je pensais.

La macro m'intéresse mais je n'ai pratiquement aucune compétence dans ce domaine.

Si tu en a une toute prête sous la main...je suis preneur.
Sinon allons-y pour le travail à la chaîne

Dailyplanet

[Heureux-oli]

Je n'en ai pas de toute prête en magasin, mais ce n'est pas trop compliqué à faire.

Le premier principe est de parcourir les éléments d'un répertoire, mais uniquement les documents.

http://warin.developpez.com/access/fichiers/

Sur le contenu de ton pied de page, si tu pouvais en dire un peu plus ce serait pas mal.

[Dailyplanet]

OK, je me lance
Je pense que j'en aurai pour quelques jours...je ferai ça au boulot !
Merci

Dailyplanet

[Heureux-oli]

Pour te faciliter un peu la tâche :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Sub PArcourirRep()
Dim Fso As New FileSystemObject
Dim Rep As String
Dim oFl As File
Dim dlg As FileDialog
Dim oFld As Folder
 
 
Set dlg = Application.FileDialog(msoFileDialogFolderPicker)
 
With dlg
    .AllowMultiSelect = False
    .Show
End With
Rep = dlg.SelectedItems(1)
 
Set oFld = Fso.GetFolder(Rep)
For Each oFl In oFld.Files
    If Mid(oFl.Name, InStr(1, oFl.Name, "."), 4) = ".doc" Then
        'Action à effectuer pour chaque document
        Debug.Print oFl.Name
    End If
Next oFl
 
End Sub

tu dois ajouter la référence "Microsoft File Scripting Runtime"

[Dailyplanet]

J'ai trouvé sur le net une macro (BatchMacro) qui est capable d'exécuter un autre macro et ceci pour un lot de fichiers.

La voici:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Public Sub BatchMacro()
' Exécute une macro par lot sur une série de fichiers
' Version légère pour WD2002+ seulement : utilise le FilePicker
' Anacoluthe pour le MPFW et la FAQ à m@rina
 
Dim NomMacro As String
Dim vFichier As Variant
Dim RetourDL As Long
Dim NbFichOK As Integer
 
' 1- Sélection des fichiers
' Le FilePicker permet de sélectionner le répertoire puis dedans
' des fichiers avec Maj ou Ctrl ou tous les fichiers avec Ctrl+A
Dim fd As FileDialog
Set fd = Application.FileDialog(msoFileDialogFilePicker)
    fd.Title = "BATCH: Sélectionner les fichiers à traiter"
    fd.Filters.Add _
    "Documents", "*.doc; *.dot; *.html; *.htm; *.rtf", 1
If fd.Show <> -1 Then Exit Sub
If MsgBox(fd.SelectedItems.Count & " documents à traiter ", vbYesNo, _
   "continuer ?") = vbNo Then Exit Sub
 
' 2- Sélection de la macro
MsgBox "Choisissez maintenant la macro" & vbCr & _
"et appuyez sur le bouton Exécuter"
With Application.Dialogs(wdDialogToolsMacro)
     RetourDL = .Display
     NomMacro = .Name
End With
If RetourDL <> 1 Then Exit Sub
If InStr(NomMacro, "Batch") <> 0 _
   Then MsgBox "Pas Batchmacro de Batchmacro !": Exit Sub
 
' 3- Exécution de la macro dans tous les fichiers choisis
' la macro doit agir uniquement sur le document actif sans le fermer
For Each vFichier In fd.SelectedItems
    On Error GoTo Suivant
    Application.Documents.Open FileName:=vFichier, _
    AddToRecentFiles:=False, ConfirmConversions:=True, _
    Visible:=True
    On Error GoTo Fermer
    Application.Run (NomMacro)
    NbFichOK = NbFichOK + 1
Fermer:
    On Error GoTo Suivant
    ActiveDocument.Close SaveChanges:=wdSaveChanges
Suivant:
    On Error GoTo 0
Next vFichier
 
' 4 fin de la BatchMacro
MsgBox ("La macro " & NomMacro & " a été exécutée sur " _
& NbFichOK & " Fichiers")
Set fd = Nothing
End Sub

Après cela je n'ai plus qu'à créer ma propre macro qui ajoute un pied de page au document.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub word_pied_de_page()
'
' word_pied_de_page Macro
'
'
    ActiveWindow.ActivePane.View.Zoom.Percentage = 100
    WordBasic.ViewFooterOnly
    Selection.Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, Text:= _
        "FILENAME  \* Lower ", PreserveFormatting:=True
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    WordBasic.ViewFooterOnly
    ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    ActiveDocument.Save
End Sub

Si ça peut servir.
Merci encore pour ton aide.

Dailyplanet