Discussion :

[ziad.shady]

Bonjour à tous

Hop je suis devant la situation suivante :

L'idée de base c'est que j'appèlle mon service à un interval de temps régulier, en lui passant un paramètre. Pour celà au niveau de la commande j'utilise un Timer.

Voici le code qui provoque l'erreur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
       // la méthode execute qui se trouve dans la commande
       public function execute( event : CairngormEvent ): void { 
               //Je déclare un objet de mon type Event.
               var myEvent : XEvent  =  event as XEvent;     
 
               //Je déclare un objet de mon type Delegate.
               var delegate : XDelegate  = new XDelegate( this );       
 
              //Je déclare un Timer pour exécuter la fonction toutes les 5 secondes.
               var timer:Timer = new Timer(5000,0);
 
               //je déclare une String qui va contenir le paramètre que j'ai spécifié   
               //quand j'ai dispaché l'événement.
               var name:String = myEvent.name as String;            
 
               //Et hop, au niveau de cette instruction je galère bien comme il faut :)
               timer.addEventListener("timer",delegate.getService(name, eventT));
               timer.start();                  
       }
 
       //Voici la méthode du delegate qui désigne l'objet qui va traiter le résultat:
       public function getService(name:String, event:TimerEvent): void {         	 
                //J'appèlle mon service qui se trouve dans une classe java.
                var token : AsyncToken = service.getService(name);
                token.addResponder(responder);
    }

Si je passe que le paramètre sans Timer ça marche bien et si je passe que le Timer sans paramètre ça marche bien aussi, mais les deux NON
(Bien évidemment je modifie les paramètres pour chaque cas)

Je suis convaincu que j'ai oublié quelque chose mais je ne sais pas trop quoi!!!

Je suis preneur de toute propositions.

Merci d'avance.

[Fares BELHAOUAS]

Salam

Je crois que tu devrais plutôt écrire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
	// la méthode execute qui se trouve dans la commande
	public function execute( event : CairngormEvent ): void
	{
		//Je déclare un objet de mon type Event.
		var myEvent : XEvent = event as XEvent;
 
		//Je déclare un objet de mon type Delegate.
		var delegate : XDelegate = new XDelegate( this );
 
		//Je déclare un Timer pour exécuter la fonction toutes les 5 secondes.
		var timer:Timer = new Timer(5000,0);
 
		//je déclare une String qui va contenir le paramètre que j'ai spécifié
		//quand j'ai dispaché l'événement.
		var name:String = myEvent.name as String;
 
		//Et hop, ÇA DEVRAIT MARCHER
		timer.addEventListener(TimerEvent.TIMER,
                function(event:TimerEvent):void
                {
                	delegate.getService(name);
                });
		timer.start();
	}
 
	//Voici la méthode du delegate qui désigne l'objet qui va traiter le résultat:
	public function getService(name:String): void
	{
		//J'appèlle mon service qui se trouve dans une classe java.
		var token : AsyncToken = service.getService(name);
		token.addResponder(responder);
	}

J'espère que ça répond à ta question.

[ziad.shady]

Wa alaykum issalam,

Je te dis "merci pour ta réponse," même avant de l'essayer

Salam.

[ziad.shady]

Là je reviens pour te dire que ça marche à merveille.

Hayaka lah.