Discussion :

[sempire]

Bonjour,
J'aimerai importer un fichier CSV comportant plus de 65000 lignes.
J'aimerai faire en sorte que seules les premières 65000 premères lignes s'enregistrent dans un premier fichier, et qu'un autre fichier se charge des 65000 autres lignes suivantes. Cela est-il gérable via Excel ou faut-il développer une macro ?

Merci d'avance pour toute réponse.

[SilkyRoad]

bonsoir


Tu peux tester cette procédure qui utilise la bibliothèque ADO.
Il est possible de paramétrer le nombre de lignes importées par feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub Test()
    Extraction "C:\dossier\nomfichier.csv", 65536, ";"
End Sub
 
 
Sub Extraction(Fichier As String, _
     NbLignesParFeuille As Long, _
     Separateur As Variant)
 
    Dim Wb As Workbook
    Dim Counter As Double
    Dim Tableau() As String
    Dim i As Integer
    Dim ContenuLigne As String
 
    Application.ScreenUpdating = False
 
    Counter = 1
    Set Wb = Workbooks.Add(1)
 
    'Ouverture du fichier txt
    Open Fichier For Input As #1
        Do While Not EOF(1)
            If Counter > NbLignesParFeuille Then
                Wb.Worksheets.Add
                Counter = 1
            End If
 
            Line Input #1, ContenuLigne
            'découpe la chaine en fonction des virgules
            'le résultat de la fonction Split est stocké dans un tableau
            Tableau = Split(ContenuLigne, Separateur)
 
            'boucle sur le tableau pour extraire les données
            For i = 0 To UBound(Tableau)
                ActiveSheet.Cells(Counter, i + 1) = Tableau(i)
            Next i
 
            Counter = Counter + 1
        Loop
    Close #1
 
    Application.ScreenUpdating = True
    MsgBox "Opération terminée"
End Sub

bon week end
michel