Discussion :

[Bragon12]

Bonjour,
Je souhaite exporter mes données dans un classeur excel. Comme je ne veut pas définir de fichier précis, j'aimerai que les données soient envoyées dans un nouveau classeur.
J'ai essayé d'utiliser la méthode

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.TransferSpreadsheet()

Mais je n'ai pas trouvé comment le faire pour un nouveau fichier.
Peut-on le faire avec cette commande, ou faut-il aller vers quelque chose de plus compliqué?

[Oleff]

Bonjour,

Tu ne peux utiliser tranfertspreadsheet qu'avec un nom de fichier.
Mais si le fichier n'existe pas, la commande le crée.

Donc tu peux initialiser ce nom dans une variable que tu passe à la commande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

docmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel97, "taTableOuRequete", "C:\tonEmplacement\" & format(now(), "yyyymmddhhnnss") & ".xls", true

Ici j'ai mis comme nom de fichier un format de now() à la seconde, mais tu peux ajouter un identificateur pour rendre plus explicite le type de fichier (comme "extrac_CA" par exemple)

[Bragon12]

L'emplacement peut-il être relatif? parce que je ne sais pas encore ou seront stockés ces fichiers.
Sinon, je vais essayer de mettre une boite de dialogue pour sélectionner le dossier de destination. J'avais trouvé le code pour sélectionner un fichier... ca ne dois pas être très différent!

[Bragon12]

Merci beaucoup, ca fonctionne!
Voila le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
Dim Dossier As String
Dim Fichier As String
 
'Requires reference to Microsoft Office 12.0 Object Library.
 
   Dim fDialog As Office.FileDialog
   Dim varFile As Variant
 
   'Clear listbox contents.
   'Me.FileList.RowSource = ""
 
   'Set up the File Dialog.
   Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
   With fDialog
      'Allow user to make multiple selections in dialog box.
      .AllowMultiSelect = False
 
      'Set the title of the dialog box.
      .Title = "Sélectionnez le dossier de destination"
 
      'Show the dialog box. If the .Show method returns True, the
      'user picked at least one file. If the .Show method returns
      'False, the user clicked Cancel.
      If .Show = True Then
 
        For Each vrtSelectedItem In .SelectedItems
 
                'vrtSelectedItem is aString that contains the path of each selected item.
                'You can use any file I/O functions that you want to work with this path.
                'This example displays the path in a message box.
                Dossier = vrtSelectedItem
 
            Next
 
      Else
        'annulation
         Cancel = True
      End If
   End With
   'vérification de la sélection du dossier
    If Dossier <> "" Then
        'création de l'adresse du fichier
        Fichier = Dossier & "\export_contrats" & Format(Now(), "yyyy-mm-dd--hh-nn") & ".xls"
        'exportation de la requête dans le fichier
        DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, "Adh_etat_contratsigne_synthese", Fichier, True
        'message de succès
        MsgBox "Export réalisé avec succès" & Chr(13) & "emplacement du fichier :" & Chr(13) & Fichier, vbInformation
 
    'pas d'export si pas de dossier
    Else
        MsgBox "Export non effectué", vbCritical
    End If