Discussion :

[le_niak]

Bonjour,

J'ai utilisé le modele de la FAQ pour utiliser la fenetre de selection de repertoire. Cependant lors de l'ouverture de cette fenetre le repertoire par default est poste de travail.
Je voudrais que cette fenetre s'ouvre deja sur un repertoire defini.

http://vb.developpez.com/faq/?page=Fichiers#select_rep

Merci.

[LedZeppII]

Bonjour,

je te propose d'utiliser l'objet VB Script Shell et sa méthode BrowseForFolder.
Il faut ajouter une référence VB à "Microsoft Shell Controls And Automation" (bibliothèque Shell32)

Un exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Function ChoisirDossier(Optional strTitre As String, Optional vRacine As Variant) As String
' Lib Shell32 : Nécessite référence à "Microsoft Shell Controls And Automation"
Const BIF_RETURNONLYFSDIRS = &H1
Const BIF_VALIDATE = &H20
Const BIF_NONEWFOLDERBUTTON = &H200  ' Do not add the "New Folder" button to the dialog.
                                     ' Only applicable with BIF_NEWDIALOGSTYLE.
Const ssfDRIVES = &H11
Dim oShell As Shell32.Shell, oFolder As Shell32.Folder2
Dim strDossier, lgOptions As Long
 
' Instancie un objet Shell32
Set oShell = New Shell32.Shell
lgOptions = BIF_RETURNONLYFSDIRS Or BIF_VALIDATE Or BIF_NONEWFOLDERBUTTON
If IsMissing(vRacine) Then vRacine = ssfDRIVES
If strTitre = "" Then strTitre = "Choisir un dossier"
' Ouvre la boîte de dialogue
Set oFolder = oShell.BrowseForFolder(Access.hWndAccessApp, strTitre, _
              lgOptions, vRacine)
If Not oFolder Is Nothing Then
   strDossier = oFolder.Self.Path
End If
' Libère les objets
Set oFolder = Nothing
Set oShell = Nothing
ChoisirDossier = strDossier
End Function

Exemple d'utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim strChemin As String
strChemin = ChoisirDossier("Sélectionnez un dossier", "C:\Documents and Settings\Moi")

strChemin contient le chemin du dossier choisi ou "" si l'utilisateur a appuyé sur [Annuler].

Cette méthode tout comme celle de la faq ne définit pas un répertoire par défaut, mais le répertoire racine à partir duquel il est possible d'explorer les dossiers.
Autrement dit, on ne peut pas remonter plus haut que ce réportoire racine.

A+

[le_niak]

Merci pour ta réponse, j'essaye de suite.

[le_niak]

Merci pour ta solution.
J'ai une autre question en rapport avec ma demande initiale.
Je réalise des exports vers excel et je voudrais de la meme façon lorsque j'enregistre le fichier excel que l'arborescence s'ouvre dans un répertoire donné.

[LedZeppII]

Bonjour,

je pense que tu peux utiliser ceci :
Afficher la boîte de dialogue Enregistrer sous afin de récupérer le nom et le chemin du fichier sélectionné

A+

[le_niak]

Merci