Discussion :

[bourgui78]

Bonjour,

je suis sous office 2000, et je cherche à faire apparaitre une boite de dialogue pour sélectionner un fichier type .txt.
Actuellement j'utilise ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Const FolderParamS = "T:\Programme\"
Const DataParamS = "test.txt"
Workbooks.OpenText Filename:= _
        FolderParamS & DataParamS, Origin:= _
        xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
        xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _
        Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(Array(1, 1), _
        Array(2, 1), Array(3, 1), Array(4, 1))

mais ceci impose que FolderParamS & DataParamS soient des constantes, or je voudrais que ce soit variable, et je voudrais que lorsque mon fichier ainsi sélectionné s'ouvre, qu'il s'ouvre dans les conditions précédentes à savoir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Origin:= _
        xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
        xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _
        Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(Array(1, 1), _
        Array(2, 1), Array(3, 1), Array(4, 1))

j'essaie la fonction Application.Dialogs.Item(xlDialogOpen).Show mais j'ai toutes les extensions possibles et ensuite à l'ouverture du fichier, cela me demande sous quel format je veux que le fichier soit ouvert.

Avez-vous une autre solution ?
j'ai essayé également la boite de dialogue de ouskel'n'or, mais c'est trop lourd pour ce que je veux.

Je vous remercie par avance pour votre aide

Patricia

[fring]

Bonjour,

Si j'ai bien compris, ceci devrait correspondre à tes attentes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim Fich As Variant
 
Fich = Application.GetOpenFilename("Fichier texte (*.txt), *.txt")
If Fich = False Then Exit Sub
 
Workbooks.OpenText Filename:=Fich, Origin:= _
        xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
        xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _
        Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(Array(1, 1), _
        Array(2, 1), Array(3, 1), Array(4, 1))

[zazaraignée]

Salut

As-tu essayé avec l'objet FileDialog ? Un petit exemple ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub AfficherDialogueOuvrir()
    With Application.FileDialog(msoFileDialogOpen)
        .Filters.Clear
        .Filters.Add "Texte pur", "*.txt", 1
        .Filters.Add "Classeur Excel", "*.xls", 2
        .FilterIndex = 1
        .Show       ' affiche la boîte de dialogue
        .Execute    ' exécute l'action (ouvrir ou annuler)
    End With
End Sub

[bourgui78]

de mon côté j'ai trouvé un truc qui le fait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
'Choix du fichier texte qui a été créé par Python (on est obligé de choisir un fichier)
encore:
DataParamS = Application.GetOpenFilename("Fichiers texte (*.txt),*.txt")
If DataParamS = False Then
MsgBox "vous devez choisir un fichier"
GoTo encore
End If
Workbooks.OpenText Filename:= _
        DataParamS, Origin:= _
        xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
        xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _
        Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(Array(1, 1), _
        Array(2, 1), Array(3, 1), Array(4, 1))

et je vais me servir de vos conseils pour améliorer mon code.

Merci beaucoup de votre aide

Patricia

[fring]

Salut zaza,

FileDialog n'est disponible qu'à partir de la version 2002 d'Excel